2 snabba sätt att exportera listan över alla flaggade Outlook-e-postmeddelanden till Excel

Om du vill exportera listan över alla flaggade e-postmeddelanden från din Outlook-postlåda till Excel kan du använda någon av de två metoderna som delas i den här artikeln.

Till exempel, för att hantera alla flaggade e-postmeddelanden mer lägligt eller dela dem med någon annan, kan du hoppas att exportera dem till ett Excel-kalkylblad. Här kommer vi att introducera 2 metoder för att förverkliga det. Den förra använder standardfunktionen "Importera och exportera" efter att ha hittat flaggade e-postmeddelanden. För att vara ärlig så är det lite tråkigt. Så i den senare kommer vi att lära dig ett bekvämare sätt som tillämpar VBA.

Exportera listan över alla flaggade Outlook-e-postmeddelanden till Excel

Metod 1: Exportera alla hittade flaggade e-postmeddelanden manuellt

  1. Först av allt, klicka i sökrutan ovanför e-postlistan.
  2. Klicka sedan på "Alla postförsändelser" i gruppen "Omfattning" på fliken "Sök".
  3. Klicka sedan på knappen "Flaggad" i gruppen "Definiera".Sök efter flaggade e-postmeddelanden
  4. Efter alla flaggade e-postmeddelanden som visas i listan, välj ett e-postmeddelande och tryck på "Ctrl + A" för att välja dem alla.
  5. Tryck sedan på "Ctrl + Shift + V" genvägar.
  6. Skapa en ny mapp under Outlook-filen i den nya dialogrutan.Skapa en ny mapp
  7. Välj senare den nya skapade mappen och klicka på "OK", vilket kommer att flytta alla hittade flaggade e-postmeddelanden till den nya mappen.Flytta alla flaggade e-postmeddelanden till den nya mappen
  8. Klicka sedan på "Arkiv"> "Öppna"> "Importera",
  9. I popup-dialogrutan väljer du “Exportera till en fil” > “Nästa” > “Microsoft Excel 97-2003” > “Nästa”.Exportera till en fil
  10. På den nya skärmen väljer du rätt mapp och trycker på "Nästa".Välj mapp att exportera från
  11. Följ sedan guiderna för att slutföra "Exportera".
  12. Du kommer att få en ny Excel-fil, som visas som följande skärmdump.Exporterad Excel-fil

Metod 2: Exportera listan över alla flaggade e-postmeddelanden via VBA

  1. I Outlook, tryck på "Alt + F11" för att aktivera VBA-redigeraren.
  2. Aktivera sedan "MS Excel Object" i enlighet med "Hur man lägger till en objektbiblioteksreferens i VBA".
  3. Kopiera sedan VBA-koden nedan till en modul.
Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllFlaggedEmailsToExcel()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
  
    'Select a source PST file
    Set objOutlookFile = Outlook.Application.Session.PickFolder
 
    If Not (objOutlookFile Is Nothing) Then
       'Create a new Excel file
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
       objExcelApp.Visible = True
 
       With objExcelWorksheet
           .Cells(1, 1) = "Subject"
           .Cells(1, 1).Font.Bold = True
           .Cells(1, 2) = "Start Date"
           .Cells(1, 2).Font.Bold = True
           .Cells(1, 3) = "Due Date"
           .Cells(1, 3).Font.Bold = True
           .Cells(1, 4) = "From"
           .Cells(1, 4).Font.Bold = True
           .Cells(1, 5) = "To"
           .Cells(1, 5).Font.Bold = True
      End With
 
      For Each objFolder In objOutlookFile.Folders
          If objFolder.DefaultItemType = olMailItem Then
             Call ProcessMailFolders(objFolder)
          End If
      Next
 
      objExcelWorksheet.Columns("A:E").AutoFit

      MsgBox "Completed!", vbInformation + vbOKOnly, "Export Emails"
    End If
End Sub

Sub ProcessMailFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objFlaggedMail As Outlook.MailItem
    Dim nLastRow As Integer
    Dim objSubfolder As Outlook.Folder
 
    For i = 1 To objCurrentFolder.Items.Count
        If objCurrentFolder.Items(i).Class = olMail Then
           'Export the information of each flagged email to Excel
           Set objMail = objCurrentFolder.Items(i)
           If objMail.IsMarkedAsTask = True And objMail.FlagStatus <> olFlagComplete Then
              Set objFlaggedMail = objMail
 
              With objExcelWorksheet
                   nLastRow = .Range("A" & .Rows.Count).End(xlUp).Row + 1
                   .Range("A" & nLastRow) = objFlaggedMail.Subject
                   .Range("B" & nLastRow) = objFlaggedMail.TaskStartDate
                   .Range("C" & nLastRow) = objFlaggedMail.TaskDueDate
                   .Range("D" & nLastRow) = objFlaggedMail.SenderName
                   .Range("E" & nLastRow) = objFlaggedMail.To
              End With
          End If
        End If
    Next i
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessMailFolders(objSubfolder)
       Next
    End If
End Sub

VBA-kod - Exportera listan över alla flaggade e-postmeddelanden

  1. Sätt slutligen markören i subrutinen "ExportAllFlaggedEmailsToExcel" och tryck på "F5"-knappen.
  2. Välj sedan en Outlook-fil i den nya dialogrutan.Välj Outlook-fil
  3. När du får "Completed"-prompten får du också en ny Excel-fil, som bilden nedan.Exporterade Excel-fil via VBA

Skydda din Outlook från korruption

Outlook är benäget för fel och korruption, så det är en mycket mödosam uppgift för oss att skydda våra Outlook-data. Det mest effektiva och praktiska sättet är utan tvekan att göra regelbundna säkerhetskopior av data för Outlook. Utöver det är det också nödvändigt för oss att få tag på ett kraftfullt och pålitligt Outlook-fixeringsverktyg, till exempel DataNumen Outlook Repair. Det kommer väl till pass om verktyg för reparation av inkorgen ger ingen effekt.

Författarintroduktion:

Shirley Zhang är expert på dataåterställning DataNumen, Inc., som är världsledande inom teknik för återställning av data, inklusive fast SQL Server och Outlook-programvara för reparationsprogramvara. För mer information besök www.datanumen.com

Kommentarer är stängda.