Jak szybko wyeksportować informacje o rozmiarze wszystkich folderów w pliku PST do pliku Excel

Jeśli chcesz sprawdzić informacje o rozmiarze każdego folderu w pliku PST, możesz skorzystać z metody przedstawionej w tym artykule. Szybko wyeksportuje informacje o rozmiarze wszystkich folderów w pliku PST do pliku Excel.

Jeśli plik PST jest zbyt duży, możesz chcieć sprawdzić rozmiar każdego folderu. Pomoże Ci łatwo zorientować się, które z nich są większe i odpowiednio zarchiwizować na podstawie rozmiaru. Ogólnie, aby sprawdzić rozmiar folderu, wystarczy kliknąć folder prawym przyciskiem myszy, a następnie wybrać „Właściwości”. W nowym wyskakującym oknie dialogowym możesz kliknąć przycisk „Rozmiar folderu”. Jednakże, jeśli utworzyłeś wiele folderów, ręczne sprawdzanie informacji o rozmiarze jeden po drugim jest dość kłopotliwe. Jeśli więc chcesz zbiorczo uzyskać informacje o rozmiarze wszystkich folderów w pliku PST, możesz użyć następującego kodu VBA. Wyeksportuje wszystkie nazwy folderów i informacje o rozmiarze do pliku Excel za jednym razem.

Wyeksportuj informacje o rozmiarze wszystkich folderów w pliku PST do pliku Excel

1. Na początek uruchom aplikację Outlook.
2. Następnie przejdź do zakładki „Programista” i kliknij przycisk „Visual Basic” lub naciśnij klawisze „Alt + F11”, aby uzyskać dostęp do edytora VBA.
3. Następnie w oknie „Microsoft Visual Basic for Applications” otwórz moduł, który nie jest używany.
4. Następnie skopiuj i wklej następujące kody VBA do tego modułu.

Dim strExcelFile As String
Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportFodlerSizetoExcel()
    Dim objSourcePST As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
    objExcelWorksheet.Cells(1, 1) = "Folder"
    objExcelWorksheet.Cells(1, 2) = "Size"
 
    'Select a source PST file
    Set objSourcePST = Outlook.Application.Session.PickFolder

    For Each objFolder In objSourcePST.Folders
        Call ProcessFolders(objFolder)
    Next
 
    'Fit the columns from A to B
    objExcelWorksheet.Columns("A:B").AutoFit
 
    strExcelFile = "E:\Outlook\" & objSourcePST.Name & " Folder Size (" & Format(Now, "yyyy-mm-dd hh-mm-ss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim objItem As Object
    Dim lCurrentFolderSize As Long
    Dim nNextEmptyRow As Integer
 
    objCurrentFolder.Items.SetColumns ("Size")
    For Each objItem In objCurrentFolder.Items
        lCurrentFolderSize = lCurrentFolderSize + objItem.Size
    Next
 
    'Convert byte to kilobyte
    'To convert to megabyte, use:
    'lCurrentFolderSize = (lCurrentFolderSize / 1024) / 1024
    lCurrentFolderSize = lCurrentFolderSize / 1024
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1

    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = objCurrentFolder.FolderPath
    objExcelWorksheet.Range("B" & nNextEmptyRow) = lCurrentFolderSize & " KB"
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

5. Następnie należy ustawić poziom bezpieczeństwa makr programu Outlook na niski.
6. W końcu możesz spróbować.

• Naciśnij klawisz F5 w bieżącym oknie makra.
• Następnie zostaniesz poproszony o wybranie pliku PST, takiego jak poniższy obraz:
• Po wybraniu pliku źródłowego program Outlook rozpocznie eksportowanie informacji o rozmiarze do programu Excel.
• Po zakończeniu działania makra otrzymasz komunikat podobny do zrzutu ekranu poniżej.
• Wreszcie, będziesz mógł znaleźć plik Excela w predefiniowanym folderze lokalnym. Plik Excel będzie wyglądał następująco:

Radzić sobie z częstymi błędami PST

Ponieważ program Outlook jest podatny na błędy, być może kiedykolwiek napotkałeś wiele problemów z programem Outlook. Aby lepiej i bardziej elastycznie radzić sobie z frustrującymi problemami z PST, zaleca się posiadanie w pobliżu doświadczonego i renomowanego narzędzia naprawczego, takiego jak DataNumen Outlook Repair. Jest w stanie naprawić PST problemy jak bryza.

Wprowadzenie autora:

Shirley Zhang jest ekspertem w dziedzinie odzyskiwania danych w DataNumen, Inc., która jest światowym liderem w technologiach odzyskiwania danych, w tym SQL Server regeneracja i oprogramowanie do naprawy programu Outlook. po więcej informacji odwiedź www.datanumen.com