Kuidas Wordi dokumendi konkreetseid lehti kiiresti Outlooki meilile manustada

MS Wordil on otsene funktsioon, mis võimaldab kasutajatel saata praegust Wordi dokumenti e-posti manusena. Kuid mõnikord võite loota, et saate Outlooki meilile lisada Wordi dokumendi konkreetsed lehed. Nüüd jagab see artikkel teile meetodit.

Terve Wordi dokumendi saatmiseks e-posti manusena MS Wordi rakenduses võite lihtsalt minna menüüsse „Fail“ ja liikuda vahekaardile „Salvesta ja saada“, mille alt leiate nupu „Saada manusena“. Kuid mõnikord võib see, mida soovite saata, olla ainult dokumendi konkreetsed leheküljed. Sellises olukorras saate selle saavutamiseks kasutada allpool kirjeldatud meetodit.

Lisage e-kirjale Wordi dokumendi konkreetsed lehed

1. Kõigepealt peaksite avama lähteteksti Wordi dokumendi, mille konkreetseid lehti soovite meiliga saata.
2. Seejärel, pärast MS Wordi aknasse sisenemist, peate vajutama klahvikombinatsiooni Alt + F11.
3. Järgmisena pääsete juurde MS Wordi VBA redaktorile.
4. Pärast seda peate lubama „Microsoft Outlook Object Library“. Selleks klõpsake menüüd „Tööriistad“ > „Viited“.
5. Seejärel peaksite kopeerima järgmise VBA koodi moodulisse, mida ei kasutata.

Sub AttachSpecificPagesToOutlookEmail()
    Dim strDocumentName As String
    Dim objSelectedPages As Word.Range
    Dim objTempDocument As Word.Document
    Dim objTempRange As Word.Range
    Dim i As Long
    Dim strTempDocument As String
    Dim objOutlookApp As Outlook.Application
    Dim objMail As Outlook.MailItem
 
    strDocumentName = Left(ActiveDocument.Name, InStr(ActiveDocument.Name, ".") - 1)
 
    'Copy the contents from Page 2 to 4
    'You can change the page as per your own needs
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=2
    Set objSelectedPages = Selection.Range
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=4
    objSelectedPages.End = Selection.Bookmarks("\Page").Range.End
    objSelectedPages.Select
    objSelectedPages.Copy
 
    'Paste the copied contents into a new Word Document
    Set objTempDocument = Word.Application.Documents.Add
    objTempDocument.Activate
    Set objTempRange = objTempDocument.Range(0, 0)
    objTempRange.PasteAndFormat (wdFormatOriginalFormatting)

    For i = objTempDocument.Paragraphs.Count To 1 Step -1
        If Len(objTempDocument.Paragraphs(i).Range) = 1 Then
           objTempDocument.Paragraphs(i).Range.Delete
        Else
           Exit For
        End If
    Next i
 
    'Save this document
    strTempDocument = "E:\" & strDocumentName & " (Excerpt).doc"
    objTempDocument.SaveAs2 strTempDocument, wdFormatDocument
 
    'Attach the new document to a new Outlook email
    On Error Resume Next
    Set objOutlookApp = GetObject(, "Outlook.Application")
    If objOutlookApp Is Nothing Then
       Set objOutlookApp = CreateObject("Outlook.Application")
    End If
 
    Set objMail = objOutlookApp.CreateItem(olMailItem)
    objMail.Attachments.Add (strTempDocument)
    objMail.Display
 
    objTempDocument.Close False
    Kill strTempDocument
End Sub

6. Lõpuks saate selle makro käivitada. Vajutage lihtsalt klahvi F5 või puudutage tööriistaribal ikooni "Käivita".
7. Pärast makro lõppu kuvatakse uus Outlooki meilisõnum, mis on lisatud Wordi lähtedokumendi väljavõttega, nagu järgmine ekraanipilt:

Ekstraheerige maksimaalselt andmeid rikutud Outlooki failist

Kui olete Outlooki aastakümneid kasutanud, võite olla kokku puutunud erinevate Outlooki probleemidega, sealhulgas hüpikakna sisemiste veateadete, äkiliste kokkujooksmiste ja tõsiste failikahjustustega. Tulenevalt asjaolust, et scanpst, sisseehitatud remonditööriist, saab hakkama ainult väikeste probleemidega, parem hoidke väline võimas parandustööriist käepärast, ütleme DataNumen Outlook Repair. See suudab kahjustatud Outlooki andmefailist välja võtta maksimaalsed andmed.

Autori sissejuhatus:

Shirley Zhang on andmete taastamise ekspert DataNumen, Inc., mis on maailmas juhtiv andmete taastamise tehnoloogiate, sealhulgas sql parandus ja Outlooki remonditarkvaratooted. Lisateabe saamiseks külastage www.datanumenCom