როგორ სწრაფად დავამაგროთ a-ს კონკრეტული სლაიდები PowerPoint პრეზენტაცია თქვენს Outlook ელფოსტაზე

Outlook Solutions სექტემბერი 29, 2025

თუ გსურთ ამოიღოთ ა-ს კონკრეტული სლაიდები PowerPoint პრეზენტაცია ცალკე ახალ პრეზენტაციაზე და მიამაგრეთ იგი Outlook ელფოსტაზე, შეგიძლიათ გამოიყენოთ ამ სტატიაში გაზიარებული გზა.

იმის ნაცვლად, რომ მიამაგრო მთელი PowerPoint პრეზენტაცია მეილზე, თუ გსურთ პრეზენტაციის კონკრეტული სლაიდების მიმაგრება, ზოგადად, ჯერ კონკრეტული სლაიდები უნდა დააკოპიროთ ახალ პრეზენტაციაზე. ძალიან პრობლემურია. ამიტომ, აქ ჩვენ გაჩვენებთ მეთოდს, რომლის განხორციელებაც შესაძლებელია ერთი ნაბიჯით.

მიამაგრეთ a-ს კონკრეტული სლაიდები PowerPoint პრეზენტაცია ელექტრონული ფოსტით

პირველ რიგში, გახსენით კონკრეტული PowerPoint პრეზენტაცია.
შემდეგ, PowerPoint განაცხადის ფანჯარაში, დააჭირეთ "Alt + F11" კლავიშებს VBA რედაქტორზე წვდომისთვის.
შემდეგ, ახალ ფანჯარაში, შექმენით ახალი მოდული დაჭერით "ჩასმა" > "მოდული".
ამის შემდეგ, დააკოპირეთ და ჩასვით შემდეგი VBA კოდი ამ მოდულში.

Sub AttachSpecificSlidesToOutlookEmail()
    Dim objActivePresetation As Presentation
    Dim objSlide As Slide
    Dim n As Long
    Dim strName As String
    Dim strTempPresetation As String
    Dim objTempPresetation As Presentation
    Dim objOutlookApp As Object
    Dim objMail As Object
 
    Set objActivePresetation = ActivePresentation
 
    For Each objSlide In objActivePresetation.Slides
        objSlide.Tags.Delete ("Selected")
    Next
 
    'Add a tag "Selected" to the selected slides
    For n = 1 To ActiveWindow.Selection.SlideRange.Count
        ActiveWindow.Selection.SlideRange(n).Tags.Add "Selected", "YES"
    Next n
 
    strName = objActivePresetation.Name
    strName = Left(strName, InStrRev(strName, ".") - 1)
    strTempPresetation = Environ("TEMP") & "\" & strName & ".pptx"
 
    'Copy the active presentation to a temp presentation
    objActivePresetation.SaveCopyAs strTempPresetation
    Set objTempPresetation = Presentations.Open(strTempPresetation)
 
    'Remove the untagged slides
    For n = objTempPresetation.Slides.Count To 1 Step -1
        If objTempPresetation.Slides(n).Tags("Selected") <> "YES" Then
           objTempPresetation.Slides(n).Delete
        End If
    Next n
 
    objTempPresetation.Save
    objTempPresetation.Close
 
    'Attach the temp presentation to a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objMail = objOutlookApp.CreateItem(olMailItem)
 
    'Change the email details as per your needs
    With objMail
         .To = "test@datanumen.com"
         .Subject = strName
         .Body = "Dear," & vbCr & vbCr & vbTab & "Specific slides are extracted and attached."
         .Attachments.Add strTempPresetation
         .Display
    End With
End Sub

ამის შემდეგ შეგიძლიათ დახუროთ მიმდინარე ფანჯარა.
მოგვიანებით, გადადით „ფაილი“ > „ოფციები“ > „სწრაფი წვდომის ხელსაწყოთა პანელი“, რათა დაამატოთ ახალი მაკრო სწრაფი წვდომის ხელსაწყოთა ზოლში.
საბოლოოდ, შეგიძლიათ სცადოთ ეს მაკრო.

დასაწყისისთვის, აირჩიეთ კონკრეტული სლაიდები, რომელთა ამოღებაც გსურთ.
შემდეგ დააწკაპუნეთ მაკრო ღილაკზე სწრაფი წვდომის ხელსაწყოთა ზოლში.
ერთდროულად გამოჩნდება Outlook ელ.წერილი, რომელშიც არის ა PowerPoint პრეზენტაცია, რომელიც ამოღებულია წყაროს პრეზენტაციიდან.

გამოიყენეთ ეფექტური აღდგენის ინსტრუმენტი

როგორც ყველამ ვიცით, Outlook აღჭურვილია ჩაშენებული სარემონტო პროგრამით – სკანპსტი. თუმცა, მას უბრალოდ შეუძლია გაუმკლავდეს მცირე ხარვეზებს Outlook-ში. თუ ის, რასაც თქვენ აწყდებით, სერიოზული ზიანია, ის არ მოიტანს ეფექტს. ამ დროს, თქვენ სხვა არჩევანი არ გაქვთ გარდა იმისა, რომ კვლავ მიმართოთ სხვა მძლავრ და სანდო სარემონტო ხელსაწყოს, მაგალითად DataNumen Outlook Repair. მასთან ერთად, თქვენ შეძლებთ თქვენი დაზიანებული Outlook ფაილის გადარჩენას.

ავტორი შესავალი:

შირლი ჟანგი არის მონაცემთა აღდგენის ექსპერტი DataNumen, Inc., რომელიც მსოფლიო ლიდერია მონაცემთა აღდგენის ტექნოლოგიებში, მათ შორის დაზიანებული მდფ და Outlook სარემონტო პროგრამული პროდუქტები. დამატებითი ინფორმაციისთვის ეწვიეთ www.datanumen. ერთად