Hvordan batcheksportere flere Outlook-e-poster til ett Word-dokument via VBA

Outlook-løsninger September 29, 2025

Hvis du vil batcheksportere flere Outlook-e-poster til et enkelt word-dokument, kan du bruke VBA-koden vist i denne artikkelen. Det kan hjelpe deg med å utføre denne oppgaven i løpet av sekunder.

Jeg har noen gang introdusert hvordan du konverterer en Outlook-e-post til et Word-dokument i min forrige artikkel - "2 effektive metoder for å konvertere en Outlook-e-post til et Word-dokument". Imidlertid er begge de 2 midlene nevnt i den sost vil være hjelpeløs i tilfelle du ønsker å batcheksportere mange e-poster til ett Word-dokument. Derfor vil vi her lære deg en annen måte. Nå, les videre for å få det utførlig.

Batcheksporter flere Outlook-e-poster til ett Word-dokument via VBA

Batch-eksporter flere Outlook-e-poster til ett Word-dokument

  1. Til start med, start Outlook-programmet.
  2. Deretter, etter å ha gått inn i hovedvinduet i Outlook, må du trykke på "Alt + F11" -tastene.
  3. Deretter får du tilgang til Outlook VBA editor, der du bør åpne en tom modul.
  4. Kopier deretter VBA-koden nedenfor til det åpnede modulvinduet.
Sub ExportMultipleEmails_OneWordDocument()
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim objSelection As Outlook.Selection
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim objWordApp As Word.Application
    Dim objNewWordDocument As Word.Document
    Dim objWordRange As Word.Range
    Dim strWordDocument As String
    Dim i As Long
  
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp" & Format(Now, "YYYYMMDDhhmmss")
    MkDir (strTempFolder)
 
    On Error Resume Next
    'Save each selected email as an individual Word document in a temp folder
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
    For Each objMail In objSelection
        strFileName = objMail.Subject
 
        'Remove the unsupported characters in email subject
        strFileName = Replace(strFileName, "/", " ")
        strFileName = Replace(strFileName, "\", " ")
        strFileName = Replace(strFileName, ":", "")
        strFileName = Replace(strFileName, "?", " ")
        strFileName = Replace(strFileName, Chr(34), " ")
 
        objMail.SaveAs strTempFolder & "\" & strFileName & ".doc", olDoc
    Next
 
    'Merge all the Word documents into a single document
    Set objWordApp = CreateObject("Word.Application")
    Set objNewWordDocument = objWordApp.Documents.Add
 
    strWordDocument = Dir(strTempFolder & "\" & "*.doc")
    i = 0
    Do Until strWordDocument = ""
       i = i + 1
       Set objWordRange = objNewWordDocument.Range
       With objWordRange
           .Collapse wdCollapseEnd
           If i > 1 Then
             .InsertBreak wdSectionBreakNextPage
             .End = objNewWordDocument.Range.End
             .Collapse wdCollapseEnd
           End If
           .InsertFile strTempFolder & "\" & strWordDocument
      End With
      strWordDocument = Dir()
    Loop
 
    'Change the path as per your own needs
    objNewWordDocument.SaveAs "E:\Exported Emails " & Format(Now, "YYYY-MM-DD hh-mm-ss")
    objWordApp.Quit
 
    'Delete the temp folder
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

VBA-kode - Batch-eksporter flere Outlook-e-poster til ett Word-dokument

  1. Etter det er det bedre å legge til dette nye VBA-prosjektet til hurtigtilgangsverktøylinjen eller båndet.
  2. Til syvende og sist kan du prøve.
  • For det første, velg flere Outlook-e-poster.
  • Deretter finner og klikker du på den nylig lagt til makro-knappen.
  • Etter at du blir bedt om "Fullfør", kan du bla til den forhåndsdefinerte lokale mappen for å finne et nytt Word-dokument.
  • Åpne dette dokumentet, der du kan se alle de valgte e-postene er eksportert.

Hold et mektig gjenopprettingsverktøy i nærheten

Uavhengig av mange funksjoner, kan Outlook fortsatt ikke være immun mot feil. Hvis du er vant til å la feil være i fred, mens de hoper seg opp, vil Outlook-krasj oppstå definitivt. På det tidspunktet er det viktig å gå tilbake til et mektig og effektivt gjenopprettingsverktøy, som DataNumen Outlook Repair. Den er godt kjent med PST-fiks. Så lenge med det, trenger du ikke å være bekymret for tap av Outlook-data lenger.

Forfatterintroduksjon:

Shirley Zhang er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert ødelagt mdf og Outlook-reparasjonsprodukter. For mer informasjon besøk www.datanumen. Med

Kommentarer er stengt.