2 Metoder för att snabbt skicka valda celler i ett Excel-kalkylblad som en Outlook-e-post

Ibland kanske du snabbt vill infoga de markerade cellerna i ett Excel-kalkylblad till ett Outlook-e-postmeddelande och skicka ut det här e-postmeddelandet. Denna artikel kommer att titta på denna önskan att erbjuda dig två metoder.

Min tidigare artikel “2 Snabbmetoder för att skicka ett Excel-kalkylblad som ett Outlook-e-postmeddelande”Har lärt dig hur du skickar ett helt Excel-kalkylblad som e-post. Ibland vill du dock bara skicka de markerade cellerna i ett kalkylblad som ett e-postmeddelande. Som svar på detta krav kommer vi att avslöja dig två metoder. Du kan välja antingen enligt dina önskemål.

Metod 1: Kopiera valda celler till e-post manuellt

1. Till att börja med, öppna källfilen i Excel och få åtkomst till rätt Excel-kalkylblad.
2. Välj sedan cellerna som du vill skicka som ett e-postmeddelande i Outlook.
3. Tryck sedan på “Ctrl + C” genvägar för att kopiera de markerade cellerna.
4. Starta sedan din Outlook-applikation efter det.
5. Därefter klickar du på knappen "Ny e-post" i menyn "Hem" för att skapa en ny Outlook-e-post.
6. Senare i det nya meddelandefönstret klickar du på avsnittet med meddelandetexten.
7. Och tryck sedan på “Ctrl + V” -tangenterna för att klistra in de tidigare kopierade valda Excel-cellerna.
8. Slutligen kan du skriva e-postmeddelandet som vanligt och klicka på "Skicka" -knappen för att skicka ut det.

Metod 2: Skicka valda celler som e-post via VBA

1. Från början öppnar du källarbetsboken för Excel.
2. Tryck sedan på “Alt + F11” -knapparna för att komma åt Excel VBA-redigeraren.
3. I det nya fönstret klickar du på "Infoga"> "Modul" för att infoga en ny modul.
4. Nästa steg är att aktivera Microsoft Outlook-objektet. Klicka på "Verktyg" > "Referenser". I popup-dialogrutan som visas, leta upp och markera "Microsoft Outlook-objektbibliotek".
5. Kopiera därefter följande VBA-kod till den här modulen.

Sub SendSelectedCells_inOutlookEmail()
    Dim objSelection As Excel.Range
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempHTMLFile As String
    Dim objTempHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objOutlookApp As Outlook.Application
    Dim objNewEmail As Outlook.MailItem
 
    'Copy the selection
    Set objSelection = Selection
    Selection.Copy
 
    'Paste the copied selected ranges into a temp worksheet
    Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
    Set objTempWorksheet = objTempWorkbook.Sheets(1)
 
    'Keep the values, column widths and formats in pasting
    With objTempWorksheet.Cells(1)
         .PasteSpecial xlPasteValues
         .PasteSpecial xlPasteColumnWidths
         .PasteSpecial xlPasteFormats
    End With
 
    'Save the temp worksheet as a HTML file
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempHTMLFile = objFileSystem.GetSpecialFolder(2).Path & "\Temp for Excel" & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".htm"
    Set objTempHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strTempHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
    objTempHTMLFile.Publish (True)
 
    'Create a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objNewEmail = objOutlookApp.CreateItem(olMailItem)
 
    'Read the HTML file data and insert into the email body
    Set objTextStream = objFileSystem.OpenTextFile(strTempHTMLFile)
    objNewEmail.HTMLBody = objTextStream.ReadAll
    objNewEmail.Display
    'You can specify the new email recipients, subjects here using the following lines:
    'objNewEmail.To = "johnsmith@datanumen.com"
    'objNewEmail.Subject = "DataNumen Products"
    'objNewEmail.Send --> directly send out this email
 
    objTextStream.Close
    objTempWorkbook.Close (False)
    objFileSystem.DeleteFile (strTempHTMLFile)
End Sub

6. Så småningom kan du prova.

• Välj först de specifika cellerna som vanligt.
• Gå sedan tillbaka till det nya makrot och tryck på F5-tangenten för att utlösa det.
• Omedelbart visas ett nytt Outlook-e-postmeddelande där du kan se att de valda cellerna har infogats i e-postkroppen, som följande skärmdump:

PST-fil är samma sårbar som Excel-fil

Som vi vet är Excel-filer och Word-dokument benägna att korrumperas. Detsamma gäller för PST-filer, som innehåller alla objekt i din Outlook-inkorg. Så det är en mödosam uppgift att säkra dina PST-data. En av de mest effektiva åtgärderna är att säkerhetskopiera filen regelbundet. Dessutom, för att ge omedelbar räddning, bör du förbereda ett erfaret verktyg, till exempel DataNumen Outlook Repair, som kan återställa Outlook data utan att svettas.

Författarintroduktion:

Shirley Zhang är expert på dataåterställning DataNumen, Inc., som är världsledande inom teknik för återställning av data, inklusive reparera mdf och Outlook-programvara för reparationsprogramvara. För mer information besök www.datanumen.com