Hur man ställer in olika påminnelsestider för Outlook-möten i olika färgkategorier

Om du klassificerar Outlook-möten efter färgkategorier och vill ställa in olika påminnelsetid för möten i olika färgkategorier kan du hänvisa till den här artikeln. Här lär vi dig att förverkliga det med Outlook VBA.

Till exempel delar du upp möten i två grupper. Den ena är i färgkategorin "Extern" eftersom mötesplatsen är för långt bort, och den andra är i färgkategorin "På plats" eftersom platsen är precis här. Nu vill du att Outlook automatiskt ska kunna ställa in påminnelsetiden för "extern"-möten till 1 timme före start och "på plats"-möten till 15 minuter före start. Med tanke på detta krav kommer vi nedan att dela en snabb metod.

Auto Ställ in olika påminnelser för möten i olika färgkategorier

1. Till att börja med startar du din Outlook-applikation.
2. Tryck sedan på “Alt + F11” -knapparna för att komma åt VBA-redigeringsfönstret.
3. Därefter, i det efterföljande fönstret, kopiera och klistra in VBA-koden nedan i projektet “ThisOutlookSession”.

Public WithEvents objCalendar As Outlook.Folder
Public WithEvents objCalendarItems As Outlook.Items

Private Sub Application_Startup()
    Set objCalendar = Outlook.Application.Session.GetDefaultFolder(olFolderCalendar)
    Set objCalendarItems = objCalendar.Items
End Sub

Private Sub objCalendarItems_ItemAdd(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub objCalendarItems_ItemChange(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub SetReminder_BasedOnCategories(ByVal objCalendarItem As Object)
    Dim objMeeting As Outlook.AppointmentItem
    Dim strCategories As String
 
    If objCalendarItem.Class = olAppointment Then
       'Check if the item is a meeting
       If objCalendarItem.MeetingStatus = olMeeting Then
          Set objMeeting = objCalendarItem
          strCategories = objMeeting.Categories
 
          'Set Reminder as 60 min before start for offsite appointments
          If InStr(strCategories, "Offsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 60
                 .Save
             End With
             'Set Reminder as 15 min before start for onsite appointments
          ElseIf InStr(strCategories, "Onsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 15
                 .Save
             End With
          End If
       End If
    End If
End Sub

4. Senare måste du klicka i subrutinen "Application_Startup" och trycka på "F5"-tangenten för att köra makrot.
5. Sedan dess, varje gång när ett nytt möte läggs till i standardkalendern eller du ändrar ett befintligt möte, kommer Outlook att automatiskt kontrollera kategorierna för mötet och automatiskt ställa in olika påminnelsestider.

Eliminera Outlook-fel

Olika problem kan uppstå med Outlook då och då. Därför är det oerhört viktigt för användare att lära sig hur man hanterar Outlook-problem. Till att börja med bör du göra regelbundna säkerhetskopior av Outlook-data. Dessutom, om det är möjligt, rekommenderas det att ha en kraftfull Outlook-reparation verktyg i närheten, t.ex. DataNumen Outlook Repair. Det kan skanna din PST-fil för att ta reda på Outlook-problem och sedan lösa dem med lätthet.

Författarintroduktion:

Shirley Zhang är expert på dataåterställning DataNumen, Inc., som är världsledande inom teknik för återställning av data, inklusive SQL-återhämtning och Outlook-programvara för reparationsprogramvara. För mer information besök www.datanumen.com