Så här tar du bort e-postadresserna till originalsändaren och mottagarna automatiskt när du vidarebefordrar en Outlook-e-post

Outlook-lösningar September 29, 2025

När du vidarebefordrar ett e-postmeddelande i Outlook kommer e-postadresserna till den ursprungliga avsändaren och mottagarna att inkluderas i meddelandets brödtext. Av säkerhetsskäl är det bäst att du just nu tar bort dessa adresser. Det här inlägget lär dig hur du låter Outlook göra detta automatiskt.

I många fall måste du vidarebefordra några e-postmeddelanden till någon annan. Som standard visas rubriken på det ursprungliga e-postmeddelandet i vidarebefordran av e-postmeddelandet. Och rubriken innehåller e-postadresserna till den ursprungliga avsändaren och mottagarna. Vid denna punkt, för säkerhet eller integritet, kanske du vill ta bort dessa e-postadresser. Ändå är det för tråkigt att manuellt ta bort dem. Därför guidar vi dig här för att göra din Outlook för att automatiskt utföra denna uppgift på din vägnar.Ta bort e-postadresserna till originalsändaren och mottagarna automatiskt när du vidarebefordrar en Outlook-e-post

Ta bort e-postadresserna till originalsändaren och mottagarna automatiskt när du vidarebefordrar ett e-postmeddelande

  1. Till att börja med, starta Outlook.
  2. Tryck sedan på “Alt + F11” -knapparna för att komma åt VBA-redigeraren.
  3. Kopiera sedan följande VBA-kod till projektet "ThisOutlookSession".
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objRegExp As Object
    Dim strHTMLBody As String
 
    Forward.Display
    strHTMLBody = Forward.HTMLBody
 
    'Find email addresses in the body via Regular Expression
    Set objRegExp = CreateObject("vbscript.RegExp")
    With objRegExp
        .Pattern = "(?:[a-z0-9!#$%&'*+/=?^_`{|}~-]+(?:\.[a-z0-9!#$%&'*+/=?^_`{|}~-]+)*|""(?:[\x01-\x08\x0b\x0c\x0e-\x1f\x21\x23-\x5b\x5d-\x7f]|\\[\x01-\x09\x0b\x0c\x0e-\x7f])*"")@(?:(?:[a-z0-9](?:[a-z0-9-]*[a-z0-9])?\.)+[a-z0-9](?:[a-z0-9-]*[a-z0-9])?|\[(?:(?:25[0-5]|2[0-4][0-9]|[01]?[0-9][0-9]?)\.){3}(?:25[0-5]|2[0-4][0-9]|[01]?[0-9][0-9]?|[a-z0-9-]*[a-z0-9]:(?:[\x01-\x08\x0b\x0c\x0e-\x1f\x21-\x5a\x53-\x7f]|\\[\x01-\x09\x0b\x0c\x0e-\x7f])+)\])"
        .IgnoreCase = True
        .Global = True
    End With
 
    'Remove email addresses
    If objRegExp.Test(strHTMLBody) Then
       Set objFoundResults = objRegExp.Execute(strHTMLBody)
       For i = 1 To objFoundResults.Count
           Forward.HTMLBody = Replace(Forward.HTMLBody, objFoundResults.Item(i - 1).Value, "")
       Next
    End If
 
    'Remove useless characters
    Forward.HTMLBody = Replace(Forward.HTMLBody, "[mailto:]", "")
    Forward.HTMLBody = Replace(Forward.HTMLBody, "()", "")
End Sub

Sätt in VBA-koden i ThisOutlookSession-projektet

  1. Starta sedan om Outlook-programmet för att aktivera det nya makrot.
  2. Så småningom kan du ta ett skott:
  • Välj eller öppna ett e-postmeddelande.
  • Klicka sedan på knappen "Vidarebefordra" i gruppen "Svara".Vidarebefordra e-post
  • Slutligen visas ett nytt vidarebefordringsmeddelande där e-postadresserna till den ursprungliga avsändaren och mottagarna har raderats.E-postadresser tas bort automatiskt vid vidarebefordran

Lugna ner i fall av korruption i Outlook

När du utsätts för några problem i din Outlook kan du få panik, rädd för Outlook korruption. Men ärligt talat kan bråttom och oro ofta resultera i många andra problem för din Outlook. Var därför inte panik men håll dig lugn i relevanta fall. Dessutom, om du har behållit ett robust PST-fixverktyg, som DataNumen Outlook Repairkan du helt enkelt använda den för att lösa Outlook-problem.

Författarintroduktion:

Shirley Zhang är expert på dataåterställning DataNumen, Inc., som är världsledande inom teknik för återställning av data, inklusive fixa sql och Outlook-programvara för reparationsprogramvara. För mer information besök www.datanumen.com

Kommentarer är stängda.