3 meetodit meilide importimiseks Windowsi kaustast Outlooki

Võib-olla olete oma Windowsi kausta salvestanud mitu Outlooki meili. Kui soovite need uuesti Outlooki kausta importida, kuidas saate seda teha? See artikkel õpetab teile 3 võimalust.

Nagu me kõik teame, pakub Outlook sisseehitatud valikut - "Salvesta nimega", mille abil saate e-kirjad Windowsi kausta salvestada. Siiski pole võimalust eksporditud meilide uuesti Outlooki kausta lisada. Seega, kui soovite Outlooki meilid Outlooki tagasi importida, siis kuidas saate seda realiseerida? Järgnevalt õpetame teile 3 meetodit. Saate valida mis tahes vastavalt oma eelistustele.

1. meetod: importimiseks pukseerige

1. Kohe alguses peate pääsema juurde Windowsi lähtekaustale, mis salvestab Outlooki importimiseks Outlooki meilisõnumeid.
2. Seejärel käivitage oma Outlooki rakendus.
3. Järgmisena avage Outlooki kaust, kuhu soovite meilid importida.
4. Seejärel tuleb kitsendada nii Windowsi kaustade kui ka Outlooki akent, kuni saate neid vahepeal vaadata.
5. Pärast seda saate Windowsi kaustas valida ühe Outlooki e-kirjadest ja seejärel kõigi nende valimiseks vajutada "Ctrl + A".
6. Hiljem saate lohistada valitud meilid nähtavasse Outlooki kausta, nagu järgmine ekraanipilt:
7. Lõpuks näete, et kõik Outlooki meilid on imporditud Windowsi kaustast Outlooki kausta, mis on näidatud alloleval pildil:

2. meetod: kasutage VBA-s käsku "CreateItemFromTemplate".

1. Et start, vajutage Outlooki peaaknas klahvikombinatsiooni Alt + F11.
2. Järgmisena saate juurdepääsu Outlook VBA redaktori aknale.
3. Seejärel kopeerige järgmine VBA kood tühja moodulisse.

Sub ImportAllOutlookEmailsfromLocaltoOutlook1()
    Dim objFileSystem As Object
    Dim strLocalFolderPath As String
    Dim objLocalFolder As Object
    Dim objTargetFolder As Outlook.Folder
    Dim objFiles As Object
    Dim objFile As Object
    Dim strFileType As String
    Dim objItem As Object
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    strLocalFolderPath = strSelectedFolder("")
    Set objLocalFolder = objFileSystem.GetFolder(strLocalFolderPath)
    Set objFiles = objLocalFolder.Files
 
    'Set the target Outlook folder
    Set objTargetFolder = Session.GetDefaultFolder(olFolderInbox).folders("Ago")
 
    For Each objFile In objFiles
        strFileType = objFileSystem.GetExtensionName(objFile)
  
        If strFileType = "msg" Then
           Set objItem = Outlook.Application.CreateItemFromTemplate(objFile.Path)
 
           objItem.Move objTargetFolder
           'Delete the source file in the Windows folder
           'objFileSystem.DeleteFile (objFile.Path)
        End If
    Next
End Sub

Function strSelectedFolder(strStartFolder As String) As String
    Dim objShell As Object
    Dim objFolder As Object
 
    On Error Resume Next
    Set objShell = CreateObject("Shell.Application")
    Set objFolder = objShell.BrowseForFolder(0, "Select the source folder:", 0, strStartFolder)
 
    strSelectedFolder = objFolder.self.Path
End Function

4. Järgmisena saate praeguse mooduli aknas vajutada klahvi F5, et valida start makro.
5. Pärast seda peate sirvima hüpikaknast Windowsi lähtekausta.
6. Lõpuks imporditakse pärast lähtekausta valimist kõik selles kaustas olevad Outlooki üksused eelmääratletud Outlooki kausta.
7. Märkus: sel viisil on imporditud meilid kõik värsked uued meilid, mida saate oma äranägemise järgi koostada, nagu järgmine ekraanipilt:

3. meetod: kasutage VBA-s valikut OpenSharedItem

1. Sarnaselt 2. meetodi puhul kopeerige järgmised VBA-koodid teise moodulisse.

Sub ImportAllOutlookEmailsfromLocaltoOutlook2()
    Dim objFileSystem As Object
    Dim strLocalFolderPath As String
    Dim objLocalFolder As Object
    Dim objTargetFolder As Outlook.Folder
    Dim objFiles As Object
    Dim objFile As Object
    Dim strFileType As String
    Dim objItem As Object
    Dim objCopiedItem As Outlook.MailItem

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    strLocalFolderPath = strSelectedFolder("")
    Set objLocalFolder = objFileSystem.GetFolder(strLocalFolderPath)
    Set objFiles = objLocalFolder.Files
 
    'Set the target Outlook folder
    Set objTargetFolder = Session.GetDefaultFolder(olFolderInbox).folders("Ago")
 
    For Each objFile In objFiles
        strFileType = objFileSystem.GetExtensionName(objFile)
 
        If strFileType = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)
           'Only import emails
           If TypeOf objItem Is MailItem Then
              Set objCopiedItem = objItem.Copy
              objCopiedItem.Move objTargetFolder
              'Delete the source file in the Windows folder
              'objFileSystem.DeleteFile (objFile.Path)
           End If
       End If
    Next
End Sub

Function strSelectedFolder(strStartFolder As String) As String
    Dim objShell As Object
    Dim objFolder As Object
 
    On Error Resume Next
    Set objShell = CreateObject("Shell.Application")
    Set objFolder = objShell.BrowseForFolder(0, "Select the source folder:", 0, strStartFolder)
 
    strSelectedFolder = objFolder.self.Path
End Function

2. Seejärel käivitage see makro, vajutades klahvi "F5".
3. Järgmisena valige lähtekaust.
4. Lõpuks imporditakse kõik meilid alloleva pildina:

Võrdlused

Vahendid PST-andmete korruptsiooni blokeerimiseks

Nagu me kõik teame, on Outlook eelinstallitud koos sisseehitatud tööriistaga - scanpst. Most aja jooksul on see võimeline lahendama väikseid probleeme. Kui aga probleemid on tõsised, kipub sisseehitatud tööriist ebaõnnestuma. Seetõttu peaksite kasutama tugevamat tööriista, näiteks DataNumen Outlook Repair.

Autori sissejuhatus:

Shirley Zhang on andmete taastamise ekspert DataNumen, Inc., mis on maailmas juhtiv andmete taastamise tehnoloogiate, sealhulgas SQL Server korruptsioon ja Outlooki remonditarkvaratooted. Lisateabe saamiseks külastage www.datanumenCom