Jak automatycznie ustawić inny czas przypomnienia o spotkaniach programu Outlook w różnych kategoriach kolorów

Jeśli klasyfikujesz spotkania programu Outlook według kategorii oznaczonych kolorami i chcesz ustawić inny czas przypomnienia o spotkaniach w różnych kategoriach oznaczonych kolorami, zapoznaj się z tym artykułem. Tutaj nauczymy Cię, jak to zrealizować za pomocą programu Outlook VBA.

Na przykład dzielisz spotkania na dwie grupy. Jedna jest oznaczona kolorem „Poza siedzibą”, ponieważ miejsce spotkania jest zbyt daleko, a druga jest oznaczona kolorem „Na miejscu”, ponieważ miejsce spotkania znajduje się tutaj. Teraz chcesz, aby Outlook automatycznie ustawiał przypomnienie o spotkaniu „poza siedzibą” na godzinę przed rozpoczęciem, a o spotkaniu „na miejscu” na 15 minut przed rozpoczęciem. Przyjrzymy się temu wymogowi, a następnie przedstawimy prostą metodę.

Automatycznie ustaw różne przypomnienia o spotkaniach w różnych kategoriach kolorów

1. Na początek uruchom aplikację Outlook.
2. Następnie naciśnij klawisze „Alt + F11”, aby uzyskać dostęp do okna edytora VBA.
3. Następnie w kolejnym oknie skopiuj i wklej poniższy kod VBA do projektu „ThisOutlookSession”.

Public WithEvents objCalendar As Outlook.Folder
Public WithEvents objCalendarItems As Outlook.Items

Private Sub Application_Startup()
    Set objCalendar = Outlook.Application.Session.GetDefaultFolder(olFolderCalendar)
    Set objCalendarItems = objCalendar.Items
End Sub

Private Sub objCalendarItems_ItemAdd(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub objCalendarItems_ItemChange(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub SetReminder_BasedOnCategories(ByVal objCalendarItem As Object)
    Dim objMeeting As Outlook.AppointmentItem
    Dim strCategories As String
 
    If objCalendarItem.Class = olAppointment Then
       'Check if the item is a meeting
       If objCalendarItem.MeetingStatus = olMeeting Then
          Set objMeeting = objCalendarItem
          strCategories = objMeeting.Categories
 
          'Set Reminder as 60 min before start for offsite appointments
          If InStr(strCategories, "Offsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 60
                 .Save
             End With
             'Set Reminder as 15 min before start for onsite appointments
          ElseIf InStr(strCategories, "Onsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 15
                 .Save
             End With
          End If
       End If
    End If
End Sub

4. Następnie należy kliknąć podprogram „Application_Startup” i nacisnąć klawisz „F5”, aby uruchomić tę makroinstrukcję.
5. Od tego czasu za każdym razem, gdy nowe spotkanie zostanie dodane do domyślnego kalendarza lub zmienisz istniejące spotkanie, program Outlook automatycznie sprawdzi kategorie spotkania i automatycznie ustawi inny czas przypomnienia.

Eliminacja błędów programu Outlook

Od czasu do czasu w programie Outlook mogą pojawiać się różne problemy. Dlatego niezwykle ważne jest, aby użytkownicy nauczyli się radzić sobie z problemami z Outlookiem. Na początek warto regularnie tworzyć kopie zapasowe danych Outlooka. Ponadto, jeśli to możliwe, zaleca się przechowywanie kopii zapasowej. Naprawa programu Outlook narzędzie w pobliżu, takie jak DataNumen Outlook Repair. Może przeskanować plik PST, aby wykryć problemy z programem Outlook, a następnie z łatwością je rozwiązać.

Wprowadzenie autora:

Shirley Zhang jest ekspertem w dziedzinie odzyskiwania danych w DataNumen, Inc., która jest światowym liderem w technologiach odzyskiwania danych, w tym odzyskiwanie sql i oprogramowanie do naprawy programu Outlook. po więcej informacji odwiedź www.datanumen.com