Jak automatycznie rejestrować całkowitą liczbę przychodzących wiadomości e-mail każdego dnia w pliku Excel

Z tego artykułu dowiesz się, jak pozwolić programowi Outlook automatycznie policzyć, ile wiadomości e-mail otrzymałeś każdego dnia i zapisać liczbę w pliku Excel.

Wielu użytkowników musi policzyć całkowitą liczbę wiadomości e-mail otrzymanych każdego dnia. Ponadto, w celu wygodniejszego sprawdzania w przyszłości, wielu jest przyzwyczajonych do zapisywania całkowitej liczby w pliku Excel. W takim przypadku możesz oczywiście zdecydować się na codzienne liczenie i nagrywanie ręcznie. Jest to jednak trochę kłopotliwe. Czasami możesz o tym zapomnieć. Dlatego musisz chcieć poręcznej metody, dzięki której Outlook będzie to robił automatycznie. W odpowiedzi na to wymaganie nauczymy Cię, jak używać VBA, aby go zrealizować w dalszej części.

Automatycznie rejestruj całkowitą liczbę przychodzących wiadomości e-mail każdego dnia w pliku Excel

1. Na samym początku uruchom aplikację Outlook.
2. Następnie naciśnij skróty klawiszowe „Alt + F11” w głównym oknie Outlooka.
3. Następnie w wyskakującym oknie edytora VBA otwórz projekt „ThisOutlookSession”.
4. Następnie skopiuj i wklej następujące kody VBA do tego projektu.

Private Sub Application_Reminder(ByVal Item As Object)
    If Item.Class = olTask And Item.Subject = "Update Email Count" Then
       Call GetAllInboxFolders
    End If
End Sub

Private Sub GetAllInboxFolders()
    Dim objInboxFolder As Outlook.Folder
    Dim strExcelFile As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nNextEmptyRow As Integer
    Dim lEmailCount As Long
 
    lEmailCount = 0
    Set objInboxFolder = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Call UpdateEmailCount(objInboxFolder, lEmailCount)
 
    ‘Change the path to the Excel file
    strExcelFile = "E:\Email\Email Count.xlsx"
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Open(strExcelFile)
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = nNextEmptyRow - 1
    objExcelWorksheet.Range("B" & nNextEmptyRow) = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
    objExcelWorksheet.Range("C" & nNextEmptyRow) = lEmailCount
 
    'Fit the columns from A to C
    objExcelWorksheet.Columns("A:C").AutoFit
   
    'Save the changes and close the Excel file
    objExcelWorkbook.Close SaveChanges:=True
End Sub

Private Sub UpdateEmailCount(objFolder As Outlook.Folder, ByRef lCurEmailCount As Long)
    Dim objItems As Outlook.Items
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim strDay As String
    Dim strReceivedDate As String
    Dim lEmailCount As Long
    Dim objSubFolder As Outlook.Folder
 
    Set objItems = objFolder.Items
 
    objItems.SetColumns ("ReceivedTime")
    strDay = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
 
    For Each objItem In objItems
        If objItem.Class = olMail Then
           Set objMail = objItem
           strReceivedDate = Year(objMail.ReceivedTime) & "-" & Month(objMail.ReceivedTime) & "-" & Day(objMail.ReceivedTime)
           If strReceivedDate = strDay Then
              lCurEmailCount = lCurEmailCount + 1
           End If
        End If
    Next
 
    'Process the subfolders in the folder recursively
    If (objFolder.Folders.Count > 0) Then
       For Each objSubFolder In objFolder.Folders
           Call UpdateEmailCount(objSubFolder, lCurEmailCount)
       Next
    End If
End Sub

5. Następnie podpisz ten kod i zmień ustawienia makr programu Outlook, aby zezwolić na podpisane makra.
6. Następnie musisz codziennie tworzyć powtarzające się zadanie.

• Najpierw kliknij przycisk „Nowe zadanie” w panelu Zadania.
• W wyskakującym oknie Nowe zadanie kliknij przycisk „Powtarzanie”.
• Następnie w kolejnym oknie dialogowym wybierz „Codziennie”, „Co 1 dzień (dni)” i „Brak daty końcowej” i na koniec naciśnij „OK”.
• Później zmień temat zadania i przypomnienie zgodnie ze swoimi potrzebami.
• Na koniec kliknij przycisk „Zapisz i zamknij”.

7. Odtąd za każdym razem, gdy przypomni się o tym zadaniu, program Outlook będzie automatycznie liczyć wiadomości e-mail otrzymane wczoraj, a następnie zapisywać liczbę w pliku Excel, jak na poniższym zrzucie ekranu:

Ucieczka przed trwałą utratą danych PST

Nikt nie jest skłonny zaakceptować trwałej utraty danych PST. Jednak plik PST programu Outlook jest podatny na uszkodzenie. Dlatego należy podjąć wystarczające środki ostrożności, takie jak tworzenie spójnych i aktualnych kopii zapasowych danych PST oraz utrzymywanie potężnego pliku Odzyskiwanie PST narzędzie w pobliżu, np DataNumen Outlook Repair.

Wprowadzenie autora:

Shirley Zhang jest ekspertem w dziedzinie odzyskiwania danych w DataNumen, Inc., która jest światowym liderem w technologiach odzyskiwania danych, w tym naprawa sql i oprogramowanie do naprawy programu Outlook. po więcej informacji odwiedź www.datanumen.com