Metody 2 do zbiorczego usuwania wszystkich kontaktów bez adresu e-mail w programie Outlook

Jeśli zauważysz, że niektóre kontakty nie mają adresu e-mail w programie Outlook, możesz przetworzyć każdy folder kontaktów, aby usunąć wszystkie takie kontakty. To post podzieli się z tobą 2 środkami.

Być może masz wiele kontaktów w Outlooku, a niektóre z nich nie mają adresu e-mail. Jeśli uważasz, że nie są już przydatne, musisz mieć nadzieję na usunięcie wszystkich kontaktów bez adresu e-mail. W standardowy sposób można użyć funkcji „Wyszukiwanie błyskawiczne”, aby je znaleźć, a następnie usunąć ręcznie, tak jak w poniższej metodzie 1. Jest to jednak trochę uciążliwe. Dlatego w Metodzie 2 nauczymy Cię innego, bardziej efektywnego sposobu.

Metoda 1: Ręczne usuwanie po znalezieniu kontaktów bez adresu e-mail

1. Jaktart, naciśnij klawisze „Ctrl + 3”, aby uzyskać dostęp do panelu „Kontakty”.
2. Następnie kliknij pole wyszukiwania.
3. Następnie na pojawiającej się wstążce „Szukaj” kliknij „Wszystkie pozycje kontaktów”.
4. Następnie kliknij „Ma adres”> „Ma adres e-mail”.
5. Następnie w polu wyszukiwania zostanie dodane kryterium „NOT emailaddresses: = []”. Musisz usunąć „NIE”.
6. Następnie zostaną wymienione wszystkie kontakty bez adresu e-mail.
7. Teraz powinieneś ręcznie wybrać kontakty w wynikach wyszukiwania, ponieważ twoje grupy kontaktów również muszą znajdować się na liście.
8. Na koniec naciśnij przycisk „Del”, aby usunąć wszystkie wybrane kontakty.

Metoda 2: Wsadowe usuwanie wszystkich kontaktów bez adresu e-mail za pomocą VBA

1. Najpierw naciśnij „Alt + F11”, aby uruchomić edytor VBA w Outlooku.
2. Na nowym ekranie skopiuj następujący kod VBA do modułu.

Sub BatchDeleteAllContactsWithoutEmailAddress()
    Dim objStore As Outlook.Store
    Dim lTotalCount As Long
 
    lTotalCount = 0
    'Process all stores in your Outlook
    For Each objStore In Application.Session.Stores
       Call ProcessContactFolders(objStore.GetRootFolder.Folders, lTotalCount)
    Next
 
    MsgBox lTotalCount & " contacts are deleted!", vbInformation + vbOKOnly, "Delete Contacts"
End Sub

Sub ProcessContactFolders(ByVal objFolders As Outlook.Folders, lCount As Long)
    Dim objFolder As Outlook.Folder
    Dim i As Long
    Dim objContact As Outlook.ContactItem
    Dim objSubfolder As Outlook.Folder

    For Each objFolder In objFolders
        If (objFolder.DefaultItemType = olContactItem) And (objFolder.Name <> "Skype Contacts") Then
           For i = objFolder.Items.Count To 1 Step -1
               If objFolder.Items(i).Class = olContact Then
                  Set objContact = objFolder.Items(i)
                  'Delete the contact w/o email address
                  If (objContact.Email1Address = "") And (objContact.Email2Address = "") And (objContact.Email3Address = "") Then
                     objContact.Delete
                     lCount = lCount + 1
                  End If
               End If
           Next
 
           'Process subfolders recursively
           If objFolder.Folders.Count > 0 Then
              Call ProcessContactFolders(objFolder.Folders, lCount)
           End If
       End If
    Next
End Sub

3. Później kliknij podprocedurę „BatchDeleteAllContactsWithoutEmailAddress”.
4. Na koniec naciśnij „F5”, aby wywołać to makro.
5. Po zakończeniu otrzymasz wiadomość o wynikach, jak na poniższym obrazku.
6. Wszystkie kontakty bez adresu e-mail zostały przeniesione do folderu „Elementy usunięte”.

Unikaj wszelkich potencjalnych zagrożeń

Program Outlook może zostać uszkodzony z powodu różnych czynników, takich jak wirusy, błędy użytkownika, awarie oprogramowania, a także awarie sprzętu. Musisz być niechętny, aby doświadczyć uszkodzenia programu Outlook, więc musisz trzymać wszystkie te potencjalne zagrożenia na dystans. Na przykład musisz zainstalować silne oprogramowanie antywirusowe na swoim komputerze. Ponadto musisz regularnie tworzyć kopie zapasowe danych programu Outlook. Wreszcie, lepiej przygotuj solidne i niezawodne narzędzie naprawcze, takie jak DataNumen Outlook Repair. To może naprawić uszkodzony plik PST plik z łatwością.

Wprowadzenie autora:

Shirley Zhang jest ekspertem w dziedzinie odzyskiwania danych w DataNumen, Inc., która jest światowym liderem w technologiach odzyskiwania danych, w tym SQL Server korupcja i oprogramowanie do naprawy programu Outlook. po więcej informacji odwiedź www.datanumen.com