Cómo exportar rápidamente estadísticas de votación desde un correo electrónico de Outlook a una hoja de cálculo de Excel

Si has enviado un correo electrónico con botones para votar, una vez que los destinatarios te envíen sus respuestas, es posible que quieras contabilizar y exportar las estadísticas de votación a una hoja de cálculo de Excel. En este artículo, te enseñaremos cómo hacerlo rápidamente.

Outlook es tan poderoso que incluso ofrece una función de "votación". Mi artículo anterior "Uso hábil de MS Outlook para votar“ nos ha enseñado cómo utilizarlo eficazmente. Además, la mayoría de las veces, después de votar, es posible que proceda a exportar las estadísticas de votación a una hoja de cálculo de Excel por algún motivo, como por ejemplo, para imprimirlas. Pero Outlook no admite esta función de forma predeterminada. Por lo tanto, a continuación, le enseñaremos cómo hacerlo fácilmente.

Exportar estadísticas de votación en un correo electrónico a una hoja de cálculo de Excel

1. Desde el principio, inicie su aplicación Outlook.
2. Luego, debe presionar los botones de tecla "Alt + F11" en la ventana principal de Outlook.
3. A continuación, en la ventana “Microsoft Visual Basic para Aplicaciones”, debe habilitar la “Biblioteca de objetos de Microsoft Excel”. Haga clic en “Herramientas” > “Referencias”. Luego, en el cuadro de diálogo emergente, marque la casilla de verificación junto a “Biblioteca de objetos de Microsoft Excel” y, por último, haga clic en “Aceptar”.
4. Después de eso, puede insertar un nuevo módulo o abrir uno que no esté en uso.
5. Posteriormente, copie y pegue los siguientes códigos VBA en este módulo.

Sub ExportVotingStatistics _Excel ()
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.recipient
    Dim objVoteDictionary As Object
    Dim varVotingCounts As Variant
    Dim varVotingOptions As Variant
    Dim varVotingOption As Variant
    Dim i As Long
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nRow As Integer
 
    Set objMail = Application.ActiveExplorer.Selection(1)
 
    'Create a new excel worksheet
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    'Fill in the predefined values
    With objExcelWorksheet
         .Cells.Font.Name = "Cambria"
         .Cells(1, 1) = "Voting Results for Email:"
         .Cells(1, 2) = Chr(34) & objMail.Subject & Chr(34)
         .Cells(3, 1) = "Voting Options"
         .Cells(3, 2) = "Voting Counts"
    End With
 
    Set objVoteDictionary = CreateObject("Scripting.Dictionary")
    'get the default voting options
    varVotingOptions = Split(objMail.VotingOptions, ";")
    'Add the voting responses to the dictionary
    For Each varVotingOption In varVotingOptions
        objVoteDictionary.Add varVotingOption, 0
    Next
    'Add a custom voting response - "No Reply"
    objVoteDictionary.Add "No Reply", 0
 
    'Process the all voting responses
    For Each objRecipient In objMail.Recipients
        If objRecipient.TrackingStatus = olTrackingReplied Then
           If objVoteDictionary.Exists(objRecipient.AutoResponse) Then
              objVoteDictionary.Item(objRecipient.AutoResponse) = objVoteDictionary.Item(objRecipient.AutoResponse) + 1
           Else
              objVoteDictionary.Add objRecipient.AutoResponse, 1
           End If
        Else
           objVoteDictionary.Item("No Reply") = objVoteDictionary.Item("No Reply") + 1
        End If
    Next
 
    'Get the voting options and vote counts
    varVotingOptions = objVoteDictionary.Keys
    varVotingCounts = objVoteDictionary.Items
 
    'Fill in the values in specific cells
    nRow = 4
    For i = LBound(varVotingOptions) To UBound(varVotingOptions)
        With objExcelWorksheet
             .Cells(nRow, 1) = varVotingOptions(i)
             .Cells(nRow, 2) = varVotingCounts(i)
        End With
        nRow = nRow + 1
    Next
 
    'Save the new Excel file
    objExcelWorksheet.Columns("A:B").AutoFit
    strExcelFile = "E:\Voting Results " & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

5. Después de eso, para un acceso conveniente, es mejor que agregue la nueva macro a la barra de herramientas de acceso rápido.
6. Eventualmente, puedes intentarlo.

• En primer lugar, seleccione un correo electrónico de origen que contenga botones de votación.
• Luego haga clic en el botón de macro en la barra de herramientas de acceso rápido.
• Una vez que esta macro termine de ejecutarse, puede buscar la carpeta local predefinida, en la que verá un nuevo libro de Excel.
• Abra este libro de Excel. Ahora verá las estadísticas de votación, como se muestra en la imagen a continuación:

Nadie puede evitar completamente los errores de Outlook

Aunque Outlook viene dotado de una variedad de capacidades, no existe tal característica que nos ayude a evitar errores de Outlook. Todo tipo de factores pueden causar errores de Outlook. Por ejemplo, si a menudo sale de Outlook de forma incorrecta, es probable que sufra Corrupción PST. En tal escenario, no tiene más remedio que manejar algunas herramientas potentes para rescatar su archivo PST, como DataNumen Outlook Repair. Se ha ganado muchos elogios debido a su alta tasa de recuperación.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo mdf corrupto y productos de software de reparación de Outlook. Para más información visite www.datanumen.com