როგორ სწრაფად მოხდეს Outlook-ის ელფოსტის ყველა სურათის დანართის ექსპორტი Excel-ის სამუშაო ფურცელზე

Outlook Solutions სექტემბერი 29, 2025

თუ გსურთ სწრაფად გადაიტანოთ Outlook ელ.ფოსტის ყველა სურათის დანართი Excel-ის სამუშაო ფურცელზე, შეგიძლიათ მიმართოთ ამ სტატიას. აქ ჩვენ გაჩვენებთ უფრო ეფექტურ გზას, ვიდრე ხელით ექსპორტი.

როდესაც იღებთ ელფოსტას, რომელიც შეიცავს სურათების დიდ რაოდენობას დამატებულ ფაილებს, თუ გსურთ მათი გამოყენება Excel-ში ანგარიშის შესაქმნელად, უნდა მოძებნოთ გზა, რომლითაც შეგიძლიათ ამ სურათების ჯგუფურად ექსპორტირება Excel-ის სამუშაო ფურცელში. ახლა, ქვემოთ გაგაცნობთ ასეთ მიდგომას.

ელფოსტის ყველა სურათის დანართის ექსპორტი Excel-ის სამუშაო ფურცელში

დასაწყისისთვის, შედით თქვენს Outlook აპლიკაციაში ჩვეულებრივი გზით.
შემდეგ, Outlook-ის ფანჯარაში, დააჭირეთ ღილაკს "Alt + F11" კლავიშების მალსახმობებზე, რომლებიც გამოჩნდება "Microsoft Visual Basic აპლიკაციებისთვის" ფანჯარა.
ამ ეკრანზე, თქვენ უნდა გახსნათ მოდული, რომელიც არ გამოიყენება, ან პირდაპირ ჩადოთ ახალი.
შემდეგი, თქვენ უნდა დააკოპიროთ ქვემოთ მოცემული VBA კოდის ნაწილი ამ მოდულში.

Sub ExportAllImageAttachmentsToExcelWorksheet()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim strImage As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim objFile As Object
    Dim objFiles As Object
    Dim nRow As Integer
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objSourceMail = ActiveInspector.currentItem
           Case olExplorer
                Set objSourceMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    If Not (objSourceMail Is Nothing) Then
 
       'Save the image attachments to a temporary folder
       strTempFolder = Environ("Temp") & "\" & Format(Now, "yyyymmddhhmmss") & "\"
       MkDir (strTempFolder)
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.Attachments
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                          objAttachment.SaveAsFile strTempFolder & objAttachment.filename
              End Select
           End If
       Next
 
       'Create a new Excel workbook
        Set objExcelApp = CreateObject("Excel.Application")
        Set objExcelWorkbook = objExcelApp.Workbooks.Add
        Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
        objExcelApp.Visible = True
        objExcelWorkbook.Activate
 
        'Get the images in the temporary folder
        Set objFiles = objFileSystem.GetFolder(strTempFolder).Files
 
        'Insert the images into this new Excel worksheet
        For Each objFile In objFiles
            strImage = strTempFolder & Trim(objFile.Name)
            nRow = nRow + 1
            With objExcelWorksheet
                 .Range("A" & nRow).value = objFile.Name
                 'Change the height and width as per your needs
                 .Range("B" & nRow).ColumnWidth = 10
                 .Range("B" & nRow).RowHeight = 80
                 .Range("B" & nRow).Activate
                 With .Pictures.insert(strImage)
                      With .ShapeRange
                           .LockAspectRatio = msoTrue
                           .Width = 50
                           .Height = 70
                      End With
                 End With
                 .Columns("A").AutoFit
                 .Activate
            End With
       Next
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

ამის შემდეგ შეგიძლიათ გახვიდეთ მაკროდან.
შემდეგ, გადადით „ფაილი“ > „ოფციები“ > „სწრაფი წვდომის ხელსაწყოთა პანელი“, რომ დაამატოთ ეს მაკრო სწრაფი წვდომის ხელსაწყოთა ზოლში.
დაბოლოს, შეგიძლიათ სცადოთ ეს მაკრო ახლავე.

პირველ რიგში, აირჩიეთ ან გახსენით წყაროს ელფოსტა.
შემდეგ დააწკაპუნეთ მაკრო ღილაკზე სწრაფი წვდომის ხელსაწყოთა ზოლში.
როდესაც მაკრო დასრულდება, თქვენ მიიღებთ Excel-ის სამუშაო ფურცელს, რომელიც ნაჩვენებია შემდეგი სკრინშოტის მსგავსად:

დაიცავით Outlook ფაილი კორუმპირებისგან

ცნობილია, რომ Outlook მიდრეკილია კორუფციისკენ. ამიტომ, ჩვენ უნდა გვესმოდეს, თუ როგორ დავიცვათ Outlook კორუფციისგან. უპირველეს ყოვლისა, ვირუსის შეტევების დაბლოკვის მიზნით, აუცილებელია ანტივირუსის ინსტალაცია და არასოდეს ჩამოტვირთოთ უცნობი დანართი. გარდა ამისა, ჩვენ ჯობია მივიღოთ ძლიერი სარემონტო ხელსაწყო, როგორიცაა DataNumen Outlook Repairმას შეუძლია შემოგთავაზოთ ყველაზე ეფექტური საშუალება იმ შემთხვევაში, თუ პერსპექტიული კორუფცია.

ავტორი შესავალი:

შირლი ჟანგი არის მონაცემთა აღდგენის ექსპერტი DataNumen, Inc., რომელიც მსოფლიო ლიდერია მონაცემთა აღდგენის ტექნოლოგიებში, მათ შორის sql აღდგენა და Outlook სარემონტო პროგრამული პროდუქტები. დამატებითი ინფორმაციისთვის ეწვიეთ www.datanumen. ერთად