Kuidas kiiresti eksportida kõik Outlooki meili pildimanused Exceli tööle

Kui soovite kõik Outlooki meili piltmanused kiiresti Exceli töölehel eksportida, vaadake seda artiklit. Siin näitame teile tõhusamat viisi kui käsitsi eksportimine.

Kui saate meili, mis sisaldab hulgaliselt piltidega manuseid, ja soovite neid Exceli aruande koostamiseks kasutada, peate otsima viisi, kuidas neid pilte partiidena Exceli töölehele eksportida. Nüüd tutvustame teile sellist lähenemisviisi järgnevalt.

Eksportige kõik meilipildi manused Exceli tööle

1. Alustuseks avage oma Outlooki rakendus tavalisel viisil.
2. Seejärel vajutage Outlooki aknas kiirklahve "Alt + F11", mis avab akna "Microsoft Visual Basic for Applications".
3. Sellel ekraanil peate avama mooduli, mida ei kasutata, või sisestama kohe uue.
4. Järgmisena peaksite sellesse moodulisse kopeerima allpool oleva VBA-koodi.

Sub ExportAllImageAttachmentsToExcelWorksheet()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim strImage As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim objFile As Object
    Dim objFiles As Object
    Dim nRow As Integer
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objSourceMail = ActiveInspector.currentItem
           Case olExplorer
                Set objSourceMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    If Not (objSourceMail Is Nothing) Then
 
       'Save the image attachments to a temporary folder
       strTempFolder = Environ("Temp") & "\" & Format(Now, "yyyymmddhhmmss") & "\"
       MkDir (strTempFolder)
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.Attachments
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                          objAttachment.SaveAsFile strTempFolder & objAttachment.filename
              End Select
           End If
       Next
 
       'Create a new Excel workbook
        Set objExcelApp = CreateObject("Excel.Application")
        Set objExcelWorkbook = objExcelApp.Workbooks.Add
        Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
        objExcelApp.Visible = True
        objExcelWorkbook.Activate
 
        'Get the images in the temporary folder
        Set objFiles = objFileSystem.GetFolder(strTempFolder).Files
 
        'Insert the images into this new Excel worksheet
        For Each objFile In objFiles
            strImage = strTempFolder & Trim(objFile.Name)
            nRow = nRow + 1
            With objExcelWorksheet
                 .Range("A" & nRow).value = objFile.Name
                 'Change the height and width as per your needs
                 .Range("B" & nRow).ColumnWidth = 10
                 .Range("B" & nRow).RowHeight = 80
                 .Range("B" & nRow).Activate
                 With .Pictures.insert(strImage)
                      With .ShapeRange
                           .LockAspectRatio = msoTrue
                           .Width = 50
                           .Height = 70
                      End With
                 End With
                 .Columns("A").AutoFit
                 .Activate
            End With
       Next
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

5. Pärast seda saate makrost väljuda.
6. Seejärel minge jaotisse Fail > Valikud > Kiirjuurdepääsu tööriistariba, et lisada see makro kiirpääsu tööriistaribale.
7. Lõpuks saate seda makrot kohe proovida.

• Esiteks valige või avage lähtemeil.
• Seejärel klõpsake kiirjuurdepääsu tööriistaribal makronuppu.
• Kui makro on lõpule jõudnud, saate Exceli töölehe, mis on näidatud nagu järgmine ekraanipilt:

Kaitske Outlooki faili riknemise eest

On teada, et Outlook on korruptsiooniohtlik. Seetõttu peaksime mõistma, kuidas Outlooki korruptsiooni eest kaitsta. Esiteks, viiruserünnakute blokeerimiseks on vaja installida viirusetõrjetarkvara ja mitte kunagi alla laadida tundmatuid manuseid. Pealegi on meil parem hankida mõni võimas remonditööriist, näiteks DataNumen Outlook RepairSee pakub kõige tõhusamat abinõu järgmistel juhtudel: Outlooki korruptsioon.

Autori sissejuhatus:

Shirley Zhang on andmete taastamise ekspert DataNumen, Inc., mis on maailmas juhtiv andmete taastamise tehnoloogiate, sealhulgas sql taastamine ja Outlooki remonditarkvaratooted. Lisateabe saamiseks külastage www.datanumenCom