Hur gruppavbryter du alla Outlook-möten som planeras inom ett visst datumintervall

Om du vill avbryta alla planerade möten inom ett visst datumintervall i Outlook kan du använda de medel som presenteras i den här artikeln. Det kan spara dig från att söka och avbryta sådana möten manuellt.

Om du av vissa skäl inte kan organisera eller delta i mötena som kommer att hållas inom ett visst framtida datumintervall, kanske du vill avbryta alla sådana möten. Generellt måste du först ta reda på dem och sedan avbryta dem en efter en. Det blir ganska besvärligt. Därför kommer vi i det följande att dela med dig på ett annat sätt, vilket är mycket bekvämare.

Batch Avbryt alla möten som planeras inom ett visst datumintervall

1. Starta ditt Outlook-program helt i början.
2. Sedan, i Outlook, måste du trycka på “Alt + F11” -knapparna.
3. Därefter kommer du in i "Microsoft Visual Basic for Applications" -fönstret.
4. I det här fönstret ska du öppna en oanvänd modul eller bara infoga en ny.
5. Därefter kan du kopiera följande VBA-kod till den här modulen.

Sub BatchCancelAllMeetingsInSpecificDateRange()
    Dim dStartDate As Date
    Dim dEndDate As Date
    Dim objCalendarFolder As Outlook.folder
    Dim objItems As Outlook.Items
    Dim objItemsInDateRange As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim objResponse As Outlook.MeetingItem
 
    'Specify the start date and end date
    dStartDate = InputBox("Enter the start date:", , "10/1/2017")
    dEndDate = InputBox("Enter the end date:", , "10/8/2017")
 
    If dStartDate <> #1/1/4501# And dEndDate <> #1/1/4501# Then
       'Select a calendar folder
       Set objCalendarFolder = Outlook.Application.Session.PickFolder
       Set objItems = objCalendarFolder.Items
       objItems.IncludeRecurrences = True
       objItems.Sort "[Start]"
 
       'Get the appointments in the specific date range
       strFilter = "[Start] >= " & Chr(34) & dStartDate & " 00:00 AM" & Chr(34) & " AND [End] <= " & Chr(34) & dEndDate & " 11:59 PM" & Chr(34)
       Set objItemsInDateRange = objItems.Restrict(strFilter)
 
       objItemsInDateRange.Sort "[Start]"
       For Each objAppointment In objItemsInDateRange
           'Cancel the meetings in this date range
           If objAppointment.MeetingStatus = olMeeting Then
              If objAppointment.Organizer = Outlook.Session.CurrentUser Then
                 objAppointment.MeetingStatus = olMeetingCanceled
                 objAppointment.Save
                 objAppointment.Send
                 objAppointment.Delete
              Else
                 Set objResponse = objAppointment.Respond(olMeetingDeclined)
                 objResponse.Send
                 objAppointment.Delete
              End If
            End If
       Next
    End If
End Sub

6. Så småningom kan du köra detta makro just nu.

• I det aktuella makrofönstret trycker du på tangenten “F5”.
• Därefter måste du ange datumintervallet.
• Därefter visas en annan dialogruta som kräver att du väljer en källkalendermapp och klickar på “OK”.
• Slutligen, när makrot är klart, kan du se att alla möten i det specifika datumintervallet har avbrutits.
• I mappen "Skickade objekt" hittar du avbokningar för möten, som skärmdumpen nedan:

Åtgärda Outlook-fel

Om du har använt Outlook i årtionden måste du ha stött på flera fel. Lyckligtvis kommer Outlook packat med ett inbyggt reparationsverktyg - Scanpst. Du kan använda den för att fixa Outlook fel. Ändå, om det misslyckas, är din sista utväg externa fixverktyg som DataNumen Outlook RepairDen kan skanna Outlook-filer och åtgärda de flesta fel, och till och med enkelt återställa skadade Outlook-data.

Författarintroduktion:

Shirley Zhang är expert på dataåterställning DataNumen, Inc., som är världsledande inom teknik för återställning av data, inklusive fixa sql och Outlook-programvara för reparationsprogramvara. För mer information besök www.datanumen.com