3 måter å få ordtellingsstatistikk relatert til tekstbokser, fotnoter og sluttnoter i dokumentet ditt

I dagens artikkel er det 3 raske måter å få ordtellingsstatistikk knyttet til tekstbokser, fotnoter og sluttnoter i dokumentet ditt.

Det er ikke vanskelig å få det totale antallet ord i et dokument. Men hvis du ønsker å få antall ord av forskjellige typer tekster, vil flere operasjoner være nødvendig. Følgende er 3 metoder. Les videre for å se hva du kan bruke. 

Metode 1: Telle ord inkludert tekster fra tekstbokser, fotnoter og sluttnoter

Som standard teller Word alle ord som vises i dokumentet, inkludert tekster i tekstbokser og ord fra fotnoter og sluttnoter.

1. Først og fremstost, gå til statuslinjen og klikk på «Ord» for å åpne «Ordtelling»-boksen.
2. Der vil du se all slags statistikk. Sørg for at du har merket av for "Inkluder tekstbokser, fotnoter og sluttnoter".
3. Klikk deretter på "Lukk".
4. Hvis du ikke finner "Words"-kommandoen på statuslinjen, høyreklikk der.
5. Sjekk deretter "Ordtelling".

Metode 2: Ekskluder tekster fra tekstbokser, fotnoter og sluttnoter fra ordtelling

Dette er motsatt av metode 1. Så du trenger bare å fjerne merket for «Inkluder tekstbokser, fotnoter og sluttnoter»-boksen.

Metode 3: Kjør Word Macro for å få separat antall ord fra tekstbokser, fotnoter og sluttnoter

1. Først, utløs "Ordtelling"-boksen ved å bruke måten i metode 1 og sørg for at alternativboksen er merket.
2. Trykk deretter "Alt + F11" for å åpne VBA-redigering.
3. Sett deretter inn en ny modul i "Normal"-prosjektet ved å klikke på "Normal" først.
4. Og klikk "Sett inn" neste.
5. Velg deretter "Modul".
6. Dobbeltklikk på modulen for å åpne kodeområdet og lim inn følgende koder der:

Sub SeparateCountNumberOfTextboxFootnoteEndnote()
  Dim lTextboxWords As Long
  Dim lTextboxChars As Long
  Dim lDocumntWords As Long
  Dim lDocumntChars As Long
  Dim objTextboxShape As Shape
  Dim objTemp As Dialog
  Dim bDone As Boolean
  Dim objRange As Range
  Dim lFootnoteWords As Long
  Dim lFootnoteChars As Long
  Dim lEndnoteWords As Long
  Dim lEndnoteChars As Long
 
  Application.ScreenUpdating = False

 Do
   bDone = True
   For Each objTextboxShape In ActiveDocument.Shapes
     If objTextboxShape.Type = msoGroup Then
       objTextboxShape.Ungroup
       bDone = False
     End If
   Next objTextboxShape
 Loop Until bDone

 '  Count the words and characters in the whole document.
 Selection.HomeKey Unit:=wdStory
 Set objTemp = Dialogs(wdDialogToolsWordCount)
   objTemp.Update
   objTemp.Execute
   lDocumntWords = objTemp.Words
   lDocumntChars = objTemp.Characters
 
 With ActiveDocument
 '  Count the words and characters in all textboxes.
   lTextboxWords = 0
   lTextboxChars = 0
   If ActiveDocument.Shapes.Count > 0 Then
     For Each objTextboxShape In .Shapes
       objTextboxShape.Select
       objTemp.Execute
       lTextboxWords = lTextboxWords + objTemp.Words
       lTextboxChars = lTextboxChars + objTemp.Characters
     Next objTextboxShape
   Else
     MsgBox ("There is no text box in this document")
   End If

   '  Count the words and characters in all footnotes.
   lFootnoteWords = 0
   lFootnoteChars = 0
   If ActiveDocument.Footnotes.Count > 0 Then
     For Each objRange In .StoryRanges
       If objRange.StoryType = wdFootnotesStory Then
         objRange.Select
         objTemp.Execute
         lFootnoteWords = lFootnoteWords + objTemp.Words
         lFootnoteChars = lFootnoteChars + objTemp.Characters
       End If
     Next objRange
   Else
     MsgBox ("There is no footnote in this document")
   End If

   '  Count the words and characters in all endnotes. 
   lEndnoteWords = 0
   lEndnoteChars = 0
   If ActiveDocument.Endnotes.Count > 0 Then
     For Each objRange In .StoryRanges
       If objRange.StoryType = wdEndnotesStory Then
         objRange.Select
         objTemp.Execute
         lEndnoteWords = lEndnoteWords + objTemp.Words
         lEndnoteChars = lEndnoteChars + objTemp.Characters
       End If
     Next objRange
   Else
     MsgBox ("There is no Endnote in this document")
   End If
 End With
 
 Application.ScreenUpdating = True

 MsgBox (" In this document there are totally" & vbCr _
   & Str(lDocumntWords) & " word(s) and" & Str(lDocumntChars) & " characters" & vbCr & vbCr _
   & "Including:" & vbCr _
   & Str(ActiveDocument.Shapes.Count) & " textboxes contain(s)" & vbCr _
   & Str(lTextboxWords) & " word(s)," & Str(lTextboxChars) & " characters" & vbCr & vbCr _
   & Str(ActiveDocument.Footnotes.Count) & " footnotes contain(s)" & vbCr _
   & Str(lFootnoteWords) & " word(s)," & Str(lFootnoteChars) & " characters" & vbCr & vbCr _
   & Str(ActiveDocument.Endnotes.Count) & " Endnotes contain(s)" & vbCr _
   & Str(lEndnoteWords) & " word(s)," & Str(lEndnoteChars) & " characters")
End Sub

7. Til slutt klikker du på "Kjør"-knappen.

Hvis det ikke er noen tekstboks, fotnote eller sluttnote, vil du motta en meldingsboks som denne:

Bare klikk "OK" for å fortsette. Deretter vil du se en annen boks, som viser alle detaljer om ordtelling.

Skaff deg et gjenopprettingsverktøy

Siden Word plutselig kan kollapse, er det tilrådelig å skaffe et avansert reparasjonsprodukt for å gjøre fikseringsjobben. Et slikt verktøy kan være en stor besparelse for korrupte Word. Bruk derfor tid til å få en så snart som mulig.

Forfatterintroduksjon:

Vera Chen er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert fikse xls og pdf reparere programvareprodukter. For mer informasjon besøk www.datanumen. Med