Jak rychle exportovat celkový čas strávený na schůzkách aplikace Outlook v každé barevné kategorii

Chcete-li vytvořit zprávu o celkovém čase, který strávíte schůzkami v každé kategorii barev, můžete využít metodu uvedenou v tomto článku. Pomůže vám to dosáhnout v rychlém čase, aniž byste museli počítat ručně.

Mnoho uživatelů je zvyklých zaznamenávat většinu svých aktivit v kalendáři Outlooku. Aby je bylo možné snadněji spravovat a rozlišovat, přiřazují jim kategorie. V takovém případě by někteří uživatelé chtěli vygenerovat zprávu zobrazující celkový čas strávený na položkách kalendáře v každé barevné kategorii. Ruční počítání a zadávání je nepochybně obtížné. Proto se zde podělíme o způsob, jak toho lze dosáhnout jednoduchým kliknutím.

Exportujte celkový čas strávený na schůzkách v každé barevné kategorii

1. Na prvním místě spusťte aplikaci Outlook.
2. Po vstupu do okna Outlooku můžete klepnout na tlačítka „Alt + F11“.
3. Následně získáte přístup do okna „Microsoft Visual Basic for Applications“.
4. Dále budete muset povolit „Knihovnu objektů Microsoft Excel“. Toho dosáhnete kliknutím na „Nástroje“ > „Reference“.
5. Poté byste měli najít a otevřít modul, který se nepoužívá.
6. Poté musíte do tohoto modulu zkopírovat následující kód VBA.

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

7. Nakonec můžete toto makro spustit, bez ohledu na to kliknutím na ikonu „Spustit“ na panelu nástrojů nebo stisknutím tlačítka „F5“.
8. Poté budete požádáni o výběr konkrétního kalendáře.
9. Jakmile vyberete a stisknete „OK“, makro se bude i nadále spouštět. Po dokončení bude na pozadí nový soubor aplikace Excel.
10. Máte k němu přístup. Bude to vypadat jako na následujícím snímku obrazovky:

Dávejte pozor na potenciální hrozby kolem vašeho Outlooku

Uživatelé aplikace Outlook by si měli dávat pozor na všechna potenciální rizika, včetně neznámých příloh e-mailů, vložených odkazů a lidských chyb. Jinak se váš Outlook může kdykoli poškodit. Rovněž je nutné provádět pravidelné zálohy dat aplikace Outlook a udržovat specializovaný nástroj pro opravy. DataNumen Outlook Repair je jedním z nejvíce doporučovaných nástrojů pro opravy. Může opravit Outlook problémy za okamžik.

Úvod autora:

Shirley Zhang je expertem na obnovu dat DataNumen, Inc., která je světovým lídrem v oblasti technologií pro obnovu dat, včetně poškozený mdf a výhledové softwarové produkty pro opravy. Pro více informací navštivte www.datanumen.com