როგორ ამოიღოთ ჩაშენებული სურათების ავტომატური ამოღება კონკრეტული შემომავალი ელფოსტიდან Outlook VBA-ით

თუ გსურთ, რომ Outlook-მა ავტომატურად ამოიღოს და შეინახოს ჩაშენებული სურათები კონკრეტული შემომავალი ელფოსტიდან, შეგიძლიათ იხილოთ ეს სტატია. აქ ჩვენ გასწავლით, თუ როგორ უნდა მიაღწიოთ ამას VBA კოდით.

ზოგიერთ მომხმარებელს ხშირად სჭირდება ჩაშენებული სურათების ამოღება კონკრეტული შემომავალი ელფოსტიდან და მათი Windows-ის კონკრეტულ საქაღალდეში შენახვა. ამის ხელით გაკეთება ყოველთვის ძალიან რთულია. ამიტომ, ბევრი მოუთმენლად ელის სწრაფი და მოსახერხებელი მიდგომის შესწავლას, რათა Outlook-მა ავტომატურად შეასრულოს ეს. ახლა კი, აქ ჩვენ გაგიზიარებთ ამ მეთოდს.

ჩაშენებული სურათების ავტომატური ამოღება კონკრეტული შემომავალი ელფოსტიდან

1. პირველ რიგში, გაუშვით თქვენი Outlook პროგრამა ჩვეულებისამებრ.
2. შემდეგ, როგორც წესი, ჩართეთ Outlook VBA რედაქტორი მითითებით t "როგორ გაუშვათ VBA კოდი თქვენს Outlook-ში".
3. მოგვიანებით, დააკოპირეთ და ჩასვით შემდეგი VBA კოდი „ThisOutlookSession“ პროექტში.

Public WithEvents objInbox As Outlook.Folder
Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInbox = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Set objInboxItems = objInbox.Items
End Sub

Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
    Dim objAttachments As Outlook.Attachments
    Dim objAttachment As Outlook.Attachment
    Dim strWindowsFolder As String
    Dim i As Long
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Specify the emails as per your needs
       If objMail.Importance = olImportanceHigh Then
          Set objAttachments = objMail.Attachments
 
          'Specify the windows folder
          strWindowsFolder = "E:\" & objMail.Subject & Format(Now, "yymmddhhmmss")
          MkDir (strWindowsFolder)
 
          'Save all embedded images to the folder
          For i = 1 To objAttachments.Count
              Set objAttachment = objAttachments.Item(i)
              If IsEmbedded(objAttachment) = True Then
                 objAttachment.SaveAsFile strWindowsFolder & "\" & objAttachment.FileName
              End If
          Next
      End If
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.PropertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.PropertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

4. ამის შემდეგ, დააწკაპუნეთ „Application_Startup“ ქვერუტინზე.
5. და ბოლოს, ამ მაკროს გასააქტიურებლად დააჭირეთ ღილაკს „F5“.
6. ამიერიდან, ყოველ ჯერზე, როდესაც შემოსულებში ახალი ელ.წერილი შემოვა, ჩაშენებული სურათები შეინახება კონკრეტულ Windows-ის საქაღალდეში, როგორც ეს ნაჩვენებია შემდეგ ეკრანის სურათზე.

რეგულარულად გაწმინდეთ დიდი დანართები

რეკომენდებულია თქვენი Outlook-იდან დიდი დანართების რეგულარულად გაწმენდა. ეს მიზნად ისახავს თქვენი Outlook ფაილის შესაბამისი ზომის შენარჩუნებას. დიდი Outlook ფაილი უფრო მგრძნობიარეა დაზიანების მიმართ. როგორც იცით, PST დაზიანების კარგად მოგვარება საკმაოდ რთულია. შესაძლოა, თავდაპირველად სცადოთ მისი გამოსწორება შემოსულების შეკეთების ხელსაწყოს გამოყენებით. თუმცა, უმეტეს შემთხვევაში, ეს არ იმუშავებს. თქვენი ერთადერთი გამოსავალი სპეციალიზებული... PST შეკეთება ინსტრუმენტი, როგორიცაა DataNumen Outlook Repair, ან შესაბამისი პროფესიონალური რეაბილიტაციის სერვისები.

ავტორი შესავალი:

შირლი ჟანგი არის მონაცემთა აღდგენის ექსპერტი DataNumen, Inc., რომელიც მსოფლიო ლიდერია მონაცემთა აღდგენის ტექნოლოგიებში, მათ შორის mdf შესწორება და Outlook სარემონტო პროგრამული პროდუქტები. დამატებითი ინფორმაციისთვის ეწვიეთ www.datanumen. ერთად