Jak rychle exportovat podrobnosti o všech členech ve skupině kontaktů aplikace Outlook do aplikace Excel

Ve výchozím nastavení můžete ve skupině kontaktů vidět pouze jména členů a e -mailové adresy. Pokud chcete získat další podrobnosti o členech, můžete použít způsob uvedený v tomto článku.

Když dvakrát kliknete na skupinu kontaktů, kterou chcete otevřít, v jejím okně uvidíte pouze jména a e -mailové adresy členů skupiny. Nemůžete získat další podrobnosti o členech, jako je společnost, pracovní pozice, telefonní číslo nebo obchodní adresa atd. Obecně platí, že k získání těchto podrobností musíte ve složce Kontakty ručně vyhledat kontakty odpovídající členům. Je to příliš problematické. Zde vám ukážeme kousek kódu VBA, který dokáže tyto detaily rychle exportovat do excelového sešitu.

Exportujte podrobnosti o všech členech ve skupině kontaktů do aplikace Excel

1. Nejprve spusťte aplikaci Outlook.
2. Poté byste měli stisknout klávesové zkratky „Alt + F11“ v hlavním okně aplikace Outlook.
3. Dále v novém okně „Microsoft Visual Basic for Applications“ musíte otevřít nepoužívaný modul nebo přímo vložit nový modul.
4. Následně zkopírujte a vložte následující kód VBA do tohoto modulu.

Sub ExportMemberContactDetailsToExcel()
    Dim objContactGroup As Outlook.DistListItem
    Dim objGroupMember As Outlook.recipient
    Dim objContacts As Outlook.Items
    Dim objFoundContact As Outlook.ContactItem
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim i As Integer
    Dim nRow As Integer
    Dim strFilename As String
 
    Set objContactGroup = Application.ActiveExplorer.Selection(1)
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkBook = objExcelApp.Workbooks.Add
    Set objExcelWorkSheet = objExcelWorkBook.Worksheets(1)
 
    'Set the seven column headers
    With objExcelWorkSheet
         .Cells(1, 1) = "Name"
         .Cells(1, 2) = "Email Address"
         .Cells(1, 3) = "Company"
         .Cells(1, 4) = "Job Title"
         .Cells(1, 5) = "Phone Number"
         .Cells(1, 6) = "Mailing Address"
         .Cells(1, 7) = "Birthday"
    End With
 
    Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items.Restrict("[Email1Address]>''")
 
    nRow = 2
    For i = 1 To objContactGroup.MemberCount
        Set objGroupMember = objContactGroup.GetMember(i)
 
        strFilter = "[Email1Address] = '" & objGroupMember.Address & "'"
        Set objFoundContact = objContacts.Find(strFilter)
 
        If Not (objFoundContact Is Nothing) Then
           'Input the Contact Details
           With objExcelWorkSheet
                .Cells(nRow, 1) = objFoundContact.FullName
                .Cells(nRow, 2) = objFoundContact.Email1Address
                .Cells(nRow, 3) = objFoundContact.CompanyName
                .Cells(nRow, 4) = objFoundContact.JobTitle
                .Cells(nRow, 5) = objFoundContact.BusinessTelephoneNumber
                .Cells(nRow, 6) = objFoundContact.MailingAddress
             If objFoundContact.Birthday = #1/1/4501# Then
                .Cells(nRow, 7) = ""
             Else
                .Cells(nRow, 7) = objFoundContact.Birthday
             End If
           End With
       Else
           With objExcelWorkSheet
               .Cells(nRow, 1) = objGroupMember.Name
               .Cells(nRow, 2) = objGroupMember.Address
           End With
       End If
       nRow = nRow + 1
    Next
 
    'Fit the columns
    objExcelWorkSheet.Columns("A:G").AutoFit
 
    'Change the Path as per where you want to save the new Excel file
    strFilename = "E:\" & objContactGroup.DLName & " Member Contact Details.xlsx"
    'Save the Excel workbook
    objExcelWorkBook.Close True, strFilename
 
    MsgBox ("Complete!")
End Sub

5. Poté můžete pro pohodlnou kontrolu přidat nový projekt VBA na panel nástrojů nebo pás karet Rychlý přístup.
6. Později nastavte úroveň zabezpečení maker aplikace Outlook na nízkou.
7. Nakonec to můžete vyzkoušet.

• Nejprve vyberte skupinu kontaktů.
• Poté stiskněte tlačítko makra na panelu nástrojů Rychlý přístup nebo na pásu karet.
• Okamžitě se spustí makro.
• Když skončí, zobrazí se výzva „Dokončeno!“
• Poté můžete přejít do předdefinované cílové místní složky, ve které najdete nový soubor aplikace Excel.
• Otevřete jej, zobrazí se kontaktní údaje členů skupiny jako následující snímek obrazovky:

Nepřepadejte panice tváří v tvář problémům s aplikací Outlook

Nikdo není ochoten přijmout jakékoli potíže s aplikací Outlook, bez ohledu na to, zda se zobrazí chybová zpráva nebo poškozený Outlook datový soubor. Proto uživatelé budou mít tendenci propadat panice, když narazí na problémy s aplikací Outlook. Pokud v takovém případě chcete zachovat klid, měli byste mít v ruce dvě nezbytnosti. Jedním z nich je aktuální záloha dat aplikace Outlook. Druhý je účinný software pro opravu aplikace Outlook DataNumen Outlook Repair.

Úvod autora:

Shirley Zhang je expertem na obnovu dat DataNumen, Inc., která je světovým lídrem v oblasti technologií pro obnovu dat, včetně zotavení sql a výhledové softwarové produkty pro opravy. Pro více informací navštivte www.datanumen.com