Jak szybko wydrukować wszystkie załączniki obrazu wiadomości e-mail programu Outlook tylko na jednej stronie

Aby oszczędzać atrament i papier do drukarek, niektórzy użytkownicy chcą wydrukować wszystkie obrazy dołączone do wiadomości e-mail tylko na jednej stronie, zamiast jednego obrazu na stronę. Teraz w tym artykule przedstawimy sposób na jego realizację.

Jak wszyscy wiemy, drukowanie obrazów to marnowanie atramentu do drukarki. Dlatego, aby oszczędzać atrament i papier do drukarki, być może wolisz drukować wiele załączników graficznych na tej samej stronie zamiast drukować obrazy na osobnych stronach. Chociaż Outlook nie oferuje takiej funkcji, nadal możesz to osiągnąć za pomocą następujących środków.

Drukuj wszystkie załączniki z obrazami wiadomości e-mail programu Outlook tylko na jednej stronie

1. Na początek uruchom aplikację Outlook.
2. Następnie w oknie programu Outlook naciśnij przyciski klawiszy „Alt + F11”.
3. Następnie przejdziesz do okna „Microsoft Visual Basic for Applications”, w którym musisz najpierw włączyć „Bibliotekę obiektów Microsoft Word”.
4. Następnie musisz otworzyć moduł, który nie jest używany.
5. Następnie skopiuj i wklej następujący kod VBA do tego modułu.

Sub PrintAllImageAttachmentsOnOnePage()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim objTempMail As Outlook.MailItem
    Dim objTempDocument As Word.Document
    Dim objWordApp As Word.Application
    Dim strImage As String
    Dim objImage As Word.InlineShape
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objSourceMail = ActiveInspector.currentItem
           Case olExplorer
                Set objSourceMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    If Not (objSourceMail Is Nothing) Then
       'Create a temp mail
       Set objTempMail = Outlook.Application.CreateItem(olMailItem)
       objTempMail.Display
       Set objTempDocument = objTempMail.GetInspector.WordEditor
       Set objWordApp = objTempDocument.Application
 
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.attachments
           'Get the Image attachments, instead of inserted Images
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                          strImage = "E:\" & objAttachment.filename
                          objAttachment.SaveAsFile strImage
 
                          'Insert the images into the temp mail
                          Set objImage = objWordApp.Selection.InlineShapes.AddPicture(filename:=strImage, LinkToFile:=False, SaveWithDocument:=True)
                          objWordApp.Selection.TypeText Text:=" "
 
                          'shrink the images to insure that they are on one page
                          objImage.ScaleHeight = 20
                          objImage.ScaleWidth = 20
 
                          Kill strImage
             End Select
           End If
       Next
 
       objTempMail.PrintOut
       objTempMail.Close olDiscard
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

6. Później możesz wrócić do listy e-mail. Wybierz lub otwórz wiadomość e-mail, której załączniki ze zdjęciami chcesz wydrukować.
7. Następnie uruchom to makro. W bieżącym oknie makra wystarczy nacisnąć klawisz „F5” lub kliknąć ikonę „Uruchom” na pasku narzędzi.
8. Wreszcie, gdy makro zakończy działanie, wszystkie załączniki obrazu źródłowej wiadomości e-mail zostaną wydrukowane na jednej stronie, jak na poniższym zrzucie ekranu:

Radzenie sobie z uszkodzonymi plikami programu Outlook

Ponieważ coraz więcej danych jest przechowywanych w programie Outlook, plik programu Outlook jest coraz bardziej podatny na ataki. Może zostać naruszona z powodu różnych czynników wewnętrznych i zewnętrznych. Ponadto trudno jest przewidzieć uszkodzenie programu Outlook. Tak więc, co możesz zrobić, to zapewnić natychmiastową i skuteczną pomoc w przypadku uszkodzenia programu Outlook. Na przykład musisz zachować specjalizację Naprawa PST narzędzie, takie jak DataNumen Outlook Repair w pobliżu. Będzie skanować i przywracać uszkodzone pliki jak bryza.

Wprowadzenie autora:

Shirley Zhang jest ekspertem w dziedzinie odzyskiwania danych w DataNumen, Inc., która jest światowym liderem w technologiach odzyskiwania danych, w tym wyzdrowieć Sql Server i oprogramowanie do naprawy programu Outlook. po więcej informacji odwiedź www.datanumen.com