Metodi 2 per inviare rapidamente celle selezionate in un foglio di lavoro Excel come e-mail di Outlook

A volte, potresti voler inserire rapidamente le celle selezionate in un foglio di lavoro di Excel in un'e-mail di Outlook e inviare questa e-mail. Questo articolo esaminerà questo desiderio di offrirti 2 metodi.

Il mio precedente articolo “2 metodi rapidi per inviare un foglio di lavoro Excel come e-mail di Outlook" ti ha insegnato come inviare un intero foglio di lavoro Excel come e-mail. Tuttavia, a volte, desideri solo inviare le celle selezionate in un foglio di lavoro come e-mail. In risposta a questa esigenza, qui ti esporremo 2 metodi. Puoi scegliere uno dei due secondo le tue preferenze.

Metodo 1: copia manualmente le celle selezionate nell'e-mail

1. Per iniziare, apri il file Excel di origine e accedi al foglio di lavoro Excel corretto.
2. Quindi seleziona le celle che desideri inviare come e-mail di Outlook.
3. Quindi premi le scorciatoie da tastiera "Ctrl + C" per copiare le celle selezionate.
4. Successivamente, avvia l'applicazione Outlook.
5. Successivamente, fai clic sul pulsante "Nuova email" nella barra multifunzione "Home" per creare una nuova email di Outlook.
6. Successivamente, nella nuova finestra del messaggio, fai clic sulla sezione del corpo del messaggio.
7. Quindi premere i pulsanti "Ctrl + V" per incollare le celle Excel selezionate precedentemente copiate.
8. Infine, puoi comporre l'e-mail come al solito e fare clic sul pulsante "Invia" per inviarlo.

Metodo 2: invia celle selezionate come e-mail tramite VBA

1. All'inizio, apri la cartella di lavoro di Excel di origine.
2. Quindi premere i pulsanti "Alt + F11" per accedere all'editor VBA di Excel.
3. Nella nuova finestra, fare clic su "Inserisci" > "Modulo" per inserire un nuovo modulo.
4. Successivamente, è necessario abilitare Microsoft Outlook Object. Fare clic su "Strumenti" > "Riferimenti". Nella finestra di dialogo visualizzata, individuare e selezionare "Microsoft Outlook Object Library".
5. Successivamente, copia il seguente codice VBA in questo modulo.

Sub SendSelectedCells_inOutlookEmail()
    Dim objSelection As Excel.Range
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempHTMLFile As String
    Dim objTempHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objOutlookApp As Outlook.Application
    Dim objNewEmail As Outlook.MailItem
 
    'Copy the selection
    Set objSelection = Selection
    Selection.Copy
 
    'Paste the copied selected ranges into a temp worksheet
    Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
    Set objTempWorksheet = objTempWorkbook.Sheets(1)
 
    'Keep the values, column widths and formats in pasting
    With objTempWorksheet.Cells(1)
         .PasteSpecial xlPasteValues
         .PasteSpecial xlPasteColumnWidths
         .PasteSpecial xlPasteFormats
    End With
 
    'Save the temp worksheet as a HTML file
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempHTMLFile = objFileSystem.GetSpecialFolder(2).Path & "\Temp for Excel" & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".htm"
    Set objTempHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strTempHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
    objTempHTMLFile.Publish (True)
 
    'Create a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objNewEmail = objOutlookApp.CreateItem(olMailItem)
 
    'Read the HTML file data and insert into the email body
    Set objTextStream = objFileSystem.OpenTextFile(strTempHTMLFile)
    objNewEmail.HTMLBody = objTextStream.ReadAll
    objNewEmail.Display
    'You can specify the new email recipients, subjects here using the following lines:
    'objNewEmail.To = "johnsmith@datanumen.com"
    'objNewEmail.Subject = "DataNumen Products"
    'objNewEmail.Send --> directly send out this email
 
    objTextStream.Close
    objTempWorkbook.Close (False)
    objFileSystem.DeleteFile (strTempHTMLFile)
End Sub

6. Alla fine, puoi provare.

• Innanzitutto, seleziona le celle specifiche come al solito.
• Quindi torna alla nuova macro e premi il tasto F5 per attivarla.
• Immediatamente, verrà visualizzata una nuova e-mail di Outlook, in cui puoi vedere che le celle selezionate sono state inserite nel corpo dell'e-mail, come il seguente screenshot:

Il file PST è lo stesso vulnerabile del file Excel

Come sappiamo, i file Excel e i documenti Word sono soggetti a danneggiamento. In realtà, lo stesso vale per i file PST, che contengono tutti gli elementi della tua casella di posta Outlook. Pertanto, proteggere i dati PST è un compito arduo. Una delle misure più efficaci è eseguire regolarmente il backup del file. Inoltre, per poter fornire un recupero immediato, è meglio preparare uno strumento esperto, come DataNumen Outlook Repair, che è in grado di recuperare Outlook dati senza sudare.

Introduzione dell'autore:

Shirley Zhang è un'esperta di recupero dati in DataNumen, Inc., che è il leader mondiale nelle tecnologie di recupero dati, tra cui riparazione mdf e prodotti software di riparazione di Outlook. Per maggiori informazioni visita www.datanumen.com