Hur man automatiskt vidarebefordrar specifika inkommande e-postmeddelanden med anpassat ämne och kropp i Outlook

Outlook-lösningar September 29, 2025

För att automatiskt vidarebefordra specifika inkommande e-postmeddelanden tänker du först på att använda regler i Outlook. Ändå stöder regel dig inte för att anpassa e-postens ämne och kropp när du vidarebefordrar. Om du vill vidarebefordra specifika e-postmeddelanden med anpassat ämne och brödtext kan du använda metoden som introduceras i den här artikeln.

Som vi alla vet kan Outlook-regler stödja användare att automatiskt vidarebefordra specifika inkommande e-postmeddelanden. Med det sättet kommer e-postmeddelandet att vidarebefordras automatiskt till de specifika personerna med ämnet i mönstret "FW: original mail subject" och original mail body. Men många användare hoppas att automatiskt vidarebefordra e-postmeddelanden med anpassat ämne och innehåll. Tydligen kan regler inte inse det. Därför kommer vi här att introducera ett tillvägagångssätt för att få det enkelt.

Automatisk vidarebefordran av specifika inkommande e-postmeddelanden med anpassat ämne och brödtext

  1. Från början, start ditt Outlook-program.
  2. Få sedan tillgång till VBA-redigeraren med hänvisning till “Hur du kör VBA-kod i din Outlook".
  3. Kopiera sedan och klistra in följande VBA-kod i projektet "ThisOutlookSession".
Public WithEvents objInbox As Outlook.Folder
Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInbox = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Set objInboxItems = objInbox.Items
End Sub

Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
    Dim objForward As Outlook.MailItem
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'If it is a specific new email
       If (objMail.SenderEmailAddress = "bob_black@datanumen.com") And (objMail.Importance = olImportanceHigh) And (objMail.Attachments.Count > 0) Then
 
           Set objForward = objMail.Forward
           'Customize the forward subject, body and recipients
           With objForward
                .Subject = "Custom Subject"
                .HTMLBody = "<HTML><BODY>Type body here. </BODY></HTML>" & objForward.HTMLBody
                .Recipients.Add ("boss@datanumen.com")
                .Recipients.Add ("john@datanumen.com")
                .Recipients.ResolveAll
                .Importance = olImportanceHigh
                .Send
           End With
       End If
    End If
End Sub

VBA-kod - Vidarebefordra specifika inkommande e-postmeddelanden med anpassat ämne och kropp

  1. Ändra sedan kriterierna för angivna inkommande e-postmeddelanden. Och ändra den specifika kroppen, ämnet och mottagarna i koden enligt dina behov.
  2. Så småningom klickar du på “Application_Startup ”subrutin och tryck på“ F5 ”-tangenten.
  3. Sedan dess vidarebefordrar Outlook varje gång en viss inkommande kommer till din standardmapp för inkorg automatiskt med anpassat ämne och kropp till de fördefinierade mottagarna.Skicka e-post automatiskt

Ta itu med Outlook-problem flexibelt

Även om Outlook är funktionsrikt kan det inte vara immunt mot fel och andra problem. Exempelvis kan Outlook PST-fil lätt skadas på grund av flera faktorer. Dessa inkluderar mänskliga fel, virus, överdimensionerade PST-filer och skadade Outlook-profiler och så vidare. Därmed måste du göra några försiktighetsåtgärder, som att hålla försiktig med Outlook PST-filstorlek, hålla alla virus i schack samt att få tag på en robust Outlook-återställning verktyg, såsom DataNumen Outlook Repair.

Författarintroduktion:

Shirley Zhang är expert på dataåterställning DataNumen, Inc., som är världsledande inom teknik för återställning av data, inklusive SQL Server återvinning och Outlook-programvara för reparationsprogramvara. För mer information besök www.datanumen.com

Kommentarer är stängda.