Outlook-ის ყველა მონიშნული ელფოსტის სიის ექსპორტის 2 სწრაფი გზა Excel-ში

თუ გსურთ ყველა დროშით მონიშნული ელფოსტის სიის ექსპორტი თქვენი Outlook საფოსტო ყუთიდან Excel-ში, შეგიძლიათ გამოიყენოთ ამ სტატიაში გაზიარებული 2 მეთოდიდან რომელიმე.

მაგალითად, იმისათვის, რომ უფრო დროულად გაუმკლავდეთ დროშით მონიშნულ ელ.წერილს ან გაუზიაროთ ისინი სხვას, შეიძლება იმედი გქონდეთ ექსპორტის ექსპორტზე Excel-ის სამუშაო ფურცელზე. აქვე შემოგთავაზებთ 2 მიდგომას მის რეალიზებისთვის. პირველი იყენებს სტანდარტულ „იმპორტი და ექსპორტი“ ფუნქციას დროშით მონიშნული ელ.ფოსტის პოვნის შემდეგ. მართალი გითხრათ, ცოტა დამღლელია. ამრიგად, ამ უკანასკნელში ჩვენ გასწავლით უფრო მოსახერხებელ გზას, რომელიც იყენებს VBA-ს.

მეთოდი 1: ყველა ნაპოვნი დროშით მონიშნული ელფოსტის ექსპორტი ხელით

1. უპირველეს ყოვლისა, დააწკაპუნეთ საძიებო ველში ფოსტის სიის ზემოთ.
2. შემდეგ, დააწკაპუნეთ "ფოსტის ყველა ელემენტზე" "Scope" ჯგუფში "ძებნა" ჩანართზე.
3. შემდეგი, დააწკაპუნეთ ღილაკზე „დროშით მონიშნული“ ჯგუფში „განსაზღვრა“.
4. სიაში ნაჩვენები ყველა დროშით მონიშნული ელფოსტის შემდეგ, აირჩიეთ ერთი წერილი და დააჭირეთ „Ctrl + A“ ყველა მათგანის ასარჩევად.
5. შემდეგ დააჭირეთ "Ctrl + Shift + V" კლავიშთა მალსახმობებს.
6. ახალ დიალოგურ ფანჯარაში შექმენით ახალი საქაღალდე Outlook ფაილის ქვეშ.
7. მოგვიანებით, აირჩიეთ ახალი შექმნილი საქაღალდე და დააწკაპუნეთ "OK", რომელიც გადაიტანს ყველა ნაპოვნი დროშის მქონე ელფოსტას ახალ საქაღალდეში.
8. ამის შემდეგ დააჭირეთ "ფაილი" > "გახსნა" > "იმპორტი",
9. ამომხტარ დიალოგურ ფანჯარაში აირჩიეთ „ექსპორტი ფაილში“ > „შემდეგი“ > „Microsoft Excel 97-2003“ > „შემდეგი“.
10. ახალ ეკრანზე აირჩიეთ სწორი საქაღალდე და დააჭირეთ "შემდეგი".
11. შემდეგ მიჰყევით ოსტატებს „ექსპორტის“ დასასრულებლად.
12. თქვენ მიიღებთ ახალ Excel ფაილს, რომელიც ნაჩვენებია შემდეგი სკრინშოტის სახით.

მეთოდი 2: ყველა დროშით მონიშნული ელფოსტის სიის ექსპორტი VBA-ით

1. Outlook-ში დააჭირეთ "Alt + F11" VBA რედაქტორის გასააქტიურებლად.
2. შემდეგ, ჩართეთ "MS Excel Object" შესაბამისად "როგორ დავამატოთ ობიექტის ბიბლიოთეკის მითითება VBA-ში".
3. შემდეგი, დააკოპირეთ ქვემოთ მოცემული VBA კოდი მოდულში.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllFlaggedEmailsToExcel()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
  
    'Select a source PST file
    Set objOutlookFile = Outlook.Application.Session.PickFolder
 
    If Not (objOutlookFile Is Nothing) Then
       'Create a new Excel file
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
       objExcelApp.Visible = True
 
       With objExcelWorksheet
           .Cells(1, 1) = "Subject"
           .Cells(1, 1).Font.Bold = True
           .Cells(1, 2) = "Start Date"
           .Cells(1, 2).Font.Bold = True
           .Cells(1, 3) = "Due Date"
           .Cells(1, 3).Font.Bold = True
           .Cells(1, 4) = "From"
           .Cells(1, 4).Font.Bold = True
           .Cells(1, 5) = "To"
           .Cells(1, 5).Font.Bold = True
      End With
 
      For Each objFolder In objOutlookFile.Folders
          If objFolder.DefaultItemType = olMailItem Then
             Call ProcessMailFolders(objFolder)
          End If
      Next
 
      objExcelWorksheet.Columns("A:E").AutoFit

      MsgBox "Completed!", vbInformation + vbOKOnly, "Export Emails"
    End If
End Sub

Sub ProcessMailFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objFlaggedMail As Outlook.MailItem
    Dim nLastRow As Integer
    Dim objSubfolder As Outlook.Folder
 
    For i = 1 To objCurrentFolder.Items.Count
        If objCurrentFolder.Items(i).Class = olMail Then
           'Export the information of each flagged email to Excel
           Set objMail = objCurrentFolder.Items(i)
           If objMail.IsMarkedAsTask = True And objMail.FlagStatus <> olFlagComplete Then
              Set objFlaggedMail = objMail
 
              With objExcelWorksheet
                   nLastRow = .Range("A" & .Rows.Count).End(xlUp).Row + 1
                   .Range("A" & nLastRow) = objFlaggedMail.Subject
                   .Range("B" & nLastRow) = objFlaggedMail.TaskStartDate
                   .Range("C" & nLastRow) = objFlaggedMail.TaskDueDate
                   .Range("D" & nLastRow) = objFlaggedMail.SenderName
                   .Range("E" & nLastRow) = objFlaggedMail.To
              End With
          End If
        End If
    Next i
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessMailFolders(objSubfolder)
       Next
    End If
End Sub

4. და ბოლოს, ჩადეთ კურსორი "ExportAllFlaggedEmailsToExcel" ქვეპროგრამაში და დააჭირეთ ღილაკს "F5".
5. შემდეგ აირჩიეთ Outlook ფაილი ახალ დიალოგურ ფანჯარაში.
6. როდესაც მიიღებთ მოთხოვნას "დასრულებულია", თქვენ ასევე მიიღებთ ახალ Excel ფაილს, როგორც ქვემოთ მოცემული სურათი.

დაიცავით თქვენი მსოფლმხედველობა კორუფციისგან

Outlook-ი მიდრეკილია შეცდომებისა და დაზიანებისკენ, ამიტომ ჩვენი Outlook მონაცემების დაცვა ჩვენთვის ძალიან რთული ამოცანაა. უდავოა, რომ ყველაზე ეფექტური და პრაქტიკული გზა Outlook-ის რეგულარული მონაცემთა სარეზერვო ასლების შექმნაა. გარდა ამისა, ჩვენთვის ასევე აუცილებელია Outlook-ის შეცდომების გამოსწორების ძლიერი და სანდო ინსტრუმენტის შეძენა, როგორიცაა DataNumen Outlook Repair. გამოდგება თუ შემოსულების სარემონტო ინსტრუმენტი არ ახდენს ეფექტს.

ავტორი შესავალი:

შირლი ჟანგი არის მონაცემთა აღდგენის ექსპერტი DataNumen, Inc., რომელიც მსოფლიო ლიდერია მონაცემთა აღდგენის ტექნოლოგიებში, მათ შორის დაფიქსირება SQL Server და Outlook სარემონტო პროგრამული პროდუქტები. დამატებითი ინფორმაციისთვის ეწვიეთ www.datanumen. ერთად