Kuidas kiiresti oma Outlooki meilile lisada Windowsi kaustas viimati muudetud fail

Mõnikord võite soovida kiiresti leida ja Outlooki meilisõnumile manustada konkreetses Windowsi kaustas viimati muudetud faili. Sel juhul saate kasutada käesolevas artiklis kirjeldatud meetodit.

Mõned kasutajad soovivad, et Outlook leiaks kiiresti välja ja lisaks e-kirjale viimase muudetud faili Windowsi kaustas, näiteks viimati loodud, muudetud või salvestatud faili. Outlook aga sellist otsest ja loomulikku funktsiooni ei paku. Seetõttu tutvustame järgnevalt VBA-koodi, mis seda hõlpsalt võimaldab.

Manustage meilile viimati muudetud fail Windowsi kaustas

1. Kohe alguses peaksite käivitama oma Outlooki rakenduse.
2. Seejärel saate pärast Outlooki peaaknasse sisenemist vajutada klahvikombinatsiooni Alt + F11.
3. Järgmisena pääsete edukalt juurde Outlooki VBA redaktori aknale.
4. Seejärel peaksite leidma ja avama mooduli, mida ei kasutata.
5. Seejärel kopeerige ja kleepige sellesse mooduli aknasse järgmine VBA kood.

Sub AttachLastModifiedSpecificFile()
    Dim objShell As Object
    Dim objSelectedFolder As Object
    Dim objFileSystem As Object
    Dim strSourceFolderPath As String
    Dim objSourceFolder As Object
    Dim objFile As Object
    Dim dLastModifiedDate As Date
    Dim strLastModifiedFilePath As String
    Dim objMail As Outlook.MailItem
 
    On Error GoTo ErrorHandler
    'Select a local source folder
    Set objShell = CreateObject("Shell.Application")
    Set objSelectedFolder = objShell.BrowseForFolder(0, "Select the source folder", 0, "")
    strSourceFolderPath = objSelectedFolder.self.Path
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objSourceFolder = objFileSystem.GetFolder(strSourceFolderPath)
 
    If objSourceFolder.Files.Count > 0 Then
       For Each objFile In objSourceFolder.Files
           'Find the last modified file within "xlsx" file type in the selected Windows folder
           If (objFile.DateLastModified > dLastModifiedDate) And (objFileSystem.GetExtensionName(objFile) = "xlsx") Then
              'You can add or change criteria, such as
              'Left(objFile.Name, 4) = "Test" ---> file whose name begins with "Test"
              '(objFile / 1024) / 1024 > 2 --> File exceeds 2 MB
              'Note: Use "And" to connect more than one criteria
              strLastModifiedFilePath = objFile.Path
              dLastModifiedDate = objFile.DateLastModified
           End If
       Next
 
       If strLastModifiedFilePath <> "" Then
          'Confirm attaching it to the current outlook email
          strMsg = "The last modified file in the " & Chr(34) & strSourceFolderPath & Chr(34) & " is: " & vbCrLf & vbCrLf & "File: " & strLastModifiedFilePath & vbCrLf & "Date: " & dLastModifiedDate & vbCrLf & vbCrLf & "Do you want to attach it?"
          nPrompt = MsgBox(strMsg, vbQuestion + vbYesNo, "Confirm Attaching Last Modified File")
 
          If nPrompt = vbYes Then
             Set objMail = Outlook.Application.ActiveInspector.CurrentItem
             objMail.Attachments.Add strLastModifiedFilePath
         End If
      Else
         MsgBox "No file in the selected folder can meet your predefined criteria!", vbExclamation + vbOKOnly
      End If
    Else
      MsgBox "No file exists in the selected Windows folder!", vbExclamation + vbOKOnly
    End If
 
ErrorHandler:
    Exit Sub
End Sub

6. Pärast seda saate praegusest VBA redaktori aknast väljuda ja jätkata uue makro lisamist kiirpääsu tööriistaribale või sõnumiakna lindile.
7. Hiljem peate muutma oma Outlooki makro turvataseme madalaks.
8. Lõpuks saate proovida.

• Esiteks looge ja koostage nagu tavaliselt uus Outlooki meil.
• Seejärel vajutage kiirpääsu tööriistaribal makronuppu, nagu alloleval pildil:
• Järgmisena peate valima Windowsi lähtekausta ja vajutama "OK".
• Kui valitud Windowsi kaustas on selline fail, kuvatakse järgmine kuvatõmmis:
• Kui vajutate "Jah", lisatakse see fail kohe.

Lahendage Outlooki probleemid niipea kui võimalik

Kui teil tekib Outlooki probleeme, on soovitatav need võimalikult kiiresti lahendada. Sellises olukorras on parem valmistada tugev Outlooki parandus tööriist ette, nt DataNumen Outlook Repair. See on võimeline parandama PST-vigu ja päästma tõhusalt teie Outlooki andmeid.

Autori sissejuhatus:

Shirley Zhang on andmete taastamise ekspert DataNumen, Inc., mis on maailmas juhtiv andmete taastamise tehnoloogiate, sealhulgas rikutud mdf ja Outlooki remonditarkvaratooted. Lisateabe saamiseks külastage www.datanumenCom