როგორ სწრაფად ამობეჭდოთ ყველა ფაილი a Zip Outlook-ის ელფოსტის დანართი

Outlook Solutions სექტემბერი 29, 2025

ბევრი მომხმარებელი იმედოვნებს, რომ დაბეჭდოს ყველა ფაილი შეკუმშული a zip Outlook-ის ელფოსტის მიმაგრება პრობლემური შენახვისა და დეკომპრესიის გარეშე zip დანართი. აქედან გამომდინარე, ეს სტატია შემოგთავაზებთ ბევრად უფრო ეფექტურ საშუალებას მის რეალიზებისთვის.

როცა გსურთ დაბეჭდოთ ა zip დანართის შემთხვევაში, შესაძლოა მიჩვეული იყოთ მასზე ხატვას და ლენტში „სწრაფი ბეჭდვის“ ღილაკზე დაწკაპუნებას. თუმცა, ამ გზით, Outlook მაინც მოგთხოვთ მის შენახვას და გახსნას. თუ გსურთ თავიდან აიცილოთ ეს შემაწუხებელი ნაბიჯები, შეგიძლიათ გამოიყენოთ შემდეგი VBA კოდი.

დაბეჭდეთ ყველა ფაილი a Zip ელ.ფოსტის დანართი

დასაწყებად, გაუშვით თქვენი Outlook აპლიკაცია.
შემდეგ, მიიღეთ წვდომა Outlook VBA რედაქტორზე სტატიაში ნაჩვენები ნაბიჯების შემდეგ – ”როგორ გაუშვათ VBA კოდი თქვენს Outlook-ში".
შემდეგი, შეგიძლიათ გახსნათ „ThisOutlookSession“ პროექტი ან გამოუყენებელი მოდული.
შემდეგ დააკოპირეთ და ჩასვით ქვემოთ მოცემული VBA კოდი.

Dim objShell As Object
Dim objFileSystem As Object

Sub PrintAllFilesInZipAttachment ()
    Dim objAttachmentSelection As Outlook.AttachmentSelection
    Dim objAttachment, objTempAttachment As Outlook.Attachment
    Dim strTempFolder As String
    Dim strSavingPath As String
    Dim objTempMail As Outlook.MailItem
    Dim strFileName As String
 
    'Get selected attachment
    Set objAttachmentSelection = Outlook.Application.ActiveExplorer.AttachmentSelection
    Set objAttachment = objAttachmentSelection.Item(1)

    If Right(LCase(objAttachment.filename), 3) = "zip" Then
 
       'Save & Unzip the zip attachment
       Set objShell = CreateObject("Shell.Application")
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
       strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Unzip" & Format(Now, "yyyymmddhhmmss")
       MkDir (strTempFolder)
 
       strSavingPath = strTempFolder & "\" & objAttachment.filename
       objAttachment.SaveAsFile (strSavingPath)
       objShell.NameSpace((strTempFolder)).CopyHere objShell.NameSpace((strSavingPath)).Items
  
       'Attach Unzipped files to a temp mail
       Set objTempMail = Outlook.Application.CreateItem(olMailItem)
       objTempMail.Display
       strFileName = Dir(strTempFolder & "\")
 
       While Len(strFileName) > 0
             objTempMail.Attachments.Add (strTempFolder & "\" & strFileName)
             strFileName = Dir()
       Wend
 
       'Print all attachments of the temp email
       Call PrintFiles(objTempMail)
 
       objTempMail.Close olDiscard
 
       objFileSystem.DeleteFolder (strTempFolder)
    End If
End Sub

Sub PrintFiles(ByVal objMail As Outlook.MailItem)
    Dim objAttachment As Outlook.Attachment
    Dim strTempFolder, strFilePath As String
    Dim objTempFolder As Object
    Dim objTempFolderItem As Object
 
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\TEMP" & Format(Now, "yyyymmddhhmmss")
    MkDir (strTempFolder)
 
    'Print all attachments
    For Each objAttachment In objMail.Attachments
        If Right(LCase(objAttachment.filename), 3) <> "zip" Then
           strFilePath = strTempFolder & "\" & objAttachment.filename
           objAttachment.SaveAsFile (strFilePath)
 
           Set objShell = CreateObject("Shell.Application")
           Set objTempFolder = objShell.NameSpace(0)
           Set objTempFolderItem = objTempFolder.ParseName(strFilePath)
           objTempFolderItem.InvokeVerbEx ("print")
        End If
    Next
 
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

ამის შემდეგ, დახურეთ მიმდინარე VBA რედაქტორის ფანჯარა.
მოგვიანებით გადადით Outlook Options-ზე, რომ დაამატოთ ახალი მაკრო სწრაფი წვდომის ხელსაწყოთა ზოლში.
საბოლოოდ, შეგიძლიათ გადაიღოთ კადრი:

პირველ რიგში, აირჩიეთ ა zip ელ.ფოსტის დანართი.
შემდეგ დააწკაპუნეთ მაკროზე სწრაფი წვდომის ინსტრუმენტთა პანელში.

ერთდროულად, ფაილები შეკუმშულია შერჩეულში zip დანართი დაიბეჭდება.

Outlook მონაცემთა ფაილების სარეზერვო ასლის შექმნა

შესაძლოა აღმოაჩინეთ, რომ Outlook მიდრეკილია დაზიანებისკენ. Outlook-ის დაზიანების შემდეგ, თქვენი Outlook-ის მონაცემები დაიკარგება. ამიტომ, მნიშვნელოვანია თქვენი Outlook-ის მონაცემთა ფაილების რეგულარული სარეზერვო ასლის შექმნა, რათა Outlook-ის მონაცემების აღდგენა მარტივად შეძლოთ სარეზერვო ასლების მეშვეობით. თუმცა, თუ აღმოაჩენთ, რომ სარეზერვო ასლი რამდენიმე კვირის წინანდელია და არაეფექტურია, სხვა გზა არ გაქვთ, გარდა იმისა, რომ დაუკავშირდეთ სანდო და გამოცდილ სპეციალისტს. PST აღდგენა ინსტრუმენტი, როგორიცაა DataNumen Outlook Repair.

ავტორი შესავალი:

შირლი ჟანგი არის მონაცემთა აღდგენის ექსპერტი DataNumen, Inc., რომელიც მსოფლიო ლიდერია მონაცემთა აღდგენის ტექნოლოგიებში, მათ შორის დაზიანებული მდფ და Outlook სარემონტო პროგრამული პროდუქტები. დამატებითი ინფორმაციისთვის ეწვიეთ www.datanumen. ერთად