Cómo exportar por lotes varios correos electrónicos de Outlook en un documento de Word a través de VBA

Si desea exportar por lotes varios correos electrónicos de Outlook en un solo documento de Word, puede usar el código VBA que se muestra en este artículo. Puede ayudarlo a realizar esta tarea en segundos.

Alguna vez he presentado cómo convertir un correo electrónico de Outlook en un documento de Word en mi artículo anterior: "2 métodos efectivos para convertir un correo electrónico de Outlook en un documento de Word”. Sin embargo, tanto los 2 medios mencionados en ese post No podrá hacer nada en el caso de que desee exportar por lotes muchos correos electrónicos en un documento de Word. Por eso, aquí te enseñaremos otra forma. Ahora, sigue leyendo para obtener información detallada.

Exportar por lotes varios correos electrónicos de Outlook en un documento de Word

1. A start con, inicie su programa Outlook.
2. Luego, después de ingresar a la ventana principal de Outlook, debe presionar los botones de tecla "Alt + F11".
3. A continuación, obtendrá acceso al editor de Outlook VBA, en el que debe abrir un módulo en blanco.
4. Posteriormente, copie el código VBA a continuación en la ventana del módulo abierta.

Sub ExportMultipleEmails_OneWordDocument()
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim objSelection As Outlook.Selection
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim objWordApp As Word.Application
    Dim objNewWordDocument As Word.Document
    Dim objWordRange As Word.Range
    Dim strWordDocument As String
    Dim i As Long
  
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp" & Format(Now, "YYYYMMDDhhmmss")
    MkDir (strTempFolder)
 
    On Error Resume Next
    'Save each selected email as an individual Word document in a temp folder
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
    For Each objMail In objSelection
        strFileName = objMail.Subject
 
        'Remove the unsupported characters in email subject
        strFileName = Replace(strFileName, "/", " ")
        strFileName = Replace(strFileName, "\", " ")
        strFileName = Replace(strFileName, ":", "")
        strFileName = Replace(strFileName, "?", " ")
        strFileName = Replace(strFileName, Chr(34), " ")
 
        objMail.SaveAs strTempFolder & "\" & strFileName & ".doc", olDoc
    Next
 
    'Merge all the Word documents into a single document
    Set objWordApp = CreateObject("Word.Application")
    Set objNewWordDocument = objWordApp.Documents.Add
 
    strWordDocument = Dir(strTempFolder & "\" & "*.doc")
    i = 0
    Do Until strWordDocument = ""
       i = i + 1
       Set objWordRange = objNewWordDocument.Range
       With objWordRange
           .Collapse wdCollapseEnd
           If i > 1 Then
             .InsertBreak wdSectionBreakNextPage
             .End = objNewWordDocument.Range.End
             .Collapse wdCollapseEnd
           End If
           .InsertFile strTempFolder & "\" & strWordDocument
      End With
      strWordDocument = Dir()
    Loop
 
    'Change the path as per your own needs
    objNewWordDocument.SaveAs "E:\Exported Emails " & Format(Now, "YYYY-MM-DD hh-mm-ss")
    objWordApp.Quit
 
    'Delete the temp folder
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

5. Después de eso, es mejor que agregue este nuevo proyecto VBA a la barra de herramientas de acceso rápido o cinta.
6. En última instancia, puedes intentarlo.

• En primer lugar, seleccione varios correos electrónicos de Outlook.
• Luego busque y haga clic en el botón de macro recién agregado.
• Una vez que se le solicite "Completar", puede buscar la carpeta local predefinida para encontrar un nuevo documento de Word.
• Abra este documento, en el que puede ver que se han exportado todos los correos electrónicos seleccionados.

Mantenga una poderosa herramienta de recuperación cerca

Independientemente de las numerosas funciones, Outlook todavía no puede ser inmune a los errores. Si está acostumbrado a dejar los errores en paz, con ellos acumulándose, el bloqueo de Outlook se producirá definitivamente. En ese momento, es esencial recurrir a una herramienta de recuperación poderosa y eficaz, como DataNumen Outlook Repair. Está bien versado en Corrección de PST. Mientras lo tenga, ya no tendrá que preocuparse por la pérdida de datos de Outlook.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo mdf dañado y productos de software de reparación de Outlook. Para más información visite www.datanumen.com