Jak szybko wyeksportować wiadomość e-mail programu Outlook jako plik obrazu

Niektórzy użytkownicy chcieliby wyeksportować wiadomość e-mail programu Outlook jako plik obrazu, na przykład plik jpg. Dlatego w tym artykule przedstawimy, jak uzyskać to za pomocą kodu VBA programu Outlook.

Musiałeś nauczyć się różnych sztuczek dotyczących eksportowania wiadomości e-mail jako pliku tekstowego, dokumentu programu Word i tak dalej. A co powiesz na eksport wiadomości e-mail jako obrazu, takiego jak plik JPG? Najwyraźniej Outlook nie ma tej funkcji. Ale później udostępnimy Ci szybkie środki.

Szybko wyeksportuj wiadomość e-mail programu Outlook jako plik obrazu

1. Na początek uruchom aplikację Outlook.
2. Następnie w głównym oknie Outlooka uzyskaj dostęp do edytora VBA zgodnie z artykułem - „Jak uruchomić kod VBA w swoim Outlooku".
3. Następnie włącz „Bibliotekę obiektów MS Word” i „MS PowerPoint „Biblioteka obiektów” odnosząc się do artykułu – „Jak dodać odwołanie do biblioteki obiektów w języku VBA".
4. Następnie skopiuj i wklej następujący kod VBA do pustego modułu.

Sub ExportEmailAsImage()
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim strWordDocument As String
    Dim objWordApp As Word.Application
    Dim objWordDocument As Word.Document
    Dim objDocumentRange As Word.Range
    Dim objPowerPointApp As PowerPoint.Application
    Dim objPresentation As PowerPoint.Presentation
    Dim objShape As PowerPoint.Shape
 
    On Error Resume Next
    'Export the email as Word document
    Set objMail = Outlook.Application.ActiveExplorer.Selection(1)
    strFileName = Replace(objMail.Subject, "/", " ")
    strFileName = Replace(strFileName, "\", " ")
    strFileName = Replace(strFileName, ":", "")
    strFileName = Replace(strFileName, "?", " ")
    strFileName = Replace(strFileName, Chr(34), " ")
    strWordDocument = Environ("Temp") & "\" & strFileName & ".doc"
 
    objMail.SaveAs strWordDocument, olDoc

    Set objWordApp = CreateObject("Word.Application")
    Set objWordDocument = objWordApp.Documents.Open(strWordDocument)
    objWordApp.Visible = True
 
    objWordApp.Selection.Find.ClearFormatting
    objWordApp.Selection.Find.Replacement.ClearFormatting
 
    With objWordApp.Selection.Find
        .Text = "^p^p"
        .Replacement.Text = "^p"
        .Wrap = wdFindContinue
    End With
 
    'Insert the document into a PowerPoint Presentation slide as an object
    objWordApp.Selection.Find.Execute Replace:=wdReplaceAll
    Set objDocumentRange = objWordDocument.Range()
    objDocumentRange.Font.Name = "Calibri"
    objDocumentRange.Font.Size = 10
    objWordDocument.Close True
    objWordApp.Quit
 
    Set objPowerPointApp = CreateObject("PowerPoint.Application")
    Set objPresentation = objPowerPointApp.Presentations.Add
    objPowerPointApp.Visible = msoTrue
 
    With objPresentation
        .PageSetup.SlideHeight = 792
        .PageSetup.SlideWidth = 612
        .Slides.AddSlide 1, .SlideMaster.CustomLayouts(1)
    End With
 
    'Export the slide
    With objPresentation.Slides(1)
         Set objShape = .Shapes.AddOLEObject(0, 0, 612, 792, , strWordDocument)
        .Export "E:\Email_" & strFileName & ".jpg", "JPG"
    End With
 
    objPresentation.Saved = msoTrue
    objPresentation.Close
    objPowerPointApp.Quit
End Sub

5. Następnie musisz dodać makro do paska narzędzi szybkiego dostępu.
6. Następnie możesz zamknąć edytor VBA.
7. Później wybierz wiadomość e-mail i naciśnij przycisk makra na pasku narzędzi Szybki dostęp.
8. Po zakończeniu działania makra możesz przejść do wstępnie zdefiniowanego folderu lokalnego, aby znaleźć wyeksportowany plik obrazu z tej wiadomości e-mail.

Pobierz dane programu Outlook z uszkodzonego pliku

Może to być bardzo frustrujące, jeśli Twój plik Outlooka ulegnie poważnemu uszkodzeniu. W takim przypadku będziesz musiał wyodrębnić dane Outlooka z zainfekowanego pliku. Niektórzy użytkownicy będą korzystać z narzędzia do naprawy skrzynki odbiorczej. Jednak w większości przypadków nie przyniesie to żadnych efektów. Dlatego lepiej mieć solidny i niezawodny… Poprawka PST narzędzie, takie jak DataNumen Outlook Repair. Może przeskanować uszkodzony plik i odzyskać maksymalną ilość danych bez żadnych kłopotów.

Wprowadzenie autora:

Shirley Zhang jest ekspertem w dziedzinie odzyskiwania danych w DataNumen, Inc., która jest światowym liderem w technologiach odzyskiwania danych, w tym poprawka mdf i oprogramowanie do naprawy programu Outlook. po więcej informacji odwiedź www.datanumen.com