Jak automatycznie zastosować kategorie wiadomości e-mail do wszystkich jej odpowiedzi i wiadomości przesyłanych dalej w programie Outlook

Odpowiadając lub przekazując wiadomość e-mail, możesz zastosować te same kategorie. W tym artykule nauczymy Cię, jak to zrealizować za pomocą kodu VBA.

Jeśli jesteś przyzwyczajony do przypisywania tych samych kategorii oznaczonych kolorami oryginalnych wiadomości e-mail do wszystkich odpowiedzi i wiadomości przesyłanych dalej, dlaczego nie pozwolisz programowi Outlook osiągnąć tego automatycznie? Mimo że program Outlook nie zapewnia tak bezpośredniej funkcji, nadal można ją uzyskać za pomocą kodu VBA. Poniżej przedstawimy szczegółowe kroki i kod.

Automatycznie stosuj kategorie wiadomości e-mail do wszystkich jej odpowiedzi i wiadomości przesyłanych dalej

1. Na samym początku uruchom aplikację Outlook.
2. Następnie naciśnij klawisze „Alt + F11”, aby uruchomić edytor VBA programu Outlook.
3. Następnie skopiuj następujący kod VBA do projektu „ThisOutlookSession”.

Private WithEvents objExplorer As Outlook.Explorer
Private WithEvents objInspectors As Outlook.Inspectors
Private WithEvents objMail As Outlook.MailItem
Private strCategories As String

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
       strCategories = objMail.Categories
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
       strCategories = objMail.Categories
    End If
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call CopyCategories(Forward)
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Call CopyCategories(Response)
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call CopyCategories(Response)
End Sub

Private Sub CopyCategories(ByVal objNewMail As Object)
    objNewMail.Categories = strCategories
End Sub

4. Następnie uruchom ponownie program Outlook, aby aktywować ten projekt.
5. Od tego czasu możesz to wypróbować, wykonując poniższe czynności.

• Po pierwsze, wybierz wiadomość e-mail i naciśnij przycisk „Przekaż dalej”.
• Następnie wyświetli się e-mail przekierowania, w którym możesz przejść do zakładki „Opcje” i kliknąć ikonę rozszerzenia w prawym dolnym rogu grupy „Więcej opcji”.
• Następnie w wyskakującym oknie dialogowym „Właściwości” widać, że ten e-mail ma przypisane te same kategorie kolorów, co oryginalny e-mail.

Napraw uszkodzony plik programu Outlook

Biorąc pod uwagę fakt, że Outlook jest podatny na ataki, musisz podjąć wiele działań, aby uniknąć utraty danych programu Outlook. Na przykład musisz okresowo tworzyć kopie zapasowe danych. Ponadto musisz uważać na nieznane wiadomości e-mail, w tym osadzone linki lub załączniki. Wreszcie, powinieneś zaopatrzyć się w doskonałe zewnętrzne narzędzie naprawcze, takie jak DataNumen Outlook Repair. Jest w stanie pomóc w odzyskaniu maksymalnej ilości danych z uszkodzony Outlook plik.

Wprowadzenie autora:

Shirley Zhang jest ekspertem w dziedzinie odzyskiwania danych w DataNumen, Inc., która jest światowym liderem w technologiach odzyskiwania danych, w tym SQL Server stały i oprogramowanie do naprawy programu Outlook. po więcej informacji odwiedź www.datanumen.com