როგორ სწრაფად მოხდეს ხმის მიცემის სტატისტიკის ექსპორტი Outlook ელფოსტიდან Excel-ის სამუშაო ფურცელში

თუ თქვენ გააგზავნეთ ელფოსტა ხმის მიცემის ღილაკებით, მას შემდეგ, რაც მიმღებები გამოგიგზავნიან პასუხებს, შეგიძლიათ დათვალოთ და ექსპორტი გაუკეთოთ ხმის მიცემის სტატისტიკას Excel-ის სამუშაო ფურცელზე. ამ პოსტში ჩვენ გასწავლით, თუ როგორ მიაღწიოთ ამას სწრაფად.

Outlook იმდენად ძლიერია, რომ „ხმის მიცემის“ ფუნქციასაც კი სთავაზობს. ჩემი წინა სტატია "MS Outlook-ის ოსტატურად გამოყენება ხმის მიცემისთვის„ასწავლა, თუ როგორ გამოიყენოთ ის ეფექტურად. ასევე, უმეტეს შემთხვევაში, ხმის მიცემის შემდეგ, შეგიძლიათ გააგრძელოთ ხმის მიცემის სტატისტიკის ექსპორტი Excel-ის სამუშაო ფურცელზე რაიმე მიზეზით, მაგალითად, სტატისტიკის დაბეჭდვის სურვილის გამო. თუმცა, Outlook სტანდარტულად არ უჭერს მხარს ამას. ამრიგად, ქვემოთ ჩვენ გასწავლით, თუ როგორ გააკეთოთ ეს საცობის მსგავსად.

ხმის მიცემის სტატისტიკის ექსპორტი ელექტრონული ფოსტით Excel-ის სამუშაო ფურცელში

1. თავიდანვე გაუშვით თქვენი Outlook აპლიკაცია.
2. შემდეგ თქვენ უნდა დააჭიროთ "Alt + F11" ღილაკებს Outlook-ის მთავარ ფანჯარაში.
3. შემდეგ, „Microsoft Visual Basic for Applications“ ფანჯარაში უნდა ჩართოთ „Microsoft Excel Object Library“. დააწკაპუნეთ „Tools“ > „Reference“. შემდეგ, ამომხტარ დიალოგურ ფანჯარაში, მონიშნეთ „Microsoft Excel Object Library“-ის წინ არსებული ველი და ბოლოს დააწკაპუნეთ „OK“.
4. ამის შემდეგ შეგიძლიათ ჩადოთ ახალი მოდული ან გახსნათ გამოუყენებელი.
5. ამის შემდეგ, დააკოპირეთ და ჩასვით შემდეგი VBA კოდები ამ მოდულში.

Sub ExportVotingStatistics _Excel ()
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.recipient
    Dim objVoteDictionary As Object
    Dim varVotingCounts As Variant
    Dim varVotingOptions As Variant
    Dim varVotingOption As Variant
    Dim i As Long
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nRow As Integer
 
    Set objMail = Application.ActiveExplorer.Selection(1)
 
    'Create a new excel worksheet
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    'Fill in the predefined values
    With objExcelWorksheet
         .Cells.Font.Name = "Cambria"
         .Cells(1, 1) = "Voting Results for Email:"
         .Cells(1, 2) = Chr(34) & objMail.Subject & Chr(34)
         .Cells(3, 1) = "Voting Options"
         .Cells(3, 2) = "Voting Counts"
    End With
 
    Set objVoteDictionary = CreateObject("Scripting.Dictionary")
    'get the default voting options
    varVotingOptions = Split(objMail.VotingOptions, ";")
    'Add the voting responses to the dictionary
    For Each varVotingOption In varVotingOptions
        objVoteDictionary.Add varVotingOption, 0
    Next
    'Add a custom voting response - "No Reply"
    objVoteDictionary.Add "No Reply", 0
 
    'Process the all voting responses
    For Each objRecipient In objMail.Recipients
        If objRecipient.TrackingStatus = olTrackingReplied Then
           If objVoteDictionary.Exists(objRecipient.AutoResponse) Then
              objVoteDictionary.Item(objRecipient.AutoResponse) = objVoteDictionary.Item(objRecipient.AutoResponse) + 1
           Else
              objVoteDictionary.Add objRecipient.AutoResponse, 1
           End If
        Else
           objVoteDictionary.Item("No Reply") = objVoteDictionary.Item("No Reply") + 1
        End If
    Next
 
    'Get the voting options and vote counts
    varVotingOptions = objVoteDictionary.Keys
    varVotingCounts = objVoteDictionary.Items
 
    'Fill in the values in specific cells
    nRow = 4
    For i = LBound(varVotingOptions) To UBound(varVotingOptions)
        With objExcelWorksheet
             .Cells(nRow, 1) = varVotingOptions(i)
             .Cells(nRow, 2) = varVotingCounts(i)
        End With
        nRow = nRow + 1
    Next
 
    'Save the new Excel file
    objExcelWorksheet.Columns("A:B").AutoFit
    strExcelFile = "E:\Voting Results " & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

5. ამის შემდეგ, მოსახერხებელი წვდომისთვის, უმჯობესია დაამატოთ ახალი მაკრო Quick Access Toolbar-ში.
6. საბოლოოდ, შეგიძლიათ სცადოთ.

• პირველ რიგში, აირჩიეთ წყარო, რომელიც შეიცავს ხმის მიცემის ღილაკებს.
• შემდეგ დააჭირეთ მაკრო ღილაკს სწრაფი წვდომის ხელსაწყოთა ზოლში.
• ამ მაკროს გაშვების დასრულების შემდეგ, შეგიძლიათ დაათვალიეროთ წინასწარ განსაზღვრული ლოკალური საქაღალდე, რომელშიც ნახავთ Excel-ის ახალ სამუშაო წიგნს.
• გახსენით ეს Excel სამუშაო წიგნი. ახლა თქვენ იხილავთ ხმის მიცემის სტატისტიკას, რომელიც ნაჩვენებია ქვემოთ მოცემულ სურათზე:

არავის შეუძლია თავიდან აიცილოს Outlook შეცდომები საფუძვლიანად

მიუხედავად იმისა, რომ Outlook აღჭურვილია მრავალფეროვანი შესაძლებლობებით, არ არსებობს ისეთი ფუნქცია, რომელიც დაგვეხმარება Outlook-ის შეცდომების თავიდან აცილებაში. ყველა სახის ფაქტორმა შეიძლება გამოიწვიოს Outlook-ის შეცდომები. მაგალითად, თუ ხშირად გამოდიხართ Outlook-დან არასწორად, სავარაუდოდ დაზარალდებით PST კორუფცია. ასეთ სცენარში, თქვენ სხვა არჩევანი არ გაქვთ გარდა იმისა, რომ გამოიყენოთ რამდენიმე ძლიერი ინსტრუმენტი თქვენი PST ფაილის გადასარჩენად, როგორიცაა DataNumen Outlook Repair. აღდგენის მაღალი მაჩვენებლის გამო მან ბევრი ქება დაიმსახურა.

ავტორი შესავალი:

შირლი ჟანგი არის მონაცემთა აღდგენის ექსპერტი DataNumen, Inc., რომელიც მსოფლიო ლიდერია მონაცემთა აღდგენის ტექნოლოგიებში, მათ შორის კორუმპირებული mdf და Outlook სარემონტო პროგრამული პროდუქტები. დამატებითი ინფორმაციისთვის ეწვიეთ www.datanumen. ერთად