Hur man snabbt exporterar information om alla medlemmar i en Outlook-kontaktgrupp till Excel

Som standard kan du bara se medlemsnamn och e-postadresser i en kontaktgrupp. Om du vill få medlemmarnas övriga uppgifter kan du använda det sätt som introduceras i den här artikeln.

När du dubbelklickar på en kontaktgrupp för att öppna den, i dess fönster, kan du bara se gruppmedlemmarnas namn och e-postadresser. Du kan inte få medlemmars andra uppgifter, som företag, befattning, telefonnummer eller företagsadress, etc. För att få dessa uppgifter måste du i allmänhet hitta de kontakter som motsvarar medlemmarna i din kontaktmapp manuellt. Det är för jobbigt. Här kommer vi att visa dig en bit VBA-kod, som snabbt kan exportera dessa detaljer till en Excel-arbetsbok.

Exportera information om alla medlemmar i en kontaktgrupp till Excel

1. Till att börja med, starta ditt Outlook-program.
2. Sedan bör du trycka på "Alt + F11" genvägar i huvudfönstret i Outlook.
3. Nästa i det nya "Microsoft Visual Basic for Applications"-fönstret måste du öppna en modul som inte används eller direkt infoga en ny modul.
4. Kopiera sedan och klistra in följande VBA-kod i den här modulen.

Sub ExportMemberContactDetailsToExcel()
    Dim objContactGroup As Outlook.DistListItem
    Dim objGroupMember As Outlook.recipient
    Dim objContacts As Outlook.Items
    Dim objFoundContact As Outlook.ContactItem
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim i As Integer
    Dim nRow As Integer
    Dim strFilename As String
 
    Set objContactGroup = Application.ActiveExplorer.Selection(1)
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkBook = objExcelApp.Workbooks.Add
    Set objExcelWorkSheet = objExcelWorkBook.Worksheets(1)
 
    'Set the seven column headers
    With objExcelWorkSheet
         .Cells(1, 1) = "Name"
         .Cells(1, 2) = "Email Address"
         .Cells(1, 3) = "Company"
         .Cells(1, 4) = "Job Title"
         .Cells(1, 5) = "Phone Number"
         .Cells(1, 6) = "Mailing Address"
         .Cells(1, 7) = "Birthday"
    End With
 
    Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items.Restrict("[Email1Address]>''")
 
    nRow = 2
    For i = 1 To objContactGroup.MemberCount
        Set objGroupMember = objContactGroup.GetMember(i)
 
        strFilter = "[Email1Address] = '" & objGroupMember.Address & "'"
        Set objFoundContact = objContacts.Find(strFilter)
 
        If Not (objFoundContact Is Nothing) Then
           'Input the Contact Details
           With objExcelWorkSheet
                .Cells(nRow, 1) = objFoundContact.FullName
                .Cells(nRow, 2) = objFoundContact.Email1Address
                .Cells(nRow, 3) = objFoundContact.CompanyName
                .Cells(nRow, 4) = objFoundContact.JobTitle
                .Cells(nRow, 5) = objFoundContact.BusinessTelephoneNumber
                .Cells(nRow, 6) = objFoundContact.MailingAddress
             If objFoundContact.Birthday = #1/1/4501# Then
                .Cells(nRow, 7) = ""
             Else
                .Cells(nRow, 7) = objFoundContact.Birthday
             End If
           End With
       Else
           With objExcelWorkSheet
               .Cells(nRow, 1) = objGroupMember.Name
               .Cells(nRow, 2) = objGroupMember.Address
           End With
       End If
       nRow = nRow + 1
    Next
 
    'Fit the columns
    objExcelWorkSheet.Columns("A:G").AutoFit
 
    'Change the Path as per where you want to save the new Excel file
    strFilename = "E:\" & objContactGroup.DLName & " Member Contact Details.xlsx"
    'Save the Excel workbook
    objExcelWorkBook.Close True, strFilename
 
    MsgBox ("Complete!")
End Sub

5. Efter det, för bekväm kontroll, kan du lägga till det nya VBA-projektet till snabbåtkomstverktygsfältet eller menyfliksområdet.
6. Ställ senare in din Outlook-makrosäkerhetsnivå till låg.
7. I slutändan kan du prova.

• Välj först en kontaktgrupp.
• Tryck sedan på makroknappen i verktygsfältet Snabbåtkomst eller menyfliksområdet.
• Makrot körs omedelbart.
• När det är klart kommer du att få en uppmaning om "Slutför!"
• Efter det kan du gå till den fördefinierade lokala målmappen, där du kan hitta en ny Excel-fil.
• Öppna den, du kommer att se gruppmedlemmarnas kontaktuppgifter som följande skärmdump:

Få inte panik inför Outlook-problem

Ingen är villig att acceptera några Outlook-problem, oavsett popup-felmeddelande eller korrupta Outlook data fil. Därför tenderar användare att få panik när de stöter på Outlook-problem. Om du i så fall vill behålla lugnet bör du ha två nödvändigheter i handen. En är aktuella Outlook-datasäkerhetskopior. Den andra är potent Outlook fix-programvara, som DataNumen Outlook Repair.

Författarintroduktion:

Shirley Zhang är expert på dataåterställning DataNumen, Inc., som är världsledande inom teknik för återställning av data, inklusive SQL-återhämtning och Outlook-programvara för reparationsprogramvara. För mer information besök www.datanumen.com