Slik flytter du e-postene automatisk med spesifikke CC-mottakere i Outlook

Outlook-løsninger September 29, 2025

I virkeligheten håper de fleste av dere kanskje å opprette en Outlook-regel for å automatisk flytte e-poster med spesifikke CC-mottakere. Men Outlook-regelen støtter ikke kontroll av CC-mottakere. Så denne artikkelen vil lære deg hvordan du realiserer det med Outlook VBA.

Det er åpenbart umulig for deg å lage en Outlook-regel for å søke etter bestemte CC-mottakere. Som vist i følgende skjermbilde, for mottatte e-poster, kan du bare sjekke om ditt eget navn er i CC-boksen. På samme måte, for sendte e-poster, er det ingen regelbetingelse for å merke av CC-boksen.Ingen betingelser for å se etter CC-mottaker

Derfor, hvis du ønsker å konfigurere Outlook til å flytte e-postene med spesifikke CC-mottakere automatisk, må du søke andre måter. Deretter. her vil vi lære deg hvordan du oppnår det ved hjelp av Outlook VBA.

Flytt de sendte e-postene automatisk med spesifikke CC-mottakere

  1. Gå først til "Utvikler" -fanen og klikk på "Visual Basic" -knappen.
  2. Åpne deretter "ThisOutlookSession" -prosjektet og kopier følgende VBA-koder inn i det.
Public WithEvents olItems As Outlook.Items

Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderSentMail).Items
End Sub

Sub olItems_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       MoveMail Item
    End If
End Sub

Sub MoveMail(Mail As Outlook.MailItem)
    Dim ccRecip As String
    Dim desFolder As Folder
 
    'Replace "test" with your desired CC'd recipient name or address
    ccRecip = "test"
    'The "Test" folder is a subfolder under "Sent Items" folder
    Set desFolder = Session.GetDefaultFolder(olFolderSentMail).Folders("Test")
 
    If InStr(LCase(Mail.CC), ccRecip) > 0 Then
       Mail.Move desFolder
    End If
End Sub

Flytt de sendte e-postene automatisk med spesifikke CC-mottakere

  1. Deretter bør du fortsette med å signere denne koden og endre makroinnstillingene som vanlig.
  2. Til slutt kan du gå ut av "Visual Basic"-vinduet. Deretter vil e-postene med de spesifikke CC-mottakerne bli flyttet til den angitte e-postmappen.

Flytt mottatte e-poster automatisk med spesifikke CC-mottakere

Nå som den ovennevnte VBA-koden er rettet mot å flytte sendte e-poster med spesifikke CC-mottakere, hvis du vil se etter spesifikke CC-mottakere i mottatte e-poster og deretter flytte den, bør du bruke følgende koder i stedet.

Public WithEvents olItems As Outlook.Items

Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Sub olItems_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       MoveMail Item
    End If
End Sub

Sub MoveMail(Mail As Outlook.MailItem)
    Dim Recips As Recipients
    Dim Recip As Recipient
    Dim ccRecip As String
    Dim desFolder As Folder
 
    Set Recips = Mail.Recipients
    'Replace "test" with the specific words in your desired CC recipient address
    ccRecip = "test"
 
    For Each Recip In Recips
        If Recip.Type = olCC Then
           If InStr(LCase(Recip.Address), ccRecip) > 0 Then
              'The "Test" folder is a subfolder under "Inbox" folder
              Set desFolder = Session.GetDefaultFolder(olFolderInbox).Folders("Test")
              Mail.Move desFolder
           End If
        End If
    Next
End Sub

Flytt mottatte e-poster automatisk med spesifikke CC-mottakere

Hold deg godt forberedt på Outlook-korrupsjon

Selv om Outlook er rikt på funksjoner, kan det fortsatt ikke være immun mot korrupsjon. Så du bør være på vakt mot alle potensielle risikoer. Det kritiske trinnet må utvilsomt være å lage en konsistent og oppdatert sikkerhetskopi for Outlook-data. Videre bør du beholde en korrupt Outlook gjenopprettingsverktøy i nærheten. Det vil være nyttig hvis både sikkerhetskopiene og Scanpst.exe mislykkes.

Forfatterintroduksjon:

Shirley Zhang er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert reparasjon SQL Server mdf-fil feil og Outlook-reparasjonsprodukter. For mer informasjon besøk www.datanumen. Med

Kommentarer er stengt.