Cómo crear rápidamente una regla de Outlook para bloquear a los remitentes de varios correos electrónicos

Si desea crear una regla para bloquear a los remitentes de varios correos electrónicos seleccionados, por lo general, primero debe escribir los remitentes y luego crear una regla manualmente. Es bastante molesto. Por lo tanto, aquí compartiremos un método mucho más rápido para obtenerlo con un solo clic.

Algunos usuarios piensan que la función "ant-spam" incorporada en Outlook no es tan eficaz como esperan. Por eso, están acostumbrados a crear reglas de Outlook para bloquear a los remitentes. Ahora, a continuación, presentaremos un método rápido para crear una regla para bloquear a los remitentes de varios correos electrónicos.

Cree rápidamente una regla para bloquear remitentes de varios correos electrónicos

1. Porque comotart, inicie la aplicación Outlook.
2. Luego, ingrese a la ventana del editor de VBA a través del acceso directo "Alt + F11".
3. A continuación, en la nueva ventana, coloque el siguiente código VBA en un módulo no utilizado.

Sub CreateRuleForBlockingMultipleSenders()
    Dim objRules As Outlook.Rules
    Dim objRule As Outlook.Rule
    Dim objMoveRuleAction As Outlook.MoveOrCopyRuleAction
    Dim objFromCondition As Outlook.ToOrFromRuleCondition
    Dim objSelection As Outlook.Selection
    Dim objMail As Outlook.MailItem
    Dim objJunkFolder As Outlook.Folder
 
    Set objRules = Application.Session.DefaultStore.GetRules()
    'Create a rule
    Set objRule = objRules.Create("Block Senders", olRuleReceive)
    Set objFromCondition = objRule.Conditions.From
 
    'Get the selected emails
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
    'Get Junk Email folder
    Set objJunkFolder = Outlook.Application.Session.GetDefaultFolder(olFolderJunk)
 
    For i = objSelection.Count To 1 Step -1
        If objSelection.Item(i).Class = olMail Then
 
           Set objMail = objSelection.Item(i)
 
           'Add the email senders to rule condition
           With objFromCondition
                .Enabled = True
                .Recipients.Add objMail.SenderEmailAddress
                .Recipients.ResolveAll
           End With
 
           'Move the emails from blocked senders to Junk Email folder
           Set objMoveRuleAction = objRule.Actions.MoveToFolder
           With objMoveRuleAction
                .Enabled = True
                .Folder = objJunkFolder
           End With
         End If
    Next
 
    objRules.Save
End Sub

4. Después de eso, de acuerdo con "Cómo ejecutar código VBA en su Outlook“, Agregue esta macro a la barra de herramientas de acceso rápido o cinta.
5. Posteriormente, salga del editor de VBA normalmente.
6. Por último, siga los siguientes pasos para intentarlo.

• En primer lugar, seleccione los correos electrónicos cuyos remitentes desea bloquear.
• Luego, haga clic en el botón de nueva macro.
• Una vez finalizada la macro, puede ir al menú "Archivo" y hacer clic en el botón "Administrar reglas y alertas" para verificar la regla recién agregada, como se muestra en la imagen a continuación.

Mantenga a raya los correos electrónicos maliciosos

Independientemente del cliente de correo electrónico que utilice, debe recibir con frecuencia los correos electrónicos de remitentes desconocidos. METROost de los correos electrónicos pueden ser spam publicitarios e incluso contener macros maliciosas. Pueden dañar su archivo de Outlook en un santiamén. Por lo tanto, en Outlook, debe tomar medidas efectivas para bloquear los correos electrónicos desconocidos. Además, si puede permitírselo, es recomendable preparar una potente herramienta de recuperación de PST, como DataNumen Outlook Repair. Se puede reparar Outlook archivo sin sudar, sin importar cuán gravemente esté dañado.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo recuperación de sql y productos de software de reparación de Outlook. Para más información visite www.datanumen.com