Jak automatycznie używać różnych kolorów czcionek do odpowiadania i przekazywania wiadomości e-mail za pomocą programu Outlook VBA

Domyślnie Outlook nie może automatycznie używać różnych kolorów czcionek do odpowiadania i przesyłania dalej wiadomości e-mail. Dlatego jeśli masz taką potrzebę, przeczytaj ten post, aby poznać inteligentne podejście.

Outlook pozwala tylko na określenie czcionki używanej zarówno do odpowiadania, jak i przekazywania wiadomości e-mail. Możesz przejść do „Plik”> „Opcje”. Następnie w „Opcje programu Outlook” przejdź do zakładki „Poczta” i kliknij przycisk „Papeteria i czcionki…”. W kolejnym oknie możesz zobaczyć przycisk „Czcionka” w „Odpowiadanie lub przekazywanie wiadomości”. Kliknij go, a następnie możesz ustawić określony kolor czcionki do odpowiadania i przekazywania wiadomości e-mail.

Jednak wielu użytkowników ma nadzieję na używanie różnych kolorów czcionek do odpowiadania lub przekazywania wiadomości e-mail. Chociaż Outlook nie zapewnia żadnych bezpośrednich funkcji do tego, nadal można to zrealizować za pomocą kodu VBA. Teraz przeczytaj, aby uzyskać taki fragment kodu VBA.

Automatycznie używaj różnych kolorów czcionek do odpowiadania i przekazywania wiadomości e-mail

1. Na początek uruchom aplikację Outlook.
2. Następnie uruchom edytor VBA w odniesieniu do „Jak uruchomić kod VBA w swoim Outlooku".
3. Następnie, zgodnie z „Jak dodać odwołanie do biblioteki obiektów w języku VBA„, dodaj odniesienie do „Biblioteki obiektów MS Word”.
4. Następnie skopiuj następujący kod do projektu „ThisOutlookSession”.

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Dim objReply As Outlook.MailItem
    Dim objReplyDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReply = objMail.Reply
    objReply.Display
    Set objReplyDoc = objReply.GetInspector.WordEditor
    objReplyDoc.Range(0, 0).Select
    Set objDocSelection = objReplyDoc.Application.Selection
    'Use "Pink" font in "Reply"
    objDocSelection.Font.ColorIndex = wdPink
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objReplyAll As Outlook.MailItem
    Dim objReplyAllDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReplyAll = objMail.ReplyAll
    objReplyAll.Display
    Set objReplyAllDoc = objReplyAll.GetInspector.WordEditor
    objReplyAllDoc.Range(0, 0).Select
    Set objDocSelection = objReplyAllDoc.Application.Selection
    'Use "Green" font in "Reply All"
    objDocSelection.Font.ColorIndex = wdGreen
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objForward As Outlook.MailItem
    Dim objForwardDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objForward = objMail.Forward
    objForward.Display
    Set objForwardDoc = objForward.GetInspector.WordEditor
    objForwardDoc.Range(0, 0).Select
    Set objDocSelection = objForwardDoc.Application.Selection
    'Use "Blue" font in Forward
    objDocSelection.Font.ColorIndex = wdBlue
End Sub

5. Następnie uruchom ponownie program Outlook, aby aktywować tę makroinstrukcję.
6. Wreszcie możesz spróbować.

• Wybierz lub otwórz wiadomość e-mail.
• Następnie kliknij przycisk „Odpowiedz”. Odpowiadając na e-mail, możesz wpisać treść niektórych słów. Kolor czcionki musi być różowy.
• Lub kliknij przycisk „Odpowiedz wszystkim”. W nowej wiadomości „odpowiadającej na wszystkie” wprowadź słowa w treści. Kolor czcionki jest z pewnością zielony.
• Podobnie kliknij przycisk „Przekaż dalej”. W wiadomości przekazującej nowe słowa będą wyświetlane na niebiesko.

Skorzystaj z niezawodnego oprogramowania

W wypadku Uszkodzenie programu OutlookWiększość użytkowników korzysta z oprogramowania do odzyskiwania danych z Outlooka. Na rynku dostępnych jest wiele takich programów. Niektóre z nich są nawet darmowe. Należy jednak uważać na te z nieznanych źródeł, ponieważ mogą one pogorszyć sytuację. Warto skorzystać z niezawodnego i sprawdzonego narzędzia, takiego jak DataNumen Outlook Repair.

Wprowadzenie autora:

Shirley Zhang jest ekspertem w dziedzinie odzyskiwania danych w DataNumen, Inc., która jest światowym liderem w technologiach odzyskiwania danych, w tym uszkodzony plik sql i oprogramowanie do naprawy programu Outlook. po więcej informacji odwiedź www.datanumen.com