Hur man automatiskt tillämpar kategorierna för ett e-postmeddelande på alla dess svar och vidarebefordran i Outlook

När du svarar eller vidarebefordrar ett e-postmeddelande kanske du vill använda samma kategorier. I den här artikeln kommer vi att lära dig att inse detta med VBA-kod.

Om du är van vid att tilldela samma färgkategorier av original e-post till alla dess svar och vidarebefordran, varför låter du inte Outlook automatiskt uppnå detta? Även om Outlook inte tillhandahåller en sådan direkt funktion, kan du fortfarande få den med hjälp av VBA-kod. I det följande kommer vi att avslöja de detaljerade stegen och koden för dig.

Tillämpa kategorierna för ett e-postmeddelande automatiskt på alla dess svar och vidarebefordran

1. Starta Outlook-applikationen redan från början.
2. Tryck sedan på "Alt + F11"-tangenterna för att köra Outlook VBA-redigeraren.
3. Kopiera sedan följande VBA-kod till projektet "ThisOutlookSession".

Private WithEvents objExplorer As Outlook.Explorer
Private WithEvents objInspectors As Outlook.Inspectors
Private WithEvents objMail As Outlook.MailItem
Private strCategories As String

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
       strCategories = objMail.Categories
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
       strCategories = objMail.Categories
    End If
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call CopyCategories(Forward)
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Call CopyCategories(Response)
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call CopyCategories(Response)
End Sub

Private Sub CopyCategories(ByVal objNewMail As Object)
    objNewMail.Categories = strCategories
End Sub

4. Starta sedan om Outlook för att aktivera projektet.
5. Sedan dess kan du prova det genom att följa stegen nedan.

• Först och främst, välj ett e-postmeddelande och tryck på knappen "Vidarebefordra".
• Sedan visas ett e-postmeddelande för vidarebefordran, där du kan flytta till fliken "Alternativ" och trycka på tilläggsikonen i det nedre högra hörnet av gruppen "Fler alternativ".
• Därefter kan du i popup-dialogrutan "Egenskaper" se att det här e-postmeddelandet är tilldelat samma färgkategorier som det ursprungliga e-postmeddelandet.

Åtgärda skadad Outlook-fil

Med tanke på att Outlook är sårbart måste du vidta många åtgärder för att undvika dataförlust i Outlook. Du måste till exempel göra periodiska säkerhetskopior av data. Dessutom är det nödvändigt för dig att akta dig för okända e-postmeddelanden inklusive de inbäddade länkarna eller bilagorna. Sist men inte minst borde du skaffa dig ett tipp-topp externt fixverktyg, som DataNumen Outlook Repair. Det kan hjälpa dig att hämta maximal data från korrupta Outlook fil.

Författarintroduktion:

Shirley Zhang är expert på dataåterställning DataNumen, Inc., som är världsledande inom teknik för återställning av data, inklusive SQL Server fast och Outlook-programvara för reparationsprogramvara. För mer information besök www.datanumen.com