3 sätt att få ordräkningsstatistik relaterade till textrutor, fotnoter och slutnoter i ditt dokument

I dagens artikel finns det tre snabba sätt att få ordräkningsstatistik relaterad till textrutor, fotnoter och slutnoter i ditt dokument.

Det är inte svårt att få det totala antalet ord i ett dokument. Men om du vill få antalet ord av olika typer av texter, kommer fler operationer att krävas. Följande är tre metoder. Läs vidare för att se vad du kan använda. 

Metod 1: Räkna ord inklusive texter från textrutor, fotnoter och slutnoter

Som standard räknar Word alla ord som visas i dokumentet, inklusive texter i textrutor och ord från fotnoter och slutnoter.

1. Först och främst, gå till statusfältet och klicka på "Ord" för att öppna rutan "Ordantal".
2. Där ser du alla typer av statistik. Se till att du har markerat rutan "Inkludera textrutor, fotnoter och slutnoter".
3. Klicka sedan på ”Stäng”.
4. Om du inte hittar kommandot ”Words” i statusfältet, högerklicka på det.
5. Kontrollera sedan ”Word Count”.

Metod 2: Uteslut texter från textrutor, fotnoter och slutnoter från ordräkning

Detta är motsatt metod 1. Så du behöver bara avmarkera rutan ”Inkludera textrutor, fotnoter och slutnoter”.

Metod 3: Kör Word Macro för att få ett separat antal ord från textrutor, fotnoter och slutnoter

1. Starta först rutan "Word Count" enligt sättet i metod 1 och se till att alternativrutan är markerad.
2. Tryck sedan på “Alt + F11” för att öppna VBA-redigeraren.
3. Sätt sedan in en ny modul i "Normal" -projektet genom att klicka på "Normal" först.
4. Och klicka på "Infoga" nästa.
5. Välj sedan "Modul".
6. Dubbelklicka på modulen för att öppna kodningsområdet och klistra in följande koder där:

Sub SeparateCountNumberOfTextboxFootnoteEndnote()
  Dim lTextboxWords As Long
  Dim lTextboxChars As Long
  Dim lDocumntWords As Long
  Dim lDocumntChars As Long
  Dim objTextboxShape As Shape
  Dim objTemp As Dialog
  Dim bDone As Boolean
  Dim objRange As Range
  Dim lFootnoteWords As Long
  Dim lFootnoteChars As Long
  Dim lEndnoteWords As Long
  Dim lEndnoteChars As Long
 
  Application.ScreenUpdating = False

 Do
   bDone = True
   For Each objTextboxShape In ActiveDocument.Shapes
     If objTextboxShape.Type = msoGroup Then
       objTextboxShape.Ungroup
       bDone = False
     End If
   Next objTextboxShape
 Loop Until bDone

 '  Count the words and characters in the whole document.
 Selection.HomeKey Unit:=wdStory
 Set objTemp = Dialogs(wdDialogToolsWordCount)
   objTemp.Update
   objTemp.Execute
   lDocumntWords = objTemp.Words
   lDocumntChars = objTemp.Characters
 
 With ActiveDocument
 '  Count the words and characters in all textboxes.
   lTextboxWords = 0
   lTextboxChars = 0
   If ActiveDocument.Shapes.Count > 0 Then
     For Each objTextboxShape In .Shapes
       objTextboxShape.Select
       objTemp.Execute
       lTextboxWords = lTextboxWords + objTemp.Words
       lTextboxChars = lTextboxChars + objTemp.Characters
     Next objTextboxShape
   Else
     MsgBox ("There is no text box in this document")
   End If

   '  Count the words and characters in all footnotes.
   lFootnoteWords = 0
   lFootnoteChars = 0
   If ActiveDocument.Footnotes.Count > 0 Then
     For Each objRange In .StoryRanges
       If objRange.StoryType = wdFootnotesStory Then
         objRange.Select
         objTemp.Execute
         lFootnoteWords = lFootnoteWords + objTemp.Words
         lFootnoteChars = lFootnoteChars + objTemp.Characters
       End If
     Next objRange
   Else
     MsgBox ("There is no footnote in this document")
   End If

   '  Count the words and characters in all endnotes. 
   lEndnoteWords = 0
   lEndnoteChars = 0
   If ActiveDocument.Endnotes.Count > 0 Then
     For Each objRange In .StoryRanges
       If objRange.StoryType = wdEndnotesStory Then
         objRange.Select
         objTemp.Execute
         lEndnoteWords = lEndnoteWords + objTemp.Words
         lEndnoteChars = lEndnoteChars + objTemp.Characters
       End If
     Next objRange
   Else
     MsgBox ("There is no Endnote in this document")
   End If
 End With
 
 Application.ScreenUpdating = True

 MsgBox (" In this document there are totally" & vbCr _
   & Str(lDocumntWords) & " word(s) and" & Str(lDocumntChars) & " characters" & vbCr & vbCr _
   & "Including:" & vbCr _
   & Str(ActiveDocument.Shapes.Count) & " textboxes contain(s)" & vbCr _
   & Str(lTextboxWords) & " word(s)," & Str(lTextboxChars) & " characters" & vbCr & vbCr _
   & Str(ActiveDocument.Footnotes.Count) & " footnotes contain(s)" & vbCr _
   & Str(lFootnoteWords) & " word(s)," & Str(lFootnoteChars) & " characters" & vbCr & vbCr _
   & Str(ActiveDocument.Endnotes.Count) & " Endnotes contain(s)" & vbCr _
   & Str(lEndnoteWords) & " word(s)," & Str(lEndnoteChars) & " characters")
End Sub

7. Slutligen klickar du på "Kör" -knappen.

Om det inte finns någon textruta, fotnot eller slutnot kommer du att få ett meddelandefält enligt följande:

Klicka bara på “OK” för att fortsätta. Då kommer du att se en annan ruta med alla detaljer om ordräkningen.

Skaffa ett återställningsverktyg

Eftersom Word plötsligt kan kollapsa, är det lämpligt att skaffa en avancerad reparationsprodukt för att göra fixningsjobbet. Ett sådant verktyg kan vara en bra sparare för korrupta Word. Ta därför tid att skaffa en så snart som möjligt.

Författarintroduktion:

Vera Chen är en dataåterställningsexpert i DataNumen, Inc., som är världsledande inom teknik för återställning av data, inklusive fixa xls och pdf reparera programvaruprodukter. För mer information besök www.datanumen.com