როგორ სწრაფად მიამაგროთ Word დოკუმენტის კონკრეტული გვერდები Outlook-ის ელფოსტაზე

Outlook Solutions სექტემბერი 29, 2025

MS Word-ს აქვს პირდაპირი ფუნქცია, რომელიც ეხმარება მომხმარებლებს გაგზავნონ მიმდინარე Word დოკუმენტი ელ.ფოსტის დანართის სახით. მაგრამ ზოგჯერ შეიძლება მხოლოდ იმედი გქონდეთ, რომ Word დოკუმენტის კონკრეტული გვერდები მიამაგრებთ Outlook-ის ელფოსტას. ახლა ეს სტატია გაგიზიარებთ მეთოდს.

MS Word აპლიკაციაში ელ.ფოსტის დანართად მთელი Word დოკუმენტის გასაგზავნად, შეგიძლიათ უბრალოდ გადახვიდეთ მენიუში „ფაილი“ და გადახვიდეთ „შენახვა და გაგზავნა“ ჩანართზე, რომლის ქვეშ შეგიძლიათ იპოვოთ ღილაკი „გაგზავნა როგორც დანართი“. თუმცა, ზოგჯერ ის, რისი გაგზავნაც გსურთ, შეიძლება იყოს მხოლოდ დოკუმენტის კონკრეტული გვერდები. ამ სიტუაციაში, შეგიძლიათ გამოიყენოთ ქვემოთ მოცემული მეთოდი მის შესასრულებლად.

მიამაგრეთ Word დოკუმენტის კონკრეტული გვერდები ელფოსტაზე

უპირველეს ყოვლისა, თქვენ უნდა გახსნათ წყარო Word დოკუმენტი, რომლის კონკრეტული გვერდების გაგზავნა გსურთ ელექტრონული ფოსტით.
შემდეგ, MS Word-ის ფანჯარაში შესვლის შემდეგ, თქვენ უნდა დააჭიროთ ღილაკებს "Alt + F11".
შემდეგი, თქვენ მიიღებთ წვდომას VBA რედაქტორზე MS Word-ში.
ამის შემდეგ, თქვენ უნდა ჩართოთ „Microsoft Outlook Object Library“. მის გამოსაყენებლად შეგიძლიათ დააჭიროთ „Tools“ > „Reference“.
შემდგომში, თქვენ უნდა დააკოპიროთ შემდეგი VBA კოდი მოდულში, რომელიც არ გამოიყენება.

Sub AttachSpecificPagesToOutlookEmail()
    Dim strDocumentName As String
    Dim objSelectedPages As Word.Range
    Dim objTempDocument As Word.Document
    Dim objTempRange As Word.Range
    Dim i As Long
    Dim strTempDocument As String
    Dim objOutlookApp As Outlook.Application
    Dim objMail As Outlook.MailItem
 
    strDocumentName = Left(ActiveDocument.Name, InStr(ActiveDocument.Name, ".") - 1)
 
    'Copy the contents from Page 2 to 4
    'You can change the page as per your own needs
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=2
    Set objSelectedPages = Selection.Range
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=4
    objSelectedPages.End = Selection.Bookmarks("\Page").Range.End
    objSelectedPages.Select
    objSelectedPages.Copy
 
    'Paste the copied contents into a new Word Document
    Set objTempDocument = Word.Application.Documents.Add
    objTempDocument.Activate
    Set objTempRange = objTempDocument.Range(0, 0)
    objTempRange.PasteAndFormat (wdFormatOriginalFormatting)

    For i = objTempDocument.Paragraphs.Count To 1 Step -1
        If Len(objTempDocument.Paragraphs(i).Range) = 1 Then
           objTempDocument.Paragraphs(i).Range.Delete
        Else
           Exit For
        End If
    Next i
 
    'Save this document
    strTempDocument = "E:\" & strDocumentName & " (Excerpt).doc"
    objTempDocument.SaveAs2 strTempDocument, wdFormatDocument
 
    'Attach the new document to a new Outlook email
    On Error Resume Next
    Set objOutlookApp = GetObject(, "Outlook.Application")
    If objOutlookApp Is Nothing Then
       Set objOutlookApp = CreateObject("Outlook.Application")
    End If
 
    Set objMail = objOutlookApp.CreateItem(olMailItem)
    objMail.Attachments.Add (strTempDocument)
    objMail.Display
 
    objTempDocument.Close False
    Kill strTempDocument
End Sub

საბოლოოდ, შეგიძლიათ ამ მაკროს გაშვება. უბრალოდ დააჭირეთ F5 ღილაკს ან შეეხეთ "Run" ხატულას ხელსაწყოთა ზოლში.
მაკრო დასრულების შემდეგ გამოჩნდება ახალი Outlook ელფოსტა, რომელსაც თან ერთვის წყარო Word დოკუმენტის ამონაწერი, როგორიცაა შემდეგი ეკრანის სურათი:

ამოიღეთ მაქსიმალური მონაცემები კორუმპირებული Outlook ფაილიდან

თუ თქვენ იყენებდით Outlook-ს ათწლეულების განმავლობაში, შეიძლება შეგექმნათ სხვადასხვა Outlook-ის პრობლემები, მათ შორის, ამომხტარი შიდა შეცდომის შეტყობინებები, უეცარი ავარია და ასევე ფაილის სერიოზული დაზიანება. გამომდინარე იქიდან, რომ სკანპსტი, ჩაშენებული სარემონტო ხელსაწყო, შეუძლია გაუმკლავდეს მხოლოდ მცირე პრობლემებს, სჯობს ხელთ გქონდეთ გარე მძლავრი სარემონტო ინსტრუმენტი, ვთქვათ DataNumen Outlook Repair. მას შეუძლია მაქსიმალური მონაცემების ამოღება დაზიანებული Outlook მონაცემთა ფაილიდან.

ავტორი შესავალი:

შირლი ჟანგი არის მონაცემთა აღდგენის ექსპერტი DataNumen, Inc., რომელიც მსოფლიო ლიდერია მონაცემთა აღდგენის ტექნოლოგიებში, მათ შორის sql შესწორება და Outlook სარემონტო პროგრამული პროდუქტები. დამატებითი ინფორმაციისთვის ეწვიეთ www.datanumen. ერთად