2 métodos para enviar rápidamente celdas seleccionadas en una hoja de cálculo de Excel como correo electrónico de Outlook

A veces, es posible que desee insertar rápidamente las celdas seleccionadas en una hoja de cálculo de Excel en un correo electrónico de Outlook y enviar este correo electrónico. Este artículo analizará este deseo para ofrecerle 2 métodos.

Mi artículo anterior "2 métodos rápidos para enviar una hoja de cálculo de Excel como correo electrónico de Outlook”Le ha enseñado a enviar una hoja de cálculo completa de Excel como correo electrónico. Sin embargo, a veces, solo desea enviar las celdas seleccionadas en una hoja de trabajo como un correo electrónico. En respuesta a este requisito, aquí te exponemos 2 métodos. Puede elegir según sus preferencias.

Método 1: copiar las celdas seleccionadas al correo electrónico manualmente

1. A start con, abra el archivo de origen de Excel y acceda a la hoja de cálculo de Excel correcta.
2. Luego, seleccione las celdas que desea enviar como correo electrónico de Outlook.
3. A continuación, presione los métodos abreviados de teclas "Ctrl + C" para copiar las celdas seleccionadas.
4. Después de eso, inicie su aplicación Outlook.
5. Posteriormente, haga clic en el botón "Nuevo correo electrónico" en la cinta "Inicio" para crear un nuevo correo electrónico de Outlook.
6. Más adelante, en la nueva ventana de Mensaje, haga clic en la sección del cuerpo del mensaje.
7. Y luego presione los botones de tecla "Ctrl + V" para pegar las celdas de Excel seleccionadas copiadas previamente.
8. Por último, puede redactar el correo electrónico como de costumbre y hacer clic en el botón "Enviar" para enviarlo.

Método 2: enviar las celdas seleccionadas como correo electrónico a través de VBA

1. Desde el principio, abra el libro de Excel de origen.
2. Luego presione los botones de tecla "Alt + F11" para acceder al editor de Excel VBA.
3. En la nueva ventana, haga clic en "Insertar"> "Módulo" para insertar un nuevo módulo.
4. A continuación, debería habilitar el objeto de Microsoft Outlook. Haga clic en "Herramientas"> "Referencias". En el cuadro de diálogo emergente, busque y marque la casilla "Microsoft Outlook Object Library ”.
5. Posteriormente, copie el siguiente código VBA en este módulo.

Sub SendSelectedCells_inOutlookEmail()
    Dim objSelection As Excel.Range
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempHTMLFile As String
    Dim objTempHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objOutlookApp As Outlook.Application
    Dim objNewEmail As Outlook.MailItem
 
    'Copy the selection
    Set objSelection = Selection
    Selection.Copy
 
    'Paste the copied selected ranges into a temp worksheet
    Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
    Set objTempWorksheet = objTempWorkbook.Sheets(1)
 
    'Keep the values, column widths and formats in pasting
    With objTempWorksheet.Cells(1)
         .PasteSpecial xlPasteValues
         .PasteSpecial xlPasteColumnWidths
         .PasteSpecial xlPasteFormats
    End With
 
    'Save the temp worksheet as a HTML file
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempHTMLFile = objFileSystem.GetSpecialFolder(2).Path & "\Temp for Excel" & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".htm"
    Set objTempHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strTempHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
    objTempHTMLFile.Publish (True)
 
    'Create a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objNewEmail = objOutlookApp.CreateItem(olMailItem)
 
    'Read the HTML file data and insert into the email body
    Set objTextStream = objFileSystem.OpenTextFile(strTempHTMLFile)
    objNewEmail.HTMLBody = objTextStream.ReadAll
    objNewEmail.Display
    'You can specify the new email recipients, subjects here using the following lines:
    'objNewEmail.To = "johnsmith@datanumen.com"
    'objNewEmail.Subject = "DataNumen Products"
    'objNewEmail.Send --> directly send out this email
 
    objTextStream.Close
    objTempWorkbook.Close (False)
    objFileSystem.DeleteFile (strTempHTMLFile)
End Sub

6. Eventualmente, puedes intentarlo.

• En primer lugar, seleccione las celdas específicas como de costumbre.
• Luego, regrese a la nueva macro y presione la tecla F5 para activarla.
• De inmediato, se mostrará un nuevo correo electrónico de Outlook, en el que puede ver que las celdas seleccionadas se han insertado en el cuerpo del correo electrónico, como la siguiente captura de pantalla:

El archivo PST es igual de vulnerable que el archivo de Excel

Como sabemos, el archivo de Excel y el documento de Word son propensos a la corrupción. En realidad, lo mismo se aplica al archivo PST, que contiene todos los elementos de su buzón de correo de Outlook. Por lo tanto, es una tarea ardua proteger sus datos PST. Uno de ellosost La medida eficaz es realizar copias de seguridad del archivo con regularidad. Además, para proporcionar un rescate inmediato, es mejor que prepare una herramienta con experiencia, como DataNumen Outlook Repair, que es capaz de recuperar Outlook datos sin sudar.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo reparar mdf y productos de software de reparación de Outlook. Para más información visite www.datanumen.com