Metody 2 do szybkiego liczenia wiadomości e-mail według nadawcy w programie Outlook

Jeśli chcesz policzyć wiadomości e-mail według nadawcy, możesz zapoznać się z tym artykułem. Tutaj przedstawimy Ci 2 szybkie podejścia.

Aby poznać najbardziej aktywnego nadawcę, możesz zliczyć wiadomości e-mail według nadawcy. Chociaż Outlook nie oferuje bezpośredniej funkcji do tego, nadal możesz poszukać obejść, takich jak Metoda 1. Jeśli uważasz, że Metoda 1 jest zbyt żmudna, możesz wybrać Metodę 2. Jest ona o wiele bardziej efektywna, ponieważ wykorzystuje VBA do szybkiego zliczania wiadomości e-mail według nadawcy i eksportowania wyników do Excela. Teraz przeczytaj szczegółowo o obu metodach. Tutaj weźmiemy za przykład wiadomości e-mail w Skrzynce odbiorczej.

Metoda 1: Zliczanie po zgrupowaniu elementów według pola „Od”

1. Na początek uruchom aplikację Outlook.
2. Następnie otwórz folder skrzynki odbiorczej.
3. Następnie przejdź do zakładki „Widok”.
4. Następnie wybierz „Od” w grupie „Aranżacja”.
5. Od razu wszystkie elementy skrzynki odbiorczej zostały podzielone na różne grupy zgodnie z różnymi nadawcami.
6. Teraz, aby policzyć przesyłki od określonego nadawcy, możesz zaznaczyć wszystkie przesyłki z powiązanej grupy i nacisnąć klawisz „Enter”. W wyskakującym ostrzeżeniu możesz zobaczyć liczbę.

Oznacza to, że jest to dość łatwe, ale liczba elementów w rzeczywistości obejmuje inne typy elementów, takie jak zaproszenia na spotkania, zlecenia zadań i pokwitowania, a nie tylko liczbę e-maili. Dlatego jeśli chcesz liczyć tylko wiadomości e-mail, możesz zamiast tego skorzystać z następującego sposobu.

Metoda 2: Policz wiadomości e-mail według nadawcy za pomocą programu Outlook VBA

1. Na początek naciśnij kombinację klawiszy „Alt + F11” w programie Outlook.
2. Następnie włącz „Bibliotekę obiektów MS Excel” zgodnie z „Jak dodać odwołanie do biblioteki obiektów w języku VBA".
3. Następnie skopiuj poniższy kod do nieużywanego modułu.

Sub CountInboxEmailsbySender()
    Dim objDictionary As Object
    Dim objInbox As Outlook.Folder
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim strSender As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varSenders As Variant
    Dim varItemCounts As Variant
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objInbox = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
 
    For i = objInbox.Items.Count To 1 Step -1
        If objInbox.Items(i).Class = olMail Then
           Set objMail = objInbox.Items(i)
           strSender = objMail.SenderEmailAddress
 
           If objDictionary.Exists(strSender) Then
              objDictionary.Item(strSender) = objDictionary.Item(strSender) + 1
           Else
              objDictionary.Add strSender, 1
           End If
        End If
    Next

    Set objExcelApp = CreateObject("Excel.Application")
    objExcelApp.Visible = True
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    With objExcelWorksheet
         .Cells(1, 1) = "Sender"
         .Cells(1, 2) = "Count"
    End With
 
    varSenders = objDictionary.Keys
    varItemCounts = objDictionary.Items
 
    For i = LBound(varSenders) To UBound(varSenders)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
        With objExcelWorksheet
             .Cells(nLastRow, 1) = varSenders(i)
             .Cells(nLastRow, 2) = varItemCounts(i)
        End With
    Next
 
    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

3. Następnie naciśnij klawisz „F5”.
4. Po zakończeniu działania makra zostanie wyświetlony nowy plik Excel.
5. Jak widać, zawiera liczbę wiadomości e-mail w skrzynce odbiorczej od różnych nadawców.

Pozbądź się frustrujących problemów z perspektywami

Być może kiedykolwiek napotkałeś wiele problemów w swoim Outlooku. Aby skutecznie im sprostać, możesz tęsknić za wszechstronnym i potężnym sposobem. Jednak w rzeczywistości nie ma takiej metody. Możesz uważać na własne operacje w Outlooku i regularnie tworzyć kopie zapasowe. Oczywiście, jeśli to możliwe, sugerujemy, abyś miał pod ręką doświadczone narzędzie naprawcze, takie jak DataNumen Outlook Repair. Może rozwiązać różne problemy z plikami PST i naprawić uszkodzony plik PST plik jak bryza.

Wprowadzenie autora:

Shirley Zhang jest ekspertem w dziedzinie odzyskiwania danych w DataNumen, Inc., która jest światowym liderem w technologiach odzyskiwania danych, w tym wyzdrowieć Sql Server i oprogramowanie do naprawy programu Outlook. po więcej informacji odwiedź www.datanumen.com