2 kiiret viisi kõigi märgistatud Outlooki meilide loendi eksportimiseks Excelisse

Kui soovite eksportida kõigi märgistatud meilide loendi oma Outlooki postkastist Excelisse, saate kasutada üht kahest selles artiklis kirjeldatud meetodist.

Näiteks selleks, et käsitleda kõiki märgistatud e-kirju õigeaegselt või jagada neid kellegi teisega, võite loota eksportida need Exceli töölehel. Siin tutvustame 2 lähenemisviisi selle realiseerimiseks. Esimene neist kasutab pärast märgistatud e-kirjade leidmist standardset "Impordi ja ekspordi" funktsiooni. Ausalt öeldes on see natuke tüütu. Seega viimases õpetame teile mugavamat viisi VBA rakendamiseks.

1. meetod: eksportige kõik leitud märgistatud meilid käsitsi

1. Kõigepealt klõpsake meililoendi kohal olevat otsingukasti.
2. Seejärel klõpsake vahekaardi "Otsing" rühmas "Uurimisala" "Kõik meiliüksused".
3. Järgmisena klõpsake rühmas "Määratlemine" nuppu "Märgistatud".
4. Pärast kõiki loendis kuvatud märgistatud e-kirju valige üks e-kiri ja vajutage nende kõigi valimiseks klahvikombinatsiooni Ctrl + A.
5. Seejärel vajutage kiirklahve "Ctrl + Shift + V".
6. Looge uues dialoogiboksis Outlooki faili alla uus kaust.
7. Hiljem valige uus loodud kaust ja klõpsake "OK", mis teisaldab kõik leitud märgistatud meilid uude kausta.
8. Seejärel klõpsake "Fail" > "Ava" > "Impordi",
9. Hüpikdialoogiboksis valige "Ekspordi faili" > "Järgmine" > "Microsoft Excel 97-2003" > "Järgmine".
10. Uuel ekraanil valige õige kaust ja klõpsake nuppu "Järgmine".
11. Seejärel järgige "Ekspordi" lõpuleviimiseks viisardeid.
12. Saate uue Exceli faili, mis on näidatud järgmise ekraanipildina.

2. meetod: eksportige kõigi märgistatud meilide loend VBA kaudu

1. Outlookis vajutage VBA redaktori käivitamiseks klahvikombinatsiooni Alt + F11.
2. Seejärel lubage "MS Exceli objekt" vastavalt valikule "Kuidas lisada VBA-s objektiteegi viidet".
3. Järgmisena kopeerige allolev VBA kood moodulisse.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllFlaggedEmailsToExcel()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
  
    'Select a source PST file
    Set objOutlookFile = Outlook.Application.Session.PickFolder
 
    If Not (objOutlookFile Is Nothing) Then
       'Create a new Excel file
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
       objExcelApp.Visible = True
 
       With objExcelWorksheet
           .Cells(1, 1) = "Subject"
           .Cells(1, 1).Font.Bold = True
           .Cells(1, 2) = "Start Date"
           .Cells(1, 2).Font.Bold = True
           .Cells(1, 3) = "Due Date"
           .Cells(1, 3).Font.Bold = True
           .Cells(1, 4) = "From"
           .Cells(1, 4).Font.Bold = True
           .Cells(1, 5) = "To"
           .Cells(1, 5).Font.Bold = True
      End With
 
      For Each objFolder In objOutlookFile.Folders
          If objFolder.DefaultItemType = olMailItem Then
             Call ProcessMailFolders(objFolder)
          End If
      Next
 
      objExcelWorksheet.Columns("A:E").AutoFit

      MsgBox "Completed!", vbInformation + vbOKOnly, "Export Emails"
    End If
End Sub

Sub ProcessMailFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objFlaggedMail As Outlook.MailItem
    Dim nLastRow As Integer
    Dim objSubfolder As Outlook.Folder
 
    For i = 1 To objCurrentFolder.Items.Count
        If objCurrentFolder.Items(i).Class = olMail Then
           'Export the information of each flagged email to Excel
           Set objMail = objCurrentFolder.Items(i)
           If objMail.IsMarkedAsTask = True And objMail.FlagStatus <> olFlagComplete Then
              Set objFlaggedMail = objMail
 
              With objExcelWorksheet
                   nLastRow = .Range("A" & .Rows.Count).End(xlUp).Row + 1
                   .Range("A" & nLastRow) = objFlaggedMail.Subject
                   .Range("B" & nLastRow) = objFlaggedMail.TaskStartDate
                   .Range("C" & nLastRow) = objFlaggedMail.TaskDueDate
                   .Range("D" & nLastRow) = objFlaggedMail.SenderName
                   .Range("E" & nLastRow) = objFlaggedMail.To
              End With
          End If
        End If
    Next i
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessMailFolders(objSubfolder)
       Next
    End If
End Sub

4. Lõpuks asetage kursor alamprogrammi "ExportAllFlaggedEmailsToExcel" ja vajutage "F5" nuppu.
5. Seejärel valige uues dialoogiboksis Outlooki fail.
6. Kui kuvatakse viip „Lõpetatud”, saate ka uue Exceli faili, nagu alloleval pildil.

Kaitske oma Outlooki korruptsiooni eest

Outlook on altid vigadele ja riknemisele, seega on meie Outlooki andmete kaitsmine väga keeruline ülesanne. Kahtlemata on kõige tõhusam ja praktilisem viis Outlooki andmete regulaarne varukoopiate tegemine. Lisaks sellele on meil vaja hankida ka võimas ja usaldusväärne Outlooki parandustööriist, näiteks DataNumen Outlook Repair. See tuleb kasuks, kui postkasti parandamise tööriist ei anna mõju.

Autori sissejuhatus:

Shirley Zhang on andmete taastamise ekspert DataNumen, Inc., mis on maailmas juhtiv andmete taastamise tehnoloogiate, sealhulgas määrata SQL Server ja Outlooki remonditarkvaratooted. Lisateabe saamiseks külastage www.datanumenCom