Jak zapobiec wysyłaniu wiadomości e-mail na określony adres e-mail w programie Outlook

Wielu użytkowników ma nadzieję zablokować przypadkowe wysyłanie wiadomości e-mail na określony adres e-mail w Outlooku. Dlatego w tym artykule przedstawimy metodę jego realizacji.

Outlook nie oferuje natywnych funkcji blokowania wysyłania wiadomości e-mail na określony adres. Dlatego, aby to zrobić, konieczne jest napisanie odrobiny skryptu. W dalszej części podzielimy się takim fragmentem kodu VBA. Jeśli nie wiesz, jak korzystać z VBA, możesz przeczytać poprzedni wpis – „Jak uruchomić kod VBA w swoim Outlooku".

Zapobiegaj wysyłaniu wiadomości e-mail na określony adres e-mail

1. Najpierw otwórz edytor VBA programu Outlook za pomocą „Alt + F11”.
2. Następnie umieść następujący kod w projekcie „ThisOutlookSession”.

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    Dim objMail As Outlook.MailItem
    Dim objRecipients As Outlook.Recipients
    Dim ContactGroupFound As Boolean
    Dim i, n As Long
    Dim objRecipient As Outlook.Recipient
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Expand the contact groups in Recipients
       ContactGroupFound = True
       Do While ContactGroupFound = True
          Set objRecipients = objMail.Recipients
          ContactGroupFound = False
 
          For i = objRecipients.Count To 1 Step -1
              If objRecipients(i).AddressEntry.DisplayType <> olUser Then
                 For n = 1 To objRecipients(i).AddressEntry.Members.Count
                     If objRecipients(i).AddressEntry.Members.Item(n).DisplayType = olUser Then
                        objMail.Recipients.Add (objRecipients(i).AddressEntry.Members.Item(n).Address)
                     Else
                        objMail.Recipients.Add (objRecipients(i).AddressEntry.Members.Item(n).Name)
                        ContactGroupFound = True
                     End If
                 Next
                 objRecipients(i).Delete
              End If
          Next i
          objRecipients.ResolveAll
       Loop
 
       'Remove specific email address
       For Each objRecipient In objRecipients
           If objRecipient.Address = "shelly@datanumen.com" Then
              If MsgBox("Do you want to email to " & Chr(34) & "shelly@datanumen.com" & Chr(34) & "?", vbExclamation + vbYesNo) = vbNo Then
                 objRecipient.Delete
              End If
           End If
       Next
    End If
End Sub

3. Następnie zamknij okno „Microsoft Visual Basic for Applications”.
4. Ostatecznie spróbuj wykonać następujące czynności.

• Na początek napisz wiadomość e-mail i podaj odbiorców.
• Następnie kliknij przycisk „Wyślij”.
• Od razu makro będzie działać, aby rozszerzyć grupy kontaktów w odbiorcach, jeśli istnieją, i dowiedzieć się, czy odbiorcy zawierają określony adres e-mail.
• Jeśli adres zostanie znaleziony, otrzymasz wiadomość, jak pokazano na poniższym rysunku.
• Jeśli wybierzesz „Nie”, określony adres e-mail zostanie natychmiast usunięty.
• Po wysłaniu wiadomości możesz sprawdzić jej odbiorców, którzy na pewno nie zawierają konkretnego adresu e-mail.

Napraw uszkodzony plik programu Outlook

Czy Twój plik Outlooka kiedykolwiek uległ uszkodzeniu? To bez wątpienia najbardziej irytujący problem w Outlooku. Kiedy się z nim zmagasz, musisz manipulować Naprawa PST, który jest nieco zawiły. Jak zwykle pomyślisz o użyciu Scanpst po raz pierwszy. Ale niestety w takich przypadkach może się to nie udać. Twój ośrodek powinien być albo bardziej doświadczonym narzędziem, jak DataNumen Outlook Repairlub profesjonalną usługę odzyskiwania plików PST.

Wprowadzenie autora:

Shirley Zhang jest ekspertem w dziedzinie odzyskiwania danych w DataNumen, Inc., która jest światowym liderem w technologiach odzyskiwania danych, w tym naprawa sql i oprogramowanie do naprawy programu Outlook. po więcej informacji odwiedź www.datanumen.com