Så här ställer du in en annan standardpåminnelsestid för olika typer av flaggade objekt i ditt Outlook

Som standard använder Outlook automatiskt standardtid för påminnelser för alla typer av flaggade objekt. Ändå, om du vill använda annan påminnelsetid för flaggade objekt på grundval av artikeltyp, kan du hänvisa till metoden som introducerades i den här artikeln.

Outlook låter dig ställa in standardpåminnelsestid för alla flaggade objekt, oavsett artikeltyp. Du kan gå till "Arkiv" -menyn och klicka på "Alternativ". I fönstret "Outlook-alternativ" kan du se alternativet "Standardpåminnelsestid" på fliken "Uppgifter", som visas i följande skärmdump.

Ändå hoppas de flesta användare kunna använda olika påminnelsetider för olika typer av flaggade objekt, till exempel "9:00" för flaggade e-postmeddelanden och "17:30" för flaggade kontakter. Nu kommer vi att fokusera på detta exempel för att introducera en metod.

Ställ in annan standardtid för påminnelse för olika typer av flaggade objekt

1. Till att börja med, starta Outlook-applikationen.
2. Gå sedan till Outlook VBA-redigeraren med hänvisning till “Hur du kör VBA-kod i din Outlook".
3. I det efterföljande “Microsoft Visual Basic for Applications” -fönstret kopierar du följande kod till “ThisOutlookSession” -projektet.

Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objMail As Outlook.MailItem
Public WithEvents objContact As Outlook.ContactItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    ElseIf TypeOf objExplorer.Selection.Item(1) Is ContactItem Then
       Set objContact = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
    ElseIf Inspector.CurrentItem.Class = olContact Then
       Set objContact = Inspector.CurrentItem
    End If
End Sub

Private Sub objMail_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objMail.IsMarkedAsTask = True Then
          If objMail.TaskDueDate <> "1/1/4501" Then
             With objMail
                  .ReminderSet = True
                  'Change the reminder time for flagged emails
                  .ReminderTime = objMail.TaskDueDate & " 10:00"
                  .Save
             End With
          End If
       End If
    End If
End Sub

Private Sub objContact_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objContact.IsMarkedAsTask = True Then
          If objContact.TaskDueDate <> "1/1/4501" Then
             With objContact
                  .ReminderSet = True
                  'Change the reminder time for flagged contacts
                  .ReminderTime = objContact.TaskDueDate & " 17:30"
                  .Save
             End With
          End If
       End If
    End If
End Sub

4. Starta sedan om Outlook för att aktivera makrot.
5. Från och med nu, varje gång du flaggar ett e-postmeddelande, kommer påminnelsestiden att ställas in till "10:00" på flaggans förfallodatum.
6. Och när du flaggar en kontakt kommer påminnelsestiden att ställas till “17:30” på flaggans förfallodatum.

Hantera Outlook-problem flexibelt

Du kan stöta på alla möjliga typer av problem i Outlook. Så du måste lära dig några åtgärder för att hantera dem i förväg. Om till exempel Outlook ofta startar om, behöver du reparera Office eller inaktivera tillägg från tredje part, etc. Eller om din Outlook PST-fil blir komprometterad kan du först prova verktyg för reparation av inkorgen. När det misslyckas kan du fortsätta använda ett kraftfullt externt verktyg, som DataNumen Outlook Repair.

Författarintroduktion:

Shirley Zhang är expert på dataåterställning DataNumen, Inc., som är världsledande inom teknik för återställning av data, inklusive mdf-återställning och Outlook-programvara för reparationsprogramvara. För mer information besök www.datanumen.com