Hvordan raskt eksportere stemmestatistikk fra en Outlook-e-post til et Excel-regneark

Outlook-løsninger September 29, 2025

Hvis du har sendt en e-post med stemmeknapper, etter at mottakerne har sendt deg sine svar, kan det være lurt å telle og eksportere stemmestatistikken til et Excel-regneark. Så i denne sost, vil vi lære deg hvordan du oppnår det raskt.

Outlook er så kraftig at det til og med tilbyr en "Stemme"-funksjon. Min forrige artikkel "Dyktig bruk av MS Outlook for stemmegivning” har lært hvordan man kan bruke det effektivt. Også most etter å ha stemt, kan du fortsette å eksportere stemmestatistikken til et Excel-regneark av noen grunner, for eksempel ønsker å skrive ut statistikken. Men Outlook støtter ikke dette som standard. Derfor vil vi i det følgende lære deg hvordan du kan realisere dette som en kork.

Eksporter stemmestatistikk raskt fra en Outlook-e-post til et Excel-regneark

Eksporter stemmestatistikk i en e-post til et Excel-regneark

  1. Start Outlook-applikasjonen helt i begynnelsen.
  2. Deretter bør du trykke på "Alt + F11"-tastene i hovedvinduet i Outlook.
  3. Neste i "Microsoft Visual Basic for Applications"-vinduet, bør du aktivere "Microsoft Excel Object Library". Klikk "Verktøy"> "Referanse". I popup-dialogboksen merker du av i avmerkingsboksen foran "Microsoft Excel Object Library" og trykk "OK" til slutt.
  4. Etter det kan du sette inn en ny modul eller åpne en som ikke er i bruk.
  5. Deretter kopierer og limer du inn følgende VBA-koder i denne modulen.
Sub ExportVotingStatistics _Excel ()
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.recipient
    Dim objVoteDictionary As Object
    Dim varVotingCounts As Variant
    Dim varVotingOptions As Variant
    Dim varVotingOption As Variant
    Dim i As Long
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nRow As Integer
 
    Set objMail = Application.ActiveExplorer.Selection(1)
 
    'Create a new excel worksheet
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    'Fill in the predefined values
    With objExcelWorksheet
         .Cells.Font.Name = "Cambria"
         .Cells(1, 1) = "Voting Results for Email:"
         .Cells(1, 2) = Chr(34) & objMail.Subject & Chr(34)
         .Cells(3, 1) = "Voting Options"
         .Cells(3, 2) = "Voting Counts"
    End With
 
    Set objVoteDictionary = CreateObject("Scripting.Dictionary")
    'get the default voting options
    varVotingOptions = Split(objMail.VotingOptions, ";")
    'Add the voting responses to the dictionary
    For Each varVotingOption In varVotingOptions
        objVoteDictionary.Add varVotingOption, 0
    Next
    'Add a custom voting response - "No Reply"
    objVoteDictionary.Add "No Reply", 0
 
    'Process the all voting responses
    For Each objRecipient In objMail.Recipients
        If objRecipient.TrackingStatus = olTrackingReplied Then
           If objVoteDictionary.Exists(objRecipient.AutoResponse) Then
              objVoteDictionary.Item(objRecipient.AutoResponse) = objVoteDictionary.Item(objRecipient.AutoResponse) + 1
           Else
              objVoteDictionary.Add objRecipient.AutoResponse, 1
           End If
        Else
           objVoteDictionary.Item("No Reply") = objVoteDictionary.Item("No Reply") + 1
        End If
    Next
 
    'Get the voting options and vote counts
    varVotingOptions = objVoteDictionary.Keys
    varVotingCounts = objVoteDictionary.Items
 
    'Fill in the values in specific cells
    nRow = 4
    For i = LBound(varVotingOptions) To UBound(varVotingOptions)
        With objExcelWorksheet
             .Cells(nRow, 1) = varVotingOptions(i)
             .Cells(nRow, 2) = varVotingCounts(i)
        End With
        nRow = nRow + 1
    Next
 
    'Save the new Excel file
    objExcelWorksheet.Columns("A:B").AutoFit
    strExcelFile = "E:\Voting Results " & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

VBA-kode - Eksporter stemmestatistikk fra en Outlook-e-post til et Excel-regneark

  1. Etter det, for enkel tilgang, bør du legge til den nye makroen til Quick Access Toolbar.
  2. Til slutt kan du prøve.
  • Først velger du en kilde-e-post som inneholder stemmeknapper.
  • Klikk deretter på makroknappen i verktøylinjen for hurtigtilgang.
  • Etter at denne makroen er ferdig, kan du bla til den forhåndsdefinerte lokale mappen, der du vil se en ny Excel-arbeidsbok.
  • Åpne denne Excel-arbeidsboken. Nå vil du se stemmestatistikken, vist som bildet nedenfor:Eksportert stemmestatistikk

Ingen kan avverge Outlook-feil grundig

Selv om Outlook er utstyrt med en rekke funksjoner, er det ingen slik funksjon som hjelper oss å unngå Outlook-feil. Alle slags faktorer kan forårsake Outlook-feil. For eksempel, hvis du ofte avslutter Outlook på feil måte, vil du sannsynligvis lide PST-korrupsjon. I et slikt scenario har du ikke noe annet valg enn å bruke noen kraftige verktøy for å redde PST-filen, som DataNumen Outlook Repair. Den har fått mye honnør på grunn av sin høye utvinningsgrad.

Forfatterintroduksjon:

Shirley Zhang er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert korrupt mdf og Outlook-reparasjonsprodukter. For mer informasjon besøk www.datanumen. Med

Kommentarer er stengt.