Hur du snabbt bifogar den senast modifierade filen i en Windows-mapp till din Outlook-e-post

Ibland kanske du snabbt vill hitta och bifoga den senast ändrade filen i en specifik Windows-mapp till en Outlook-e-post. I det här fallet kan du använda metoden som introduceras i den här artikeln.

Vissa användare vill att Outlook snabbt ska kunna hitta och lägga till den senast ändrade filen i en Windows-mapp i ett e-postmeddelande, till exempel den senast skapade, ändrade eller sparade filen. Outlook erbjuder dock inte en sådan direkt och inbyggd funktion. Därför kommer vi i det följande att visa en del VBA-kod som enkelt kan användas.

Bifoga den senast modifierade filen i en Windows-mapp till e-post

1. Från början bör du starta din Outlook-applikation.
2. Sedan, när du kommer in i huvudfönstret i Outlook, kan du trycka på "Alt + F11" -tangentknapparna.
3. Därefter kommer du åtkomst till Outlook VBA-redigeringsfönstret i framgång.
4. Därefter bör du hitta och öppna en modul som inte används.
5. Och kopiera och klistra sedan in följande VBA-kod i det här modulfönstret.

Sub AttachLastModifiedSpecificFile()
    Dim objShell As Object
    Dim objSelectedFolder As Object
    Dim objFileSystem As Object
    Dim strSourceFolderPath As String
    Dim objSourceFolder As Object
    Dim objFile As Object
    Dim dLastModifiedDate As Date
    Dim strLastModifiedFilePath As String
    Dim objMail As Outlook.MailItem
 
    On Error GoTo ErrorHandler
    'Select a local source folder
    Set objShell = CreateObject("Shell.Application")
    Set objSelectedFolder = objShell.BrowseForFolder(0, "Select the source folder", 0, "")
    strSourceFolderPath = objSelectedFolder.self.Path
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objSourceFolder = objFileSystem.GetFolder(strSourceFolderPath)
 
    If objSourceFolder.Files.Count > 0 Then
       For Each objFile In objSourceFolder.Files
           'Find the last modified file within "xlsx" file type in the selected Windows folder
           If (objFile.DateLastModified > dLastModifiedDate) And (objFileSystem.GetExtensionName(objFile) = "xlsx") Then
              'You can add or change criteria, such as
              'Left(objFile.Name, 4) = "Test" ---> file whose name begins with "Test"
              '(objFile / 1024) / 1024 > 2 --> File exceeds 2 MB
              'Note: Use "And" to connect more than one criteria
              strLastModifiedFilePath = objFile.Path
              dLastModifiedDate = objFile.DateLastModified
           End If
       Next
 
       If strLastModifiedFilePath <> "" Then
          'Confirm attaching it to the current outlook email
          strMsg = "The last modified file in the " & Chr(34) & strSourceFolderPath & Chr(34) & " is: " & vbCrLf & vbCrLf & "File: " & strLastModifiedFilePath & vbCrLf & "Date: " & dLastModifiedDate & vbCrLf & vbCrLf & "Do you want to attach it?"
          nPrompt = MsgBox(strMsg, vbQuestion + vbYesNo, "Confirm Attaching Last Modified File")
 
          If nPrompt = vbYes Then
             Set objMail = Outlook.Application.ActiveInspector.CurrentItem
             objMail.Attachments.Add strLastModifiedFilePath
         End If
      Else
         MsgBox "No file in the selected folder can meet your predefined criteria!", vbExclamation + vbOKOnly
      End If
    Else
      MsgBox "No file exists in the selected Windows folder!", vbExclamation + vbOKOnly
    End If
 
ErrorHandler:
    Exit Sub
End Sub

6. Därefter kan du stänga det aktuella VBA-redigeringsfönstret och fortsätta att lägga till det nya makrot i verktygsfältet Snabbåtkomst eller menyfönstret.
7. Senare måste du ändra din säkerhetsnivå för makro i Outlook till låg.
8. Så småningom kan du prova.

• För det första, skapa och skapa en ny Outlook-e-post som vanligt.
• Klicka sedan på makroknappen i snabbåtkomstverktygsfältet, som bilden nedan:
• Därefter måste du välja en Windows-källmapp och trycka på "OK".
• Om det finns en sådan fil i den valda Windows-mappen får du en fråga som följande skärmdump:
• När du trycker på “Ja” bifogas filen direkt.

Lös Outlook-problem så snart som möjligt

När du stöter på några Outlook-problem rekommenderas att du löser dem så snart som möjligt. I den här situationen borde du bättre förbereda en robust Outlook-fix verktyg i förväg, till exempel DataNumen Outlook Repair. Det kan fixa PST-fel och rädda dina Outlook-data effektivt.

Författarintroduktion:

Shirley Zhang är expert på dataåterställning DataNumen, Inc., som är världsledande inom teknik för återställning av data, inklusive skadad mdf och Outlook-programvara för reparationsprogramvara. För mer information besök www.datanumen.com