Jak ustawić inny domyślny czas przypomnienia dla różnych rodzajów oflagowanych elementów w programie Outlook

Domyślnie program Outlook automatycznie użyje domyślnego czasu przypomnienia o zadaniach dla wszystkich rodzajów oflagowanych elementów. Jeśli jednak chcesz użyć innego czasu przypomnienia dla oflagowanych przedmiotów w zależności od typu przedmiotu, możesz skorzystać z metody przedstawionej w tym artykule.

Program Outlook umożliwia ustawienie domyślnego czasu przypomnienia dla wszystkich oflagowanych elementów, niezależnie od typu elementu. Możesz przejść do menu „Plik” i kliknąć „Opcje”. Następnie w oknie „Opcje programu Outlook” możesz zobaczyć opcję „Domyślny czas przypomnienia” na karcie „Zadania”, jak pokazano na poniższym zrzucie ekranu.

Niemniej jednak większość użytkowników liczy na różne godziny przypomnienia dla różnych rodzajów oznaczonych elementów, na przykład „9:00” dla oznaczonych wiadomości e-mail i „17:30” dla oznaczonych kontaktów. W dalszej części skupimy się na tym przykładzie, aby przedstawić metodę.

Ustaw inny domyślny czas przypomnienia dla różnych rodzajów oflagowanych przedmiotów

1. Na początek uruchom aplikację Outlook.
2. Następnie uzyskaj dostęp do edytora Outlook VBA w odniesieniu do „Jak uruchomić kod VBA w swoim Outlooku".
3. W kolejnym oknie „Microsoft Visual Basic for Applications” skopiuj poniższy kod do projektu „ThisOutlookSession”.

Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objMail As Outlook.MailItem
Public WithEvents objContact As Outlook.ContactItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    ElseIf TypeOf objExplorer.Selection.Item(1) Is ContactItem Then
       Set objContact = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
    ElseIf Inspector.CurrentItem.Class = olContact Then
       Set objContact = Inspector.CurrentItem
    End If
End Sub

Private Sub objMail_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objMail.IsMarkedAsTask = True Then
          If objMail.TaskDueDate <> "1/1/4501" Then
             With objMail
                  .ReminderSet = True
                  'Change the reminder time for flagged emails
                  .ReminderTime = objMail.TaskDueDate & " 10:00"
                  .Save
             End With
          End If
       End If
    End If
End Sub

Private Sub objContact_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objContact.IsMarkedAsTask = True Then
          If objContact.TaskDueDate <> "1/1/4501" Then
             With objContact
                  .ReminderSet = True
                  'Change the reminder time for flagged contacts
                  .ReminderTime = objContact.TaskDueDate & " 17:30"
                  .Save
             End With
          End If
       End If
    End If
End Sub

4. Następnie uruchom ponownie program Outlook, aby aktywować tę makroinstrukcję.
5. Od teraz za każdym razem, gdy oznaczysz wiadomość e-mail, czas przypomnienia zostanie ustawiony na „10:00” w dniu wymagalności flagi.
6. A kiedy oznaczysz kontakt, czas przypomnienia zostanie ustawiony na „17:30” w terminie oznaczenia.

Elastycznie rozwiązuj problemy z programem Outlook

W programie Outlook mogą pojawić się różnego rodzaju problemy. Dlatego musisz nauczyć się, jak sobie z nimi radzić. Na przykład, jeśli Outlook często się restartuje, musisz naprawić pakiet Office lub wyłączyć dodatki innych firm itd. Jeśli Twój plik PST programu Outlook zostanie naruszony, możesz najpierw wypróbować narzędzie do naprawy skrzynki odbiorczej. Gdy to się nie powiedzie, możesz nadal korzystać z potężnego narzędzia zewnętrznego, takiego jak DataNumen Outlook Repair.

Wprowadzenie autora:

Shirley Zhang jest ekspertem w dziedzinie odzyskiwania danych w DataNumen, Inc., która jest światowym liderem w technologiach odzyskiwania danych, w tym odzyskiwanie mdf i oprogramowanie do naprawy programu Outlook. po więcej informacji odwiedź www.datanumen.com