Cómo usar automáticamente diferentes colores de fuente para responder y reenviar correos electrónicos con Outlook VBA

Por defecto, Outlook no puede usar automáticamente diferentes colores de fuente para responder y reenviar correos electrónicos. Por lo tanto, si necesita esta función, puede leer este artículo para aprender una solución práctica.

Outlook solo le permite especificar una fuente utilizada tanto para responder como para reenviar correos electrónicos. Puede ir a "Archivo"> ​​"Opciones". Luego, en "Opciones de Outlook", vaya a la pestaña "Correo" y haga clic en el botón "Papelería y fuentes ...". En la siguiente ventana, puede ver el botón "Fuente" en "Responder o reenviar mensajes". Haga clic en él y luego podrá establecer un color de fuente específico para responder y reenviar correos electrónicos.

Sin embargo, muchos usuarios esperan usar diferentes colores de fuente para responder o reenviar correos electrónicos. Aunque Outlook no proporciona ninguna función directa para esto, aún se puede realizar con código VBA. Ahora, siga leyendo para obtener un fragmento de código VBA.

Uso automático de diferentes colores de fuente para responder y reenviar correos electrónicos

1. Para empezar, abre la aplicación Outlook.
2. Luego, active el editor de VBA con referencia a "Cómo ejecutar código VBA en su Outlook".
3. A continuación, de acuerdo con "Cómo agregar una referencia a una biblioteca de objetos en VBA“, agregue la referencia a “Biblioteca de objetos de MS Word”.
4. Posteriormente, copie el siguiente código en el proyecto "ThisOutlookSession".

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Dim objReply As Outlook.MailItem
    Dim objReplyDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReply = objMail.Reply
    objReply.Display
    Set objReplyDoc = objReply.GetInspector.WordEditor
    objReplyDoc.Range(0, 0).Select
    Set objDocSelection = objReplyDoc.Application.Selection
    'Use "Pink" font in "Reply"
    objDocSelection.Font.ColorIndex = wdPink
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objReplyAll As Outlook.MailItem
    Dim objReplyAllDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReplyAll = objMail.ReplyAll
    objReplyAll.Display
    Set objReplyAllDoc = objReplyAll.GetInspector.WordEditor
    objReplyAllDoc.Range(0, 0).Select
    Set objDocSelection = objReplyAllDoc.Application.Selection
    'Use "Green" font in "Reply All"
    objDocSelection.Font.ColorIndex = wdGreen
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objForward As Outlook.MailItem
    Dim objForwardDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objForward = objMail.Forward
    objForward.Display
    Set objForwardDoc = objForward.GetInspector.WordEditor
    objForwardDoc.Range(0, 0).Select
    Set objDocSelection = objForwardDoc.Application.Selection
    'Use "Blue" font in Forward
    objDocSelection.Font.ColorIndex = wdBlue
End Sub

5. Después, reinicie Outlook para activar esta macro.
6. Finalmente, puedes intentarlo.

• Seleccione o abra un correo electrónico.
• Luego, haga clic en el botón "Responder". Al responder un correo electrónico, puede escribir algunas palabras en el cuerpo. El color de la fuente debe ser rosa.
• O haga clic en el botón "Responder a todos". En el nuevo correo "responder a todos", ingrese palabras en el cuerpo. El color de la fuente seguramente es verde.
• Del mismo modo, haga clic en el botón "Adelante". En el correo de reenvío, las nuevas palabras se mostrarán en azul.

Recurra a software confiable

En el caso de Corrupción de OutlookLa mayoría de los usuarios tienden a recurrir al software de recuperación de Outlook. Hay una gran cantidad de programas de este tipo disponibles en el mercado, e incluso algunos son gratuitos. Sin embargo, debe tener cuidado con los de fuentes desconocidas, ya que podrían empeorar la situación. Debe recurrir a una herramienta confiable y experimentada, como DataNumen Outlook Repair.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo sql dañado y productos de software de reparación de Outlook. Para más información visite www.datanumen.com