Kuidas kiiresti välja võtta kõik adressaadid mitmest Outlooki sõnumifailist (.msg).

Mõned kasutajad soovivad kiiresti ekstraktida kõik adressaadid mitmest Outlooki meilisõnumitest salvestatud Outlooki sõnumifailist. Nüüd see lkost vaatab seda, et jagada kiiret lähenemist.

Adressaatide eraldamiseks ühest Outlooki sõnumifailist saate selle avamiseks lihtsalt topeltklõpsata ja seejärel kopeerida adressaadid avanenud sõnumiaknas. Kuid kui teil on vaja käsitleda Outlooki sõnumifailide partii, ei ole käsitsi meetod piisavalt tõhus. Seega võite otsida palju tõhusamat viisi. Siin tutvustame teile sellist. Selle üksikasjade saamiseks lugege edasi.

Ekstraktige kõik adressaadid mitmest Outlooki sõnumifailist (.msg).

1. Sest nagutart, hankige juurdepääs Outlooki VBA redaktorile vastavalt "Kuidas Outlookis VBA-koodi käivitada".
2. Järgmisena kopeerige ja kleepige järgmine VBA kood tühja moodulisse.

Dim strRecipients As String

Sub ExtractRecipientsFromOutlookMSGFiles()
    Dim objShell, objWindowsFolder As Object
 
    strRecipients = ""
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       Call ProcessWindowsFolders(objWindowsFolder.self.Path & "\")
       'Display a Message
       MsgBox "Recipients: " & vbCrLf & strRecipients, vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessWindowsFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.Recipient
    Dim objSubfolder As Object

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
 
    For Each objFile In objFolder.Files
        If objFileSystem.GetExtensionName(objFile) = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)

           If TypeName(objItem) = "MailItem" Then
              Set objMail = objItem
              'Extract recipients' email addresses
              For Each objRecipient In objMail.Recipients
                  strRecipients = strRecipients & objRecipient.Address & vbCr
              Next
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubfolder In objFolder.SubFolders
           If ((objSubfolder.Attributes And 2) = 0) And ((objSubfolder.Attributes And 4) = 0) Then
               Call ProcessWindowsFolders(objSubfolder.Path)
           End If
       Next
    End If
End Sub

3. Seejärel liigutage kursorit esimeses alamprogrammis.
4. Seejärel klõpsake nuppu "Käivita" või vajutage klahvi "F5".
5. Seejärel valige hüpikaknas dialoogiboksis Windowsi kaust, mis sisaldab Outlooki sõnumite (.msg) lähtefaile.
6. Pärast valimist klõpsake makro töö jätkamiseks "OK".
7. Kui makro on lõppenud, kuvatakse teade, mis sisaldab kõigi ekstraktitud adressaatide e-posti aadresse, nagu on näidatud järgmisel ekraanipildil.

Kaitske oma Outlooki andmeid ohu eest

Outlooki andmed on kahtlemata altid korruptsioonile. Seetõttu on Outlooki andmete kaitsmine üsna koormav ülesanne. See nõuab teilt visadust Outlooki andmete regulaarsel varundamisel. Samuti on võimalusel mõistlik ja soovitatav koostada kogenud ja professionaalne Outlook PST remont tööriist, nagu DataNumen Outlook Repair, et saaksite Outlooki riknemise korral kohe ja õigeaegselt päästa.

Autori sissejuhatus:

Shirley Zhang on andmete taastamise ekspert DataNumen, Inc., mis on maailmas juhtiv andmete taastamise tehnoloogiate, sealhulgas taastuma Sql Server ja Outlooki remonditarkvaratooted. Lisateabe saamiseks külastage www.datanumenCom