2 სწრაფი გზა, რომ იპოვოთ ან წაშალოთ წინადადებები, რომლებიც შეიცავს კონკრეტულ ტექსტს თქვენს სიტყვაში

სიტყვის გადაწყვეტილებები სექტემბერი 28, 2025

ამ სტატიაში ჩვენ შემოგთავაზებთ 2 სწრაფ გზას, რათა იპოვოთ ან წაშალოთ წინადადებები, რომლებიც შეიცავს კონკრეტულ ტექსტს თქვენს Word-ში.

ყველასთვის ცნობილია, რომ Word-ში „ძებნა და ჩანაცვლება“ ფუნქციის გამოყენებით, კონკრეტული სიტყვების ყველა შემთხვევის მარტივად მოსაძებნად შეგვიძლია გამოვიყენოთ. ამ შემთხვევაში, მათი მონიშვნა, ჩანაცვლება ან წაშლა პრობლემას არ შეგვიქმნის. როგორც ხედავთ, სამიზნე სიტყვა ან ფრაზაა. თუმცა, დღეს სიამოვნებით გაგაცნობთ მაკრო გზას, თუ როგორ მოვძებნოთ ან წავშალოთ გარკვეული ტექსტის შემცველი წინადადებები.

მეთოდი 1: იპოვნეთ ან წაშალეთ წინადადებები, რომლებიც შეიცავს კონკრეტულ ტექსტს

დასაწყისისთვის, დააჭირეთ "Alt+ F11", რათა ჩართოთ VBA რედაქტორი Word-ში.
შემდეგ შექმენით ახალი მოდული "ნორმალური" დაწკაპუნებით.
შემდეგ დააჭირეთ "ჩასმა" და აირჩიეთ "მოდული", რომ მიიღოთ ახალი.
და გახსენით მოდული ორმაგი დაწკაპუნებით.
ახლა ჩასვით შემდეგი კოდები:

Sub DeleteSentencesContainingSpecificWords()
  Dim strTexts As String
  Dim strButtonValue As String
 
  strTexts = InputBox("Enter texts to be found here: ")
 
  With Selection
    .HomeKey Unit:=wdStory
 
    '  Find the entered texts.
    With Selection.Find
      .ClearFormatting
      .Text = strTexts
      .Replacement.Text = ""
      .Forward = True
      .Wrap = wdFindContinue
      .Format = False
      .MatchCase = False
      .MatchWholeWord = False
      .MatchWildcards = False
      .MatchSoundsLike = False
      .MatchAllWordForms = False
      .Execute
    End With
 
    Do While .Find.Found = True
      '  Expand the selection to the entire sentence.
      Selection.Expand Unit:=wdSentence
      strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
      If strButtonValue = vbYes Then
        Selection.Delete
      End If
      .Collapse wdCollapseEnd
      .Find.Execute
    Loop
  End With
End Sub

შემდეგ დააჭირეთ "Run".
იქნება შეყვანის ველი, რომელიც მოგთხოვთ ტექსტის შეყვანას. უბრალოდ ჩაწერეთ საერთო ტექსტი, რომელსაც შეიცავს ყველა წინადადება. დააჭირეთ "OK".
შემდეგ დაინახავთ წინადადებას, რომელიც შეიცავს შერჩეულ ტექსტს შეტყობინებების ველით. დააჭირეთ "დიახ" წინადადების წასაშლელად და "არა" მის შესანარჩუნებლად.
დადასტურების შემდეგ, შემდეგი წინადადება, რომელსაც აქვს მითითებული ტექსტი, მონიშნულია. ასევე არის დადასტურების ველი. კერძოდ, მაკრო გადაგიყვანთ მთელ დოკუმენტში, სამიზნე წინადადებების მოსაძებნად და ყოველ ჯერზე დადასტურების მოთხოვნით.

მეთოდი 2: იპოვნეთ ან წაშალეთ წინადადებები, რომლებიც შეიცავს სიის ნებისმიერ ტექსტს

მაკრო მეთოდი 1-ში შეგიძლიათ მოძებნოთ მხოლოდ ერთი სიტყვა ან ფრაზა. რა თქმა უნდა, შეგიძლიათ მაკრო არაერთხელ გაუშვათ სიტყვების ან ფრაზების მრავალი მაგალითის მოსაძებნად. მრავალჯერადი ძიების საჭიროების დასაკმაყოფილებლად, ჩვენ მოგაწვდით სხვა მაკროს.

პირველ რიგში, ყველა სამიზნე ტექსტი ახალ დოკუმენტში მოათავსეთ. დარწმუნდით, რომ ტექსტის თითოეული ნაწილი ერთ აბზაცს იკავებს ბოლოში სივრცის გარეშე. დახურეთ და შეინახეთ დოკუმენტი.
შემდეგ დააინსტალირეთ და გაუშვით მაკრო 1 მეთოდის ზუსტი ნაბიჯებით.
შემდეგ შეცვალეთ მაკრო ამით:

Sub DeleteSentencesContainingSpecificWordsOnAList()
  Dim objListDoc As Document, objTargetDoc As Document
  Dim objParaRange As Range
  Dim objParagraph As Paragraph
  Dim strFileName As String, strButtonValue As String
  Dim dlgFile As FileDialog
 
  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    If .Show = -1 Then
      strFileName = .SelectedItems(1)
    Else
      MsgBox "No file is selected! Please select the target file."
      Exit Sub
    End If
  End With
  Set objTargetDoc = ActiveDocument
  Set objListDoc = Documents.Open(strFileName)
  objTargetDoc.Activate
 
  For Each objParagraph In objListDoc.Paragraphs
    Set objParaRange = objParagraph.Range
    objParaRange.End = objParaRange.End - 1
 
    With Selection
      .HomeKey Unit:=wdStory
 
      '  Find target words.
      With Selection.Find
        .ClearFormatting
        .Text = objParaRange
        .MatchWholeWord = True
        .MatchCase = False
        .Execute
      End With
 
      '  Expand the selection to the entire sentence.
      Do While .Find.Found
        Selection.Expand Unit:=wdSentence
        strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
        If strButtonValue = vbYes Then
          Selection.Delete
        End If
        .Collapse wdCollapseEnd
        .Find.Execute
      Loop
    End With
  Next objParagraph
End Sub

ახლა გაიხსნება "Browse" ფანჯარა. აირჩიეთ ახლახან შენახული დოკუმენტი და დააჭირეთ ღილაკს "გახსნა".
შემდეგი პროცედურა იგივეა, რაც 1 მეთოდში.

კორუმპირებულ დოკუმენტებთან გამკლავების მიდგომა

ღირებული მონაცემების დაკარგვა აბსოლუტურად დამღუპველია. მას შეუძლია დატოვოს თქვენი ბიზნესი სასწორზე. ასეთი იმედგაცრუების თავიდან ასაცილებლად, თქვენ უნდა დაიჭიროთ ა სიტყვის შესწორება ინსტრუმენტი რაც შეიძლება მალე. ასეთი ინსტრუმენტი დაგეხმარებათ მოიგოთ ბრძოლა დოკუმენტების კორუფციასთან.

ავტორი შესავალი:

ვერა ჩენი არის მონაცემთა აღდგენის ექსპერტი DataNumen, Inc., რომელიც მსოფლიო ლიდერია მონაცემთა აღდგენის ტექნოლოგიებში, მათ შორის შეასწორეთ Excel მდე pdf პროგრამული პროდუქტების შეკეთება. დამატებითი ინფორმაციისთვის ეწვიეთ www.datanumen. ერთად