2 sposoby drukowania list zadań programu Outlook z różnymi kategoriami na różnych stronach

Jeżeli przypisałeś zadania programu Outlook w różnych kategoriach kolorystycznych i teraz chcesz wydrukować listy zadań z różnymi kategoriami na różnych stronach, możesz zapoznać się z tym artykułem. Tutaj udostępnimy Ci 2 metody, aby to uzyskać.

Być może, aby klasyfikować i dobrze zarządzać swoimi zadaniami, zastosowałeś do swoich zadań kategorie kolorystyczne. Jeśli teraz chcesz wydrukować listy swoich zadań z różnymi kategoriami na różnych stronach, czytaj dalej. Poniżej przedstawimy Ci 2 sposoby, aby to zdobyć.

Metoda 1: Ręczne drukowanie list zadań pojedynczo

1. Najpierw w Outlooku przejdź do panelu „Zadania”.
2. Następnie otwórz folder Zadania.
3. Następnie naciśnij „Ctrl + E”, aby aktywować wstążkę „Wyszukaj”.
4. Następnie w zakładce „Wyszukaj” kliknij przycisk „Kategoryzuj”.
5. Z rozwijanej listy wybierz kategorię koloru.
6. Następnie na liście pozostaną tylko zadania z wybraną kategorią.
7. Teraz przejdź do „Plik” > „Drukuj”, aby wydrukować tę listę zadań.
8. Następnie w ten sam sposób wydrukuj ręcznie zestawienia zadań z pozostałymi kategoriami kolorystycznymi.

Metoda 2: Wydrukuj wsadowo listy zadań za pomocą VBA

1. Na samym początku uruchom edytor VBA zgodnie z „Jak uruchomić kod VBA w swoim Outlooku".
2. Następnie dodaj odniesienie do „Biblioteki obiektów MS Excel” zgodnie z „Jak dodać odwołanie do biblioteki obiektów w języku VBA".
3. Następnie skopiuj następujący kod VBA do modułu.

Sub PrintTaskList_SpecificColorCategory()
    Dim objTasks As Outlook.Items
    Dim objTask As Outlook.TaskItem
    Dim objDictionary As Object
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varKey As Variant
    Dim strKey As String
    Dim i As Long
    Dim bSheetFound As Boolean
    Dim nLastRow As Integer
    Dim objSheet As Excel.Worksheet
 
    Set objTasks = Application.Session.GetDefaultFolder(olFolderTasks).Items
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
     'Get All Tasks' Categories
    For Each objTask In objTasks
        arrCategory = Split(objTask.Categories, ",")
        For Each varCategory In arrCategory
            If objDictionary.Exists(Trim(varCategory)) = False Then
               objDictionary.Add Trim(varCategory), 0
            End If
        Next
    Next
 
    'Export the Tasks with Different Categories into Different Sheet in an Excel Workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    i = 0
    For Each varKey In objDictionary.Keys
        strKey = CStr(varKey)

        On Error Resume Next
        objExcelWorkbook.Sheets(strKey).Select
        bSheetFound = (Err = 0)
        On Error GoTo 0
        If bSheetFound = False Then
           i = i + 1
           If i < 4 Then
              Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
           Else
              Set objExcelWorksheet = objExcelWorkbook.Sheets.Add(After:=objExcelWorkbook.Sheets(objExcelWorkbook.Sheets.Count))
           End If
           objExcelWorksheet.Name = strKey
        End If
 
        With objExcelWorksheet
             .Cells(1, 1) = strKey
             .Cells(1, 1).Font.Bold = True
             .Cells(1, 1).Font.Size = 18
             .Cells(2, 1) = "Subject"
             .Cells(2, 1).Font.Bold = True
             .Cells(2, 2) = "Start Date"
             .Cells(2, 2).Font.Bold = True
             .Cells(2, 3) = "Due Date"
             .Cells(2, 3).Font.Bold = True
        End With
 
        For Each objTask In objTasks
            If InStr(objTask.Categories, strKey) > 0 Then
               nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
               With objExcelWorksheet
                    .Range("A" & nLastRow) = objTask.Subject
                    .Range("B" & nLastRow) = objTask.startDate
                    .Range("C" & nLastRow) = objTask.DueDate
               End With
            End If
        Next
 
        objExcelWorksheet.Columns("A:C").AutoFit
    Next
 
    'Print out All Sheets in this Excel Workbook
    For Each objSheet In objExcelWorkbook.Sheets
        objSheet.PrintOut
    Next
 
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

4. Następnie naciśnij przycisk klawisza „F5”, aby od razu uruchomić to makro.
5. Po zakończeniu makra listy zadań z różnymi kategoriami zostaną wydrukowane na różnych stronach, jak pokazano na poniższym zrzucie ekranu.

Odzyskaj cenne dane z zaatakowanego pliku PST

Jeśli masz niedostępny plik PST, następnym krokiem będzie niewątpliwie Naprawa PST. W takim przypadku możesz najpierw wypróbować narzędzie do naprawy skrzynki odbiorczej. Jeśli to się nie powiedzie, możesz spróbować innego zewnętrznego narzędzia, takiego jak DataNumen Outlook Repair. Jest w stanie szybko odzyskać dane PST.

Wprowadzenie autora:

Shirley Zhang jest ekspertem w dziedzinie odzyskiwania danych w DataNumen, Inc., która jest światowym liderem w technologiach odzyskiwania danych, w tym odzyskać mdf i oprogramowanie do naprawy programu Outlook. po więcej informacji odwiedź www.datanumen.com