Cómo eliminar automáticamente los correos electrónicos de Outlook de un remitente específico después de días específicos

Para permitir que Outlook elimine automáticamente los correos electrónicos de un remitente específico de días específicos, puede leer este artículo. Aquí le mostraremos los pasos detallados para usar el código VBA para obtenerlo.

Cuando se trata de eliminar automáticamente correos electrónicos, primero puede pensar en la función "Autoarchivar". Sin embargo, no puede filtrar los remitentes específicos al archivar automáticamente correos electrónicos. Por lo tanto, por ejemplo, si desea eliminar automáticamente los correos electrónicos de un remitente específico después de x días, debe utilizar otros medios, como el siguiente.

Eliminar automáticamente los correos electrónicos de un remitente específico después de X días

1. Al principio, start su aplicación de Outlook.
2. Luego, active el editor de Outlook VBA de acuerdo con "Cómo ejecutar código VBA en su Outlook".
3. A continuación, copie el siguiente código VBA en el proyecto "ThisOutlookSession".

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
 
    Call DeleteEmailsFromSpecificSenderAfterXDays
End Sub

Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'From the specific sender
       If objMail.SenderEmailAddress = "bob_black@datanumen.com" Then
          'Set expiry time - after 5 days
          objMail.ExpiryTime = objMail.ReceivedTime + 4
          objMail.Save
       End If
    End If
End Sub

Private Sub DeleteEmailsFromSpecificSenderAfterXDays()
    Dim strFilter As String
    Dim objExpiredItems As Outlook.Items
    Dim objExpiredMail As Outlook.MailItem
 
    strFilter = "[ExpiryTime] <= " & Chr(34) & Now & Chr(34)
 
    'Get all expired items
    Set objExpiredItems = objInboxItems.Restrict(strFilter)
 
    For i = objExpiredItems.Count To 1 Step -1
        If objExpiredItems(i).Class = olMail Then
           Set objExpiredMail = objExpiredItems(i)
 
           'Auto delete expired emails from the specific sender
           If objExpiredMail.SenderEmailAddress = "bob_black@datanumen.com" Then
              objExpiredMail.Delete
           End If
        End If
    Next
End Sub

4. Después de eso, restart Outlook para activar esta macro.
5. Desde entonces, cada vez que llega un nuevo correo electrónico del remitente específico a la Bandeja de entrada, se le asignará un tiempo de vencimiento específico, los días específicos posteriores a su recepción.
6. Entonces, cada vez que start Outlook, Outlook comprobará automáticamente y eliminará los correos caducados del remitente específico.

Restaurar datos de Outlook después de la corrupción

Quizás haya encontrado una variedad de errores y problemas en Outlook. Entonces, ¿alguna vez se ha enfrentado a la corrupción de Outlook? Por ejemplo, si con frecuencia sale de Outlook incorrectamente, su archivo PST tiende a dañarse. Generalmente, en tal caso, puede seleccionar recuperar los datos de Outlook de las copias de seguridad. O puedes usar herramienta de reparación de la bandeja de entrada o una herramienta externa confiable, como DataNumen Outlook Repair.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo recuperar sql y productos de software de reparación de Outlook. Para más información visite www.datanumen.com